set g2_trace_ftions 0

# This example shows two ways to add methods to a class.

class Animal {
   ctor ( ) {
   }

   @
   // First way: just write the method in output mode, between
   // two 'at' signs.
   char* get_name() { return "Fido"; }
   @
   // Second way: in TCL mode, use the procedure 'f'.
   f :pvc void talk(num) {
      // Abstract function with 'int num' argument
   }
}

array set sounds { Cat miowwwwwww Dog woofffffff Snake hisssssss }

foreach animal { Cat Dog Snake } {
   class $animal : public Animal {
      ctor i() {@
         printf("Creating a new \"$(animal)\"\n");
      @}
      dtor () { }

      f :vc void talk(num) {@
         for(int i= 0; i<num; i++)
            printf("$(sounds($animal))...\n");
      @}
   }
}

add Snake:H PUBLIC {@
   void rattle();
@}

cb_clear Dog:CC CTOR
add Dog:CC CTOR {@
   printf("The Dog constructor behaves differently.\n");
@}

c_hdr animals animals.h {
   sys_inc stdio stdlib iostream
   ref Animal:H Dog:H Cat:H Snake:H
}

c_src animals animals.cc {
   my_inc animals
   ref Animal:CC Dog:CC Cat:CC Snake:CC
}