Silly Software Company -=oOo=- A poor man's way of doing things is still a way to get things done

How to Create
DOS Installation Disks

In those days, the disk operating system consisted of 2-3 system files (the 'kernel'), and a directory, typically C:\DOS with some additional software, the so-called external commands. All you need to do is make a DOS boot disk and put the C:\DOS directory on a couple of diskettes, and you have a set of DOS installation disks, as explained before.

What follows is a batch file, a script, that creates these diskettes automatically, from an existing DOS system. It's not very interactive, and works on a couple of assumptions :

• the diskette station is called A:
• DOS is installed in C:\DOS
• C:\DOS also contains
  • pkzip, pkunzip from PKware : archiving tools, like WinZip :-)
  • install.bat, an other batch file, that you will use to install DOS on the other computer.
  if it does not, download and those first. It will make things easier for you.
• the GetDOS script will - for now - copy the autoexec.bat and the config.sys from one computer to another. You'll be given the chance to edit them, eg remove a couple of too specific entries. That should be enough to get you started. Alternatively, you may get a standard, more general config.sys and autoexec.bat from The Silly Software Company and edit use those. Ideally, the config.sys and autoexec.bat used during installation could be different from those that will be used permanently on the target machine, so you may want to arrange that yourself.

With that taken care of, the following bat file will do two things ;

1. create a bootable DOS disk and add some elementary software to it. That includes install.bat if it is located in C:\DOS.
2. archive the C:\DOS directory over (probably) 3 1.44 MB diskettes

The DOS BOOT disk will be used to boot another computer and install the DOS 'kernel' on it. Then, the install.bat will ask for the first of the 3 DOSFILES archive diskettes, and start unzipping them. You'll be prompted to insert the next disk etc. Nothing too it.

Have Fun.

	@echo off
	BREAK ON
	CLS
	echo.
	GOTO intro
	:MAIN
	ECHO You will need 3 empty 1.44 MB diskettes
	ECHO we recommand formatting them to make sure they're OK
	ECHO do you want to format 3 floppy disks now ?
	CHOICE /CYN 
	IF ERRORLEVEL == 2 GOTO skipformat
	GOTO formatt
	
	:SKIPFORMAT
	c:
	IF NOT EXIST C:\DOS\NUL ECHO C:\DOS not found
	IF NOT EXIST C:\DOS\pkzip.exe ECHO pkzip not found 
	IF NOT EXIST C:\DOS\pkunzip.exe ECHO pkunzip not found 
	IF NOT EXIST C:\DOS\install.bat ECHO install.bat not found
	ECHO OK to continue ?
	CHOICE /CYN
	IF ERRORLEVEL==2 GOTO END
	REM COPYING FILES to get started on other machine
	echo insert DOSDISK_1 again
	PAUSE
	sys c: a:
	a:
	copy c:\dos\fdisk.*
	copy c:\dos\format.*
	copy c:\dos\choice.*
	copy c:\dos\key*
	copy c:\config.sys
	copy c:\autoexec.bat
	copy c:\dos\pkunzip.exe
	
	ECHO edit autoexec.bat and config.sys for boot disk / new configuration
	CHOICE /CYN
	IF ERRORLEVEL==2 GOTO SKIPEDIT
	EDIT A:\AUTOEXEC.BAT
	EDIT A:\CONFIG.SYS
	
	:SKIPEDIT
	c:
	IF EXIST C:\DOS\install.bat GOTO NEXTSTEPS
	ECHO install.bat will not be copied to DOSISK_1
	ECHO you will need to execute all installation steps yourself
	GOTO ARCHIVE
	
	:NEXTSTEPS
	a:
	copy c:\dos\install.bat
	
	:ARCHIVE
	REM archiving C:\DOS folder
	ECHO you've now created a DOS BOOT diskette
	IF NOT EXIST C:\DOS\PKZIP.EXE GOTO NOZIP
	ECHO insert DOSDISK_1 in drive A:
	PAUSE
	c:
	pkzip -& -ex a:\dosfiles.zip c:\dos\*.* 
	ECHO done archiving C:\DOS
	GOTO END
	
	:NOZIP
	ECHO no PKWARE (pkzip, pkunzip) found
	ECHO you'll need to find another way to copy C:\DOS to the other computer
	GOTO END
	
	:FORMATT
	echo.
	echo have 3 diskettes ready, label them DOSDISK_1, DOSDISK_2, DOSDISK_3
	echo DOSDISK_1 will be your DOS BOOT disk
	PAUSE
	echo. > %temp%\reply
	echo N >> %temp%\reply
	echo insert DOSDISK_1
	PAUSE
	FORMAT /U /V:DOSDISK_1 A: < %temp%\reply
	echo insert DOSDISK_2
	PAUSE
	FORMAT /U /V:DOSDISK_2 A: < %temp%\reply
	echo insert DOSDISK_3
	PAUSE
	FORMAT /U /V:DOSDISK_3 A: < %temp%\reply
	DEL %temp%\reply > NUL
	GOTO SKIPFORMAT
	
	:INTRO
	ECHO.
	ECHO.
	ECHO.			SILLY SOFTWARE PRODUCTIONS
	ECHO.
	ECHO	           Create DOS Installation Disks at home
	ECHO.
	ECHO				-=oOo=-
	ECHO.
	ECHO.
	echo creating DOS installation disks
	echo assuming that dos files are in C:\DOS
	echo and that
	echo            pkzip.exe
	echo            pkunzip.exe
	echo            install.bat     (silly software DOS installation script)
	echo.
	echo are present in C:\DOS
	echo if that is not the case, uou may want to interrupt this program
	echo (use control-C or BREAK to interrupt)
	echo ---------------------------------------------------------------------
	echo.
	echo.
	GOTO MAIN
	
	:END
	c:
	echo finished creating DOS installation disks.
	echo insert DOS BOOT diskette in other machine and start it
	echo and type install 
	echo.
	echo Have Fun !
	echo.