program "KLANTEN"

dcl selindex#,selindex2#,selindex3#
dcl selnaam$=25,selnaam2$=25,selgem$=25
dcl aant%,tul%,telhist%,test6%,test%

dcl opm$=10,newkode$=8,pass$=1,vv$=1,loper$=1
dcl tabel$=8(25),tabopf$=15(25),tabhis$=16(25)
dcl totaal=6,totklan=6,zon4=6,zon5=6,saldo=6,dr=6(2)


dcl delhis$=16
field=m,delhis
dcl delnaam$=8,deldat$=6,deltel%
field=m

dcl bon1$=12
field=m,bon1
dcl bon2$=10,bon3$=2
field=m
dcl bon4,bon5

dcl testbnk$=14
field=m,testbnk
dcl testb1$=3,testbu$=1,testb2$=7,testbv$=1,testb3$=2,tstbnk$=7
field=m,tstbnk
dcl tstbon$=1(7)
field=m

dcl bon9$=12
field=m,bon9
dcl bon13$=3,bon23$=7,bon33$=2
field=m

dcl zon1$=9
field=m,zon1
dcl zon2$=7,zon3$=2
field=m

dcl testbtw$=11
field=m,testbtw
dcl testv1$=3,testpu$=1,testv2$=3,testpv$=1,testv3$=3
field=m

dcl tstbtw$=3
field=m,tstbtw
dcl tstzon$=1(3)
field=m

dcl btw9$=9
field=m,btw9
dcl btw13$=3,btw23$=3,btw33$=3
field=m

#INCLUDE  "CRINCLU"
#INCLUDE  "CRINCLU2"

assign=02,bestand(04),wr,si                 ;klantenbestand
assign=03,bestand(11),wr,si                 ;klantenhistoriek
assign=04,bestand(10),wr,si                 ;openstaande fakturen bestand
assign=05,bestand(15),wr,si                 ;bonbestand
assign=08,left(bestand(04),6)+"S",wr,si     ;sort klanten op naam
assign=09,left(bestand(04),3)+"TKL",wr,si
assign=12,bestand(01),wr,si                 ;rekeningen
assign=10,"GEMEEN",wr,si
assign=11,"GEMEEN2",wr,si
assign=12,bestand(01),wr,si                 ;rekeningen

open=2:&1,e
open=12:&1,e
open=9:&7,e
goto &8 
&7
cfile=9,d=70,lk=9
&8
open=8:&9,e
goto &10
&9 
cfile=8,lk=28
&10
open=3:&11,e
goto &14
&11
cfile=3,d=60,k=16
teller(07)=1
par(3)=param3

&14
vv=" "
totklan=0
totaal=0
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  BEHANDELING KLANTEN ",tab(70),ndat
print=1:paint(kl,0),tab(01,02),ltb,gener(77,hto),rtb
print=1:tab(01,03),vtb,tab(79),vte
print=1:tab(01,04),lto,gener(77,hto),rto,paint(kt,0)
print=1:tab(03,03),paint(kh,ka),"F1=Overzicht  F2=Fiche  F3=Opens facturen  F4=Voorschotten",paint(kt,0)
if phil=1 : goto  &60
&15
phil=0
print=1:tab(01,05),atb(22)
&16
ask=1,i=&1,u=&1,/80=&905,/81=&4000,/82=&3000,/83=&904,/84=&805,/85=&700,/8a=&22,/8b=&24:tab(01,05),"Geef klantenkode",esc,klkode,tab(32)=klkode
if klkode=" " : goto  &16
klkode=large(klkode)
if klkode=pwtest : goto  &680
search=2,klkode:&20,e,klrec
goto &60 
&20
ask=1,i=&15,u=&15,/8a=&22,/8b=&24,"nN"=&29:tab(01,24),paint(kh,ka),"Klant",ng,paint(kt,0)," ",paint(kh,ka),"N",paint(kt,0),"=nieuwe klant ",fvoor,voor,fvolg,volg=j
goto &15
&22
up=2:&23,e,kldown
goto &60
&23
print=1:tab(01,24),atb(21)
ask=1,i=&15,u=&15,/8b=&24:tab(01,24),paint(kh,ka),berb,paint(kt,0),fvolg,volg=j
goto &15
&24
down=2:&25,e,kldown
goto &60
&25
print=1:tab(01,24),atb(21)
ask=1,i=&15,u=&15,/8a=&22:tab(01,24),paint(kh,ka),bere,paint(kt,0),fvoor,voor=j
goto &15
&29
klrec=" "
kltego=0
kltbtw=0
klcred=0
klover=0
kljomz=0
klomzvj=0
klomz2j=0
klland="B"
kllbtw="BE.0"
klniet="N"
&60
print=1:tab(01,05),atb(22)
print=1:tab(01,05),"Klantenkode : ",klkode
print=1:tab(01,07),"Naam",tab(20),": ",paint(kh,ka),left(klnaam,len$(klnaam)),paint(kt,0),"."
print=1:tab(01,08),"Naam 2",tab(20),": ",kltwnaam,"."
print=1:tab(01,09),"Straat",tab(20),": ",klstra,"."
print=1:tab(01,10),"Gemeente",tab(20),": ",klgem,".",tab(50),klland,"."
print=1:tab(01,11),"Btwnummer",tab(20),": ",kllbtw,klbtwnr,"."
print=1:tab(01,12),"Telefoon",tab(20),": ",kltelef,"."
print=1:tab(01,13),"Fax",tab(20),": ",klfax,"."
print=1:tab(01,14),"Gsm",tab(20),": ",klgsm,"."
print=1:tab(01,16),"Banknummer",tab(20),": ",klbank,"."
print=1:tab(01,17),"Annulatie Y-N   ",tab(20),": ",klniet,"."
print=1:paint(kl,0),tab(01,18),gener(79,hto),paint(kt,0)
print=1:tab(01,19),"Jaaromzet",tab(20),": ",(-9.n2),kljomz
print=1:tab(40,19),"Vorig jaar",tab(60),": ",(-9.n2),klomzvj
print=1:tab(40,20),"2 jaar    ",tab(60),": ",(-9.n2),klomz2j
print=1:tab(01,20),"Totaal btw",tab(20),": ",(-9.n2),kltbtw-klcred
print=1:paint(kl,0),tab(01,21),gener(79,hto),paint(kt,0)
print=1:tab(01,22),"Totale tegoeden",tab(20),": ",(-9.n2),kltego
print=1:tab(01,23),"Totaal voorschot",tab(20),": ",(-9.n2),klover
print=1:tab(40,23),paint(kh,ka),"Saldo",paint(kt,0)," : ",(-9.n2),kltego-klover
print=1:tab(01,24),paint(kh,ka),"F6=bijkomende lijnen voor deze klant ",paint(kt,0)
&300
phil=0
ask=1,i=&15,u=&15,/80=&905,/81=&4000,/82=&3000,/85=&7000,/8a=&22,/8b=&24:tab(22,07)=klnaam
&301
print=1:tab(01,24),atb(21)
ask=1,i=&600,u=&300,/8a=&22,/8b=&24:tab(22,08)=kltwnaam
&302
ask=1,i=&600,u=&301,/8a=&22,/8b=&24:tab(22,09)=klstra
&303
print=1:tab(01,24),atb(21)
ask=1,i=&600,u=&302,/80=&2000,/81=&2500:tab(22,10)=klgem
if klgem=" " : goto  &303
klgem=large(klgem)
&310
print=1:tab(01,24),atb(21)
print=1:tab(01,24),paint(kh,ka),"Geef land",paint(kt,0)
ask=1,i=&600,u=&303,/8a=&2030,/8b=&2040:tab(50,10),klland,tab(50),(a)=klland
klland=large(klland)
&311
ask=1,i=&600,u=&310,/8a=&2030,/8b=&2040:tab(22,11),kllbtw,tab(22)=kllbtw
kllbtw=large(kllbtw)
&312
test6=0
ask=1,i=&600,u=&311,/8a=&2030,/8b=&2040:tab(26,11)=klbtwnr
if left(klbtwnr,1)="0" 
klbtwnr="000.000.000" 
goto &325
endif
if left(klbtwnr,1)="9" 
klbtwnr="999.999.999" 
goto &325
endif
&315
if len$(klbtwnr)=11 : goto  &318
if len$(klbtwnr)=9  : goto  &321
&317
print=1:tab(01,24),atb(21)
ask=1,i=&14,u=&14,/8a=&22,/8b=&24:tab(01,24),bell,paint(kh,ka),"Btw nummer niet in orde : ",paint(kt,0)," "=j
print=1:tab(01,24),atb(21)
goto &312
&318
testbtw=klbtwnr
tstbtw=testv1
gosub &319
if test6=1 : goto  &317
tstbtw=testv2
gosub &319
if test6=1 : goto  &317
tstbtw=testv3
gosub &319
if test6=1 : goto  &317
goto &322
&319
for i=1 to 3
if tstzon(i)<"0" : goto  &320
if tstzon(i)>"9" : goto  &320
next i
return
&320
test6=1
goto &317
&321
btw9=klbtwnr
testv1=btw13
testv2=btw23
testv3=btw33
testpu="."
testpv="."
klbtwnr=testbtw
goto &318
&322
btw13=testv1
btw23=testv2
btw33=testv3
zon1=btw9
zon4=conv(zon2)+conv(zon3)
zon5=mod(zon4,97)
if zon5<>0 : goto  &317
&325
print=1:tab(22,11),kllbtw,klbtwnr,"."
&328
print=1:tab(01,24),atb(21)
ask=1,i=&600,u=&312,/8a=&22,/8b=&24:tab(22,12)=kltelef
&329
ask=1,i=&600,u=&328,/8a=&22,/8b=&24:tab(22,13)=klfax 
&330
ask=1,i=&600,u=&329,/8a=&22,/8b=&24:tab(22,14)=klgsm 
&340
test=0
print=1:tab(01,24),atb(21)
ask=1,i=&600,u=&330,/8a=&22,/8b=&24:tab(22,16)=klbank
if klland="B" : goto  &341
if klland=" " : goto  &341
goto &360
&341
if len$(klbank)=14 : goto  &344
if len$(klbank)=12 : goto  &350
if klbank="0" 
testbnk="000-0000000-000"
endif
if klbank="9" 
testbnk="999-9999999-999"
endif
goto &359
&342
print=1:tab(01,24),atb(21)
ask=1,i=&14,u=&360,/8a=&22,/8b=&24:tab(01,24),bell,paint(kh,ka),"Banknummer niet in orde : ",paint(kt,0)," "=j
print=1:tab(01,24),atb(21)
goto &340
&344     ;bank op 14 posities
testbnk=klbank
tstbnk=testb1
aant=3
gosub &346
if test=1 : goto  &342
tstbnk=testb2
aant=7
gosub &346
if test=1 : goto  &342
tstbnk=testb3
aant=2
gosub &346
if test=1 : goto  &342
goto &352               ;test btw
&346    ;routine testen zones
for i=1 to aant
if tstbon(i)<"0" : goto  &347
if tstbon(i)>"9" : goto  &347
next i
return
&347
test=1
return
&350
bon9=klbank
testb1=bon13
testb2=bon23
testb3=bon33
testbu="-"
testbv="-"
klbank=testbnk
goto &344
&352
bon13=testb1
bon23=testb2
bon33=testb3
bon1=bon9
bon4=conv(bon2)-conv(bon3)
bon5=mod(bon4,97)
if bon5<>0 : goto  &342
&359
klbank=testbnk
print=1:tab(22,16),klbank
&360
print=1:tab(01,24),paint(kh,ka),"Annulatie klant in bonbestand Y-N : ",paint(kt,0),atb(21)
ask=1,i=&600,u=&340:tab(22,17)=klniet
klniet=large(klniet)
if klniet="Y" : goto  &380
if klniet="N" : goto  &380
goto &360
&380
if pass=" " : goto  &600
print=1:tab(01,18),atb(22)
print=1:tab(01,18),"Jaaromzet",tab(20),": ",(-8.n2),kljomz
print=1:tab(01,19),"Omzet vorig j.",tab(20),": ",(-8.n2),klomzvj
print=1:tab(01,20),"Voorschotten",tab(20),": ",(-8.n2),klover
print=1:tab(01,21),"Totaal Btw ",tab(60),": ",(-8.n2),kltbtw
print=1:tab(01,22),"Btw kredietnota",tab(20),": ",(-8.n2),klcred
&391
ask=1,i=&600,u=&600:tab(22,18),(-7z.n2)=kljomz
&393
ask=1,i=&600,u=&391:tab(22,19),(-7z.n2)=klomzvj
&395
ask=1,i=&600,u=&393:tab(22,20),(-7z.n2)=klover
&396
ask=1,i=&600,u=&395:tab(22,21),(-7z.n2)=kltbtw
&397
ask=1,i=&600,u=&396:tab(22,22),(-7z.n2)=klcred
&600
print=1:tab(01,24),atb(21)
&601
j=" "
ask=1,i=&14,u=&360,/80=&612,/8a=&22,/8b=&24:tab(01,24),paint(kh,ka),vali,paint(kt,0)," (A=annulatie)  ",paint(kh,ka),"F1",paint(kt,0),"=nieuw : "=j
j=large(j)
print=1:tab(01,24),atb(21)
if j="N" : goto  &14
if j="Y" : goto  &605
if j="A" : goto  &620
goto &601
&605
klkode2=klkode
insert=2,klkode:next,e,klrec
modif=2,klkode:next,e,klrec
sortnaam=klnaam
sortklant=klkode
insert=8,sortkode:&14,e
goto &14

&612
newkode=left(klnaam,5)
print=1:tab(01,24),atb(22)
ask=1,i=&600,u=&600,/80=&690:tab(01,24),"Geef nieuwe klantenkode (F1) : ",newkode,tab(32)=newkode 
if newkode=" " : goto &612
newkode=large(newkode)
klkode2=newkode
insert=2,newkode:&615,e,klrec
delete=2,klkode:&14,e
goto &14
&615

if e=81 
print=1:bell,tab(01,24),atb(21)
ask=1:tab(01,24),"Deze kode bestaat reeds "=j
goto &612
endif

print=1:tab(01,24),"Fout bijvoegen nieuwe kode : ",e," ",newkode
stop
&620
if kljomz<>0 : goto  &650
if kltbtw<>0 : goto  &650
if kltego<>0 : goto  &650
if klover<>0 : goto  &650
bonklant=klkode
bonnumer=0
search=5,bonkode:&630,e,bonrec
&630
down=5:&660,e,bondown
if bonklant=klkode : goto  &650
goto &660
&650
print=1:tab(01,24),atb(22)
ask=1,i=&14,u=&14,/80=&660:bell,tab(01,24),"Geen annulatie toegelaten voor deze klant : ",paint(kt,0)=e
goto &14
&660
delete=2,klkode:&670,e
goto &14
&670
if e=78 : goto  &14
print=1:tab(01,24),"Fout delete klant : ",e," ",klkode
stop

&680
pass="Y"
print=1:bell
goto &15 

&690
newkode=" "
print=1:tab(01,24),atb(22)
ask=1,i=&600,u=&600:tab(01,24),"Geef bijkomende klantenkode : "=newkode
newkode=large(newkode)
kljomz=0
klomzvj=0
klomz2j=0
klcred=0
klover=0
kltego=0
kltbtw=0
klkode2=newkode
insert=2,newkode:&690,e,klrec
goto &14

&700
dfile=8:&710,e
&710
cfile=8,lk=28:&14,e
&720
klkode=" "
search=2,klkode:&750,e,klrec
&750
down=2:&760,e,kldown
print=1:tab(01,24),klkode
sortnaam=klnaam
sortklant=klkode
insert=8,sortkode:&750,e
goto &750
&760
goto &15

&805
print=1:tab(01,05),atb(21)
l6=6
&806
print=1:tab(01,02),atb(21)
print=1:tab(01,03),atb(21)
print=1:tab(01,04),atb(21)
print=1:paint(kl,0),tab(20,02),ltb,gener(38,htb),rtb,tab(29),mtb,tab(40),mtb,tab(50),mtb
print=1:tab(20,04),lto,gener(38,hto),rto,tab(29),mto,tab(40),mto,tab(50),mto
print=1:tab(20,03),vtb,"        ",vtb,tab(40),vtb,"         ",vtb,tab(59),vte,paint(kt,0)
print=1:tab(22,03),paint(kh,ka),"Totaal",tab(42),"Klanten",paint(kt,0)
ask=1,i=&14,u=&14:tab(01,05),paint(kh,ka),"Overzicht van de klanten op naam :",paint(kt,0)," Geef beginkode overzicht : "=sortnaam
sortnaam=large(sortnaam)
print=1:tab(01,05),atb(22)
print=1:tab(01,05),paint(kh,ka),tab(03),"Nr",tab(08),"Kode",tab(19),"Naam",tab(46),"Gemeente",tab(72),"Saldo",paint(kt,0)
search=8,sortnaam:&807,e
goto &810
&807
down=8:&833,e,sortdown
&810
search=2,sortklant:&807,e,klrec
klkode=sortklant
print=1:tab(01,l6),paint(kn,ka),"  ",(n2),l6,(e)," ",paint(kt,ka2),"  ",klkode,"  ",paint(kt,ka3)," ",klnaam,"  ",paint(kt,ka4)," ",klgem,"  ",paint(kn,ka5),(-6.n2),kltego-klover,paint(kt,0)
tabel(l6)=sortklant
&812
totaal=totaal+kltego-klover
totklan=totklan+1
print=1:tab(30,03),(-9),totaal,tab(52),(-5),totklan
l6=l6+1
if l6<22 : goto  &807
&813
i=0
ask=1,i=&14,u=&14:tab(01,24),paint(kh,ka),bla,paint(kt,0),num,ret,esc,(n2)=i
if i<6 : goto  &814
if i>l6-1 : goto  &814
klkode=tabel(i)
search=2,klkode:&814,e,klrec
phil=1
goto &14
&814
for l6=6 to 24
tabel(l6)=" "
next l6
print=1:tab(01,06),atb(22)
l6=6
goto &807
&833
i=0
ask=1,i=&14,u=&14:tab(01,24),paint(kh,ka),bere,paint(kt,0),num,ret,esc,(n2)=i
if i<6 : goto  &14
if i>l6-1 : goto  &14
search=2,klkode:&14,e,klrec
phil=1
goto &14

&904
vv="1" 
goto &905
&905
totaal=0
totklan=0
klkode=" "
l6=6
print=1:tab(01,02),atb(22)
print=1:paint(kl,0),tab(20,02),ltb,gener(38,htb),rtb,tab(29),mtb,tab(40),mtb,tab(50),mtb
print=1:tab(20,04),lto,gener(38,hto),rto,tab(29),mto,tab(40),mto,tab(50),mto
print=1:tab(20,03),vtb,"        ",vtb,tab(40),vtb,"         ",vtb,tab(59),vte,paint(kt,0)
print=1:tab(22,03),paint(kh,ka),"Totaal",tab(42),"Klanten",paint(kt,0)
&906
print=1:tab(01,05),atb(22)
ask=1,i=&14,u=&14:tab(01,05),paint(kh,ka),"Overzicht van de klanten :",paint(kt,0)," Geef beginkode overzicht : ",klkode,tab(55)=klkode
klkode=large(klkode)
print=1:tab(01,05),atb(22)
print=1:tab(01,05),paint(kh,ka),tab(03),"Nr",tab(08),"Kode",tab(19),"Naam",tab(46),"Gemeente",tab(72),"Saldo",paint(kt,0)
search=2,klkode:&907,e,klrec
goto &908
&907    
down=2:&933,e,kldown
&908
if vv<>"1" 
print=1:tab(01,l6),paint(kn,ka),"  ",(n2),l6,(e)," ",paint(kt,ka2),"  ",klkode,"  ",paint(kt,ka3)," ",left(klnaam,25)," ",paint(kt,ka4)," ",klgem," ",paint(kn,ka5),(-6.n2),kltego-klover,paint(kt,0)
totaal=totaal+kltego-klover
goto &912
endif

if klover=0 : goto  &907
print=1:tab(01,l6),paint(kn,ka),"  ",(n2),l6,(e)," ",paint(kt,ka2),"  ",klkode,"  ",paint(kt,ka3)," ",left(klnaam,25)," ",paint(kt,ka4)," ",klgem," ",paint(kn,ka5),(-6.n2),klover,paint(kt,0)
totaal=totaal+klover
&912
tabel(l6)=klkode
totklan=totklan+1
print=1:tab(30,03),(-7.n2),totaal,tab(52),(-5),totklan
sortnaam=klnaam
sortklant=klkode
insert=8,sortkode:next,e
l6=l6+1
if l6<22 : goto  &907
&915
i=0
ask=1,i=&14,u=&14:tab(01,24),paint(kh,ka),bla,paint(kt,0),num,ret,esc,(n2)=i
&920
if i<6 : goto  &925
if i>l6-1 : goto  &925
klkode=tabel(i)
search=2,klkode:&925,e,klrec
phil=1
goto &14
&925
print=1:tab(01,06),atb(22)
l6=6
goto &907
&933
i=0
ask=1,i=&14,u=&14:tab(01,24),paint(kh,ka),bere,paint(kt,0),num,ret,esc,(n2)=i
&935
if i<6 : goto  &940
if i>l6-1 : goto  &940
klkode=tabel(i)
search=2,klkode:&925,e,klrec
phil=1
&940
goto &14

&2000
print=1:tab(01,24),atb(21)
print=1:tab(01,24),paint(kh,ka),"Opzoeken van postnummer",paint(kt,0)
ask=1,i=&600,u=&303,/81=&2500:tab(22,10)=postnum
posttel=0
search=10,postkode:&2010,e,postrec
goto &2090
&2010
print=1:tab(01,24),atb(21)
ask=1,i=&303,u=&303,/8a=&2030,/8b=&2040:tab(01,24),paint(kh,ka),"Postnummer",ng,paint(kt,0),fvoor,voor,fvolg,volg=j
goto &303 
&2030
up=10:&2060,e,postdown
goto &2090
&2040
down=10:&2070,e,postdown
goto &2090
&2060
print=1:tab(01,24),atb(21)
ask=1,i=&303,u=&303,/80=&2500,/8b=&2040:tab(01,24),paint(kh,ka),berb,paint(kt,0),fvolg,volg=j
goto &303 
&2070
print=1:tab(01,24),atb(21)
ask=1,i=&303,u=&303,/80=&2500,/8a=&2030:tab(01,24),paint(kh,ka),bere,paint(kt,0),fvoor,voor=j
goto &303 
&2090
klgem=postnum+" "+postrec 
print=1:tab(01,24),atb(21)
ask=1,i=&303,u=&303,/8a=&2030,/8b=&2040:tab(01,24),paint(kh,ka),fvoor,paint(kt,0),voor,paint(kh,ka),fvolg,paint(kt,0),volg,esc,tab(22,10),klgem,tab(45,24)=j
goto &303 

&2500
print=1:tab(01,24),atb(21)
print=1:tab(01,24),paint(kh,ka),"Opzoeken van gemeente",paint(kt,0)
ask=1,i=&600,u=&303,/80=&2000:tab(22,10)=gem
gem=large(gem)
gemtel=0
search=11,gemkode:&2520,e,gemrec
goto &2590
&2520
print=1:tab(01,24),atb(21)
ask=1,i=&303,u=&303,/8a=&2530,/8b=&2540:tab(01,24),atb(21),tab(01,24),paint(kh,ka),"Gemeente",ng,paint(kt,0),fvoor,voor,fvolg,volg=j
goto &303 
&2530
up=11:&2560,e,gemdown
goto &2590
&2540
down=11:&2570,e,gemdown
goto &2590
&2560
print=1:tab(01,24),atb(21)
ask=1,i=&303,u=&303,/8b=&2540:tab(01,24),paint(kh,ka),berb,paint(kt,0),fvolg,volg=j
goto &303 
&2570
print=1:tab(01,24),atb(21)
ask=1,i=&303,u=&303,/8a=&2530:tab(01,24),paint(kh,ka),bere,paint(kt,0),fvoor,voor=j
goto &303 
&2590
klgem=gemrec+" "+gem
print=1:tab(01,24),atb(21)
ask=1,i=&303,u=&303,/8a=&2530,/8b=&2540:tab(01,24),paint(kh,ka),fvoor,paint(kt,0),voor,paint(kh,ka),fvolg,paint(kt,0),volg,esc,tab(22,10),klgem,tab(45,24)=j
goto &303 

&3000  ;openstaande fakturen 
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  OPENSTAANDE FAKTUREN  ",tab(70),ndat
print=1:paint(kl,0),tab(01,02),gener(79,hto),paint(kt,0)
&3001
print=1:tab(01,05),atb(22)
&3002
ask=1,i=&14,u=&14,/81=&4000,/8a=&3005,/8b=&3007:tab(01,05),"Geef klantenkode",esc,klkode,tab(32)=klkode
if klkode=" " : goto  &3002
klkode=shl(klkode)
klkode=large(klkode)
search=2,klkode:&3003,e,klrec
goto &3020
&3003
print=1:tab(01,24),atb(21)
ask=1,i=&3001,u=&3001,/8a=&3005,/8b=&3007:tab(01,24),paint(kh,ka),"Klant",ng,paint(kt,0),fvoor,voor,fvolg,volg=j
goto &3001
&3005
up=2:&3006,e,kldown
goto &3020
&3006
print=1:tab(01,24),atb(21)
ask=1,i=&3000,u=&3000,/8b=&3007:tab(01,24),paint(kh,ka),berb,paint(kt,0),fvolg,volg=j
goto &3000
&3007
down=2:&3008,e,kldown
goto &3020
&3008
print=1:tab(01,24),atb(21)
ask=1,i=&3000,u=&3000,/8a=&3005:tab(01,24),paint(kh,ka),bere,paint(kt,0),fvoor,voor=j
goto &3000
&3020
l6=6
gosub &5000
gosub &5500    ;sublijn
for e=1 to 17
tabopf(e)=" "
next e
fakkllv="K"
fakname=klkode
fakfak=" "
totaal=0
search=4,fakkode:&3030,e,fakrec
&3030
down=4:&3035,e,fakdown
if fakname<>klkode : goto  &3035
print=1:tab(01,l6),paint(kn,ka)," ",(n2),l6-5,(e)," ",paint(kt,ka2)," ",fakdat,"  ",paint(kn,ka3),shr(faknum)," ",paint(kn,ka4)," ",fakverv," ",paint(kn,ka5),(-7.n2),faktebe,(e)," ",paint(kn,ka),(-7.n2),fakont,(e)," ",paint(kn,ka2),(-7.n2),faktebe-fakont,(e)," ",tab(66),paint(kt,ka3)," ",(u12),fakoms
totaal=totaal+faktebe-fakont
tabopf(l6-5)=fakkode
l6=l6+1
if l6>22 : goto  &3100  ;blad volzet
goto &3030
&3035
kltego=totaal
modif=2,klkode:&3040,e,klrec
&3040
print=1:tab(01,23),atb(22)
print=1:tab(01,23),"Totaal te betalen : ",(-9.n2),kltego
print=1:tab(46,23),"Voorschotten : ",(-9.n2),klover
print=1:tab(01,24),paint(kh,ka),"S a l d o         : ",paint(kt,0),(-9.n2),kltego-klover
j=" " 
ask=1,i=&3000,u=&3000,/8a=&3005,/8b=&3007,/80=&4900,"bB"=&4900,"sS"=&3200:tab(35,24),fvoor,voor,fvolg,volg=j
goto &3000
&3100   
j=" " 
print=1:tab(01,24),atb(21)
ask=1,i=&3000,u=&3000,/8a=&3005,/8b=&3007,/80=&4900,"bB"=&4900,"sS"=&3200:tab(01,24),paint(kh,ka),bla,paint(kt,0),ret=j
&3105
for e=1 to 24
tabopf(e)=" "
next e
gosub &5000
gosub &5500
l6=6
goto &3030

&3200
dfile=14:&3205,e
&3205
cfile=14,d=80,lk=15
&3210
fakkllv="K"
fakname=klkode
fakfak=" "
search=4,fakkode:&3230,e,fakrec
&3230
down=4:&3235,e,fakdown
if fakname<>klkode : goto  &3235
fakfak=right(fakdat,2)+substr(fakdat,4,2)+left(fakdat,2)
insert=14,fakkode:&3231,e,fakrec
goto &3230
&3231
print=1:tab(01,24),"Fout insert fakkode : ",(-3),e
stop
&3235
fakkllv="K"
fakname=klkode
fakfak=" "
search=4,fakkode:&3236,e,fakrec
&3236
down=4:&3239,e,fakdown
if fakname<>klkode : goto  &3239
delete=4,fakkode:&3236,e
goto &3236
&3239
open=14:&3020,e
&3240
down=14:&3020,e,fakdown
print=1:tab(01,24),fakkllv," ",fakname," ",fakfak
insert=4,fakkode:&3240,e,fakrec
goto &3240

&4000    ;routine historiek
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  KLANTENFICHE - HISTORIEK ",tab(70),ndat
print=1:paint(kl,0),tab(01,02),gener(79,hto),paint(kt,0)
&4001
print=1:tab(01,05),atb(22)
&4002
ask=1,i=&14,u=&14,/82=&3000,/8a=&4005,/8b=&4007:tab(01,05),"Geef klantenkode",esc,klkode,tab(32)=klkode
if klkode=" " : goto  &4002
klkode=shl(klkode)
klkode=large(klkode)
search=2,klkode:&4003,e,klrec
goto &4020
&4003
print=1:tab(01,24),atb(21)
ask=1,i=&4001,u=&4001,/8a=&4005,/8b=&4007:tab(01,24),paint(kh,ka),"Klant",ng,paint(kt,0),fvoor,voor,fvolg,volg=j
goto &4001
&4005
up=2:&4006,e,kldown
goto &4020
&4006
print=1:tab(01,24),atb(21)
ask=1,i=&4001,u=&4001,/8b=&4007:tab(01,24),paint(kh,ka),berb,paint(kt,0),fvolg,volg=j
goto &4001
&4007
down=2:&4008,e,kldown
goto &4020
&4008
print=1:tab(01,24),atb(21)
ask=1,i=&4001,u=&4001,/8a=&4005:tab(01,24),paint(kh,ka),bere,paint(kt,0),fvoor,voor=j
goto &4000
&4020     
histdat=" "
gosub &5000
gosub &5600
loper="O"
GOTO &4021
ask=1,i=&4000,u=&4000,/8a=&4005,/8b=&4007:tab(01,24),"Geef lopersekwentie ",paint(kh,ka),"N",paint(kt,0),"=normaal  ",paint(kh,ka),"O",paint(kt,0),"=omgekeerd : ",loper," : "=loper
loper=large(loper)
if loper="N" : goto  &4022
if loper="O" : goto  &4021
goto &4020
&4021
histdat="ZZZZZZ"
&4022
for e=1 to 24
tabhis(e)=" "
next e
saldo=0
l6=6
&4025
hisnaam=klkode
search=3,hiskode:&4030,e,kllvhis
&4030
for i=1 to 2
dr(i)=0
next i
opm=" "
if loper="O" : goto  &4035
down=3:&4300,e,hisdown
goto &4040
&4035
up=3:&4300,e,hisdown
&4040
if hisnaam<>klkode : goto  &4300
if hiskod1="V" : goto  &4070
if hiskod1="F" : goto  &4075
goto &4080
&4070
dr(1)=hisbed1
saldo=saldo+hisbed1
hisbed2=hisbtw
if hisbed2=0 : goto  &4090
opm="Btw"
goto &4090
&4075 
dr(2)=hisbed1
if hiskod2="+" : goto  &4076
saldo=saldo-hisbed1
goto &4077
&4076
saldo=saldo+hisbed1
&4077
opm=" "
rekkode=shl(large(hisbetw))
search=12,hisbetw:&4080,e,rekrec
opm=large(rekoms)
&4080
if hiskod2="T" : goto  &4081
if hiskod2="K" : goto  &4082
if hiskod2="I" : goto  &4083
if hiskod2="V" : goto  &4084
if hiskod2="X" : goto  &4085
if hiskod2="+" : goto  &4086
if hiskod2="-" : goto  &4087
if hiskod2=" " : goto  &4088
goto &4090
&4081
opm="Teveel"
goto &4090
&4082
opm="Korting"
goto &4090
&4083
opm="Intrest" 
goto &4090
&4084
opm="Koersv"
goto &4090
&4085
opm="Bet.verschil"
goto &4090
&4086 
opm="Terug"
goto &4090
&4087
opm="Voorschot"
goto &4090
&4088
&4090
print=1:tab(01,l6),paint(kn,ka)," ",(n2),l6-5,(e)," ",paint(kt,ka2)," ",hisdat," ",paint(kn,ka3),shr(hisfakt)," ",paint(kn,ka4),(-7.n2),dr(1),(e)," ",paint(kn,ka5),(-7.n2),dr(2)
print=1:(e),paint(kn,ka)," ",hisbetw," ",paint(kn,ka2),(-7.n2),hisbed2,(e)," ",paint(kt,ka3),left(opm,6)," ",paint(kn,ka4),(-7.n2),dr(1)-hisbed2,paint(kt,0)
tabhis(l6-5)=hiskode
l6=l6+1
if l6>22 : goto  &4200    
goto &4030
&4200
j=" " 
print=1:tab(01,23),atb(22)
print=1:tab(50,23),paint(kh,ka),"Saldo : ",paint(kt,0),(-8.n2),kltego-klover,saldo
ask=1,i=&4000,u=&4000,/8a=&4005,/8b=&4007,/80=&4800,"tT"=&4400,"bB"=&4800:tab(01,24),paint(kh,ka),bla,paint(kt,0),ret,paint(kh,ka),"T",paint(kt,0),"=vorig blad : "=j
l6=6
gosub &5000
gosub &5600
for e=1 to 17
tabhis(e)=" "
next e
goto &4030
&4300
j=" " 
print=1:tab(01,22),atb(22)
print=1:tab(50,23),paint(kh,ka),"Saldo : ",paint(kt,0),(-8.n2),kltego-klover,saldo
ask=1,i=&4000,u=&4000,/8a=&4005,/8b=&4007,/80=&4800,"tT"=&4400,"bB"=&4800:tab(01,24),paint(kh,ka),"Einde historiek : ",paint(kt,0),ret,paint(kh,ka),"T",paint(kt,0),"=vorig blad : "=j
goto &4000
&4400       ;routine einde blad en terug keren
if loper="N" : goto  &4410
loper="N"
goto &4420
&4410
loper="O"
&4420
print=1:tab(01,06),atb(22)
for e=1 to 17
tabhis(e)=" " 
next e
l6=6
goto &4030

&4800
print=1:tab(01,23),atb(21)
print=1:tab(01,01),paint(kh,ka),space(79),tab(01)," MANIPULATIE VAN DE HISTORIEKEN",tab(70),ndat,tab(79)," ",paint(kt,0)
for e=1 to 17
if tabhis(e)=" " : goto  &4805
l6=e    
print=1:tab(02,e+5),paint(kh,ka),(--),e,paint(kt,0) 
next e
&4805
lijntel=0
print=1:tab(01,24),atb(21)
ask=1,i=&4000,u=&4000,"bB"=&4860,/80=&4860:tab(01,24),"Geef lijnnummer te veranderen : "=lijntel
if lijntel<1 : goto  &4805
if lijntel>l6 : goto  &4805
hiskode=tabhis(lijntel)
&4806
search=3,hiskode:&4807,e,kllvhis
print=1:tab(01,06),atb(22)
goto &4809
&4807
print=1:tab(01,24),"Fout search hiskode : ",e," ",hiskode
stop
&4809
print=1:tab(01,06),"Datum faktuur",tab(20),": ",hisdat,"."
print=1:tab(01,07),"Kode F-L-A-V",tab(20),": ",hiskod1,"."
print=1:tab(01,08),"Bedrag 1     ",tab(20),": ",(-8.n2),hisbed1
print=1:tab(01,09),"Btw bedrag",tab(20),": ",(-8.n2),hisbtw
print=1:tab(01,10),"Kode T-I-K-V ",tab(20),": ",hiskod2,"."
print=1:tab(01,11),"Bedrag 2     ",tab(20),": ",(-8.n2),hisbed2
print=1:tab(01,12),"Kode histor.",tab(20),": ",hiskllv,"."
print=1:tab(01,13),"Factuurnummer",tab(20),": ",hisfakt,"."
print=1:tab(01,14),"Betaalwijze  ",tab(20),": ",hisbetw,"."
print=1:tab(01,15),"Omschrijving",tab(20),": ",hisoms,"."
print=1:paint(kl,0),tab(01,17),gener(79,hto),paint(kt,0)
goto &4812
&4810
print=1:tab(01,18),atb(22)
up=3:&4000,e,hisdown
if hisnaam<>klkode : goto  &4000
goto &4809
&4811
print=1:tab(01,18),atb(22)
down=3:&4000,e,hisdown
if hisnaam<>klkode : goto  &4000
goto &4809
&4812
delhis=hiskode
ask=1,i=&4834,u=&4834,/8a=&4810,/8b=&4811:tab(22,06)=hisdat
histdat=right(hisdat,2)+substr(hisdat,4,2)+left(hisdat,2)
&4814
ask=1,i=&4834,u=&4812:tab(22,07)=hiskod1
hiskod1=large(hiskod1)
&4816
ask=1,i=&4834,u=&4814:tab(22,08)=hisbed1
&4818
ask=1,i=&4834,u=&4816:tab(22,09)=hisbtw
&4820
ask=1,i=&4834,u=&4818:tab(22,10)=hiskod2
hiskod2=large(hiskod2)
&4822
ask=1,i=&4834,u=&4820:tab(22,11)=hisbed2
&4824
ask=1,i=&4834,u=&4822:tab(22,12)=hiskllv
hiskllv=large(hiskllv)
hisnaam=hiskllv
&4826
ask=1,i=&4834,u=&4824:tab(22,13)=hisfakt
&4828
ask=1,i=&4834,u=&4826:tab(22,14)=hisbetw
&4830
ask=1,i=&4834,u=&4828:tab(22,15)=hisoms
hisoms=large(hisoms)
&4834
j=" "
ask=1,i=&4000,u=&4830,/8a=&4810,/8b=&4811,/80=&4835:tab(01,19),vali," (A=annulatie) : "=j
j=large(j)
if j="A" : goto  &4846
if j<>"Y" : goto  &4811
delete=3,delhis:&4835,e
&4835
insert=3,hiskode:&4845,e,kllvhis
goto &4850
&4845
histel=histel+1
goto &4835
&4846
delete=3,hiskode:&4847,e
&4847
print=1:tab(01,06),atb(22)
goto &4021
&4850
teller(07)=teller(07)+1       ;aanpassen historieken teller
par(3)=param3
goto &4000
&4860
hiskode=klkode 
search=3,hiskode:&4865,e,kllvhis
&4865
down=3:&4000,e,hisdown
if hisnaam<>klkode : goto  &4000
delete=3,hiskode:&4865,e
&4866
hisnaam=klkode
histdat=right(hisdat,2)+substr(hisdat,4,2)+left(hisdat,2)
histel=0
&4870
insert=3,hiskode:&4875,e,kllvhis 
goto &4865
&4875
histel=histel+1
goto &4870

&4900
print=1:tab(01,01),paint(kh,ka),space(79),tab(01)," MANIPULATIE VAN DE OPENSTAANDE FAKTUREN ",tab(70),ndat,tab(79)," ",paint(kt,0)
for e=1 to 17
if tabopf(e)=" " : goto  &4905
l6=e
print=1:tab(02,e+5),paint(kh,ka),(--),e,paint(kt,0)
next e
&4905
lijntel=0
print=1:tab(01,24),atb(21)
&4906
ask=1,i=&3000,u=&3000:tab(01,24),"Geef lijnnummer te veranderen : "=lijntel
if lijntel=0 : goto  &4906
fakkode=tabopf(lijntel)
search=4,fakkode:&4905,e,fakrec
print=1:tab(01,06),atb(22)
&4910
faknum=shr(faknum)
print=1:tab(01,06),"Datum faktuur",tab(20),": ",fakdat,".    ",faktest," ",fakteba
print=1:tab(01,07),"Vervaldatum  ",tab(20),": ",fakverv,"."
print=1:tab(01,08),"Klantenkode  ",tab(20),": ",faknaam,"."
print=1:tab(01,09),"Omschrijving ",tab(20),": ",fakoms,"."
print=1:tab(01,10),"Factuurnummer",tab(20),": ",faknum,"."
print=1:tab(01,11),"Te betalen   ",tab(20),": ",(-8.n2),faktebe
print=1:tab(01,12),"Reeds betaald",tab(20),": ",(-8.n2),fakont
print=1:tab(20,13),"ÄÄÄÄÄÄÄÄÄÄÄÄ"
print=1:tab(01,14),"Saldo        ",tab(20),": ",(-8.n2),faktebe-fakont
print=1:paint(kl,0),tab(01,16),gener(79,hto),paint(kt,0)
&4912
ask=1,i=&3000,u=&3000,/8a=&4955,/8b=&4950:tab(22,06)=fakdat
&4914
ask=1,i=&4924,u=&4912:tab(22,07)=fakverv
&4915
ask=1,i=&4924,u=&4914:tab(22,08)=faknaam
faknaam=large(faknaam)
&4916
ask=1,i=&4924,u=&4915:tab(22,09)=fakoms
fakoms=large(fakoms)
&4918
ask=1,i=&4924,u=&4916:tab(22,10)=faknum
faknum=shr(faknum)
&4920
ask=1,i=&4924,u=&4918:tab(22,11)=faktebe
&4922
ask=1,i=&4924,u=&4920:tab(22,12)=fakont
&4924
j=" "
print=1:tab(01,18),atb(21)
ask=1,i=&3000,u=&3000,/80=&4926:tab(01,18),vali," (A=annulatie) : "=j
j=large(j)
if j="A" : goto  &4925
if j<>"Y" : goto  &4950
modif=4,fakkode:&4950,e,fakrec
goto &4950
&4925
delete=4,fakkode:&4950,e
goto &4950
&4926
fakkllv="K"
fakname=faknaam 
fakfak=shr(faknum)
insert=4,fakkode:&4927,e,fakrec
teller(05)=teller(05)+1
par(3)=param3
goto &4950
&4927
modif=4,fakkode:&4950,e,fakrec
&4950
down=4:&3000,e,fakdown
&4951
if fakname<>klkode : goto  &3000
goto &4910
&4955
up=4:&3000,e,fakdown
goto &4951

&5000
print=1:clear,paint(kl,0),ltb,gener(77,hto),rtb
print=1:tab(01,02),vte,tab(79),vte
print=1:tab(01,03),vtb,gener(77,hto),vte,paint(kt,0)
print=1:tab(03,02),paint(kh,ka),klnaam,paint(kt,0)
return
&5500
print=1:paint(kl,0),tab(01,04),vtb,tab(79),vte
print=1:tab(01,05),lto,gener(77,hto),rto,paint(kt,0)
print=1:tab(06,04),paint(kh,ka),"Datum",tab(16),"Factuur",tab(24),"Vervald.",tab(34),"Totaal",tab(46),"Betaald",tab(57),"Saldo",tab(67),"Omschrijv.",paint(kt,0)
return
&5600
print=1:paint(kl,0),tab(01,04),vtb,tab(79),vte
print=1:tab(01,05),lto,gener(77,hto),rto,paint(kt,0)
print=1:tab(06,04),paint(kh,ka),"Datum",tab(16),"Factuur",tab(25),"Verkoop",tab(36),"Financ",tab(44),"Reken.",tab(53),"Bedrag",tab(62),"Opm",tab(72),"Netto",paint(kt,0)
return

&7000
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  BIJKOMEND SCHERM VOOR : ",klnaam
print=1:paint(kl,0),tab(01,02),ltb,gener(77,hto),rtb,tab(06),mtb
for tektel=1 to 20
print=1:tab(01,tektel+2),vte,tab(06),vte,tab(79),vte
next tektel
print=1:tab(01,23),lto,gener(77,hto),rto,tab(06),mto,paint(kt,0)
tektyp=klkode 
&7001
for tektel=1 to 20
tekrec=" "
search=9,tekkode:&7002,e,tekrec
&7002
print=1:tab(02,tektel+2),(-3),tektel,(e),tab(08),(u70),tekrec
next tektel
&7100
tektel=1
&7101
if tektel<1 : goto  &14   
if tektel>20 : goto  &14   
tekrec=" "
search=9,tekkode:&7102,e,tekrec
&7102
ask=1,i=&14,u=&7106:tab(08,tektel+2)=tekrec
&7103
insert=9,tekkode:&7104,e,tekrec
goto &7105
&7104
modif=9,tekkode:&7105,e,tekrec
&7105
tektel=tektel+1
goto &7101
&7106
tektel=tektel-1
goto &7101
eseg 0

segment 200
test1=conv(right(dat,2))
test1=test1+1900
if test1>1950 : goto  &10
test1=test1+100
&10
test1=test1*372
test2=conv(substr(dat,4,2))
test2=test2*31
test1=test1+test2
test2=conv(left(dat,2))
test1=test1+test2
ret.seg
eseg 200
end