program "LEVERANCIERS"

dcl buffer$=60,htel$=15,telh#,v#,f#,f1#,f2#,t%,r1#
dcl zon4=6,zon5=6,test#,saldo=6,bon4=6,bon5=6,aant%,telhist%,lees%,bl%,o%
dcl selindex%,dr=6(2),totaal=6,totlev=6,sall=6
dcl tabopf$=15(25),selzoek$=10,newkode$=8,vindrek$=6
dcl pass$=1,tabel$=8(25),tabhis$=16(25),vv$=1,opm$=14,loper$=1

dcl delhis$=16
field=m,delhis
dcl delnaam$=8,deldat$=6,deltel%
field=m

dcl bon1$=12
field=m,bon1
dcl bon2$=10,bon3$=2
field=m

dcl testbnk$=14
field=m,testbnk
dcl testb1$=3,testbu$=1,testb2$=7,testbv$=1,testb3$=2
field=m

dcl tstbnk$=7
field=m,tstbnk
dcl tstbon$=1(7)
field=m

dcl bon9$=12
field=m,bon9
dcl bon13$=3,bon23$=7,bon33$=2
field=m

dcl zon1$=9
field=m,zon1
dcl zon2$=7,zon3$=2
field=m

dcl testbtw$=11
field=m,testbtw
dcl testv1$=3,testpu$=1,testv2$=3,testpv$=1,testv3$=3
field=m

dcl tstbtw$=3
field=m,tstbtw
dcl tstzon$=1(3)
field=m

dcl btw9$=9
field=m,btw9
dcl btw13$=3,btw23$=3,btw33$=3
field=m

#INCLUDE  "CRINCLU"
#INCLUDE  "CRINCLU2"

assign=02,bestand(03),wr,si                 ;leveranciersbestand
assign=03,bestand(01),wr,si                 ;rekeningenbestand
assign=04,bestand(10),wr,si                 ;openstaande fakturen
assign=05,bestand(12),wr,si                 ;historiek leveranciers
assign=09,left(bestand(03),3)+"TLV",wr,si   ;bijkomend scherm leveranciers
assign=10,"GEMEEN",wr,si
assign=11,"GEMEEN2",wr,si
assign=14,left(bestand(10),6)+"S",wr,si     ;sort openstaande fakturen
open=2
open=3
open=4
open=5
&7
open=9:&8,e
goto &10 
&8
cfile=9,d=70,lk=9
goto &10
&9 
pass="Y"
print=1:bell
goto &15

&10
vv=" "
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  BEHANDELING LEVERANCIERS ",tab(70),ndat
print=1:paint(kl,0),tab(01,02),ltb,gener(77,hto),rtb
print=1:tab(01,03),vtb,tab(79),vte
print=1:tab(01,04),lto,gener(77,hto),rto,paint(kt,0)
print=1:tab(03,03),paint(kh,ka),"F1=Overzicht  F2=Fiche  F3=Openst facturen  F4=Voorschotten",paint(kt,0)
&15
print=1:tab(01,05),atb(22)
if phil=1 : goto  &40
&16
ask=1,i=&1,u=&1,/80=&905,/81=&4000,/82=&3000,/83=&904,/8a=&22,/8b=&24:tab(01,05),"Geef leverancierskode",esc,levkode,tab(37)=levkode
levkode=large(levkode)
if levkode=pwtest : goto  &9
if levkode=" " : goto  &16 
search=2,levkode:&20,e,levrec
goto &40
&20
if e=74 : goto  &16
ask=1,i=&15,u=&15,/8a=&22,/8b=&24:tab(01,24),paint(kh,ka),"Leverancier",ng,paint(kt,0)," ",paint(kh,ka),"N",paint(kt,0),"=nieuwe  ",fvoor,voor,fvolg,volg=j
j=large(j)
if j="N" : goto  &29
goto &15
&22
up=2:&23,e,levdown
goto &40
&23
if e=74 : goto  &22
print=1:tab(01,24),atb(21)
ask=1,i=&15,u=&15,/8b=&24:tab(01,24),paint(kh,ka),berb,paint(kt,0),fvolg,volg=j
goto &15
&24
down=2:&25,e,levdown
goto &40
&25
if e=74 : goto  &24
print=1:tab(01,24),atb(21)
ask=1,i=&15,u=&15,/8a=&22:tab(01,24),paint(kh,ka),bere,paint(kt,0),fvoor,voor=j
goto &15
&29
levrec=" "
levnaam="."
levjomz=0
levvj=0
levtbtw=0
levmede=0
levtebe=0
levvoor=0
levbest=0
levkort=0
rekoms=" "
&40
phil=0
gosub &8000
&300 
ask=1,i=&15,u=&15,/81=&4000,/82=&3000,/85=&7000,/8a=&22,/8b=&24:tab(22,07)=levnaam
&305
ask=1,i=&600,u=&300,/8a=&22,/8b=&24:tab(22,08)=levstraa
&310
print=1:tab(01,24),atb(21)
ask=1,i=&600,u=&305,/80=&2000,/81=&2500:tab(22,09)=levgem
if levgem=" " : goto  &310
&315
print=1:tab(01,24),atb(21)
ask=1,i=&600,u=&310,/8a=&22,/8b=&24:tab(72,09)=levland
if levland=" " : goto  &315
levland=large(levland)
if levland<>"B" : goto &316
levlbtw="BE.0"
&316
test=0
ask=1,i=&600,u=&315,/8a=&22,/8b=&24:tab(22,10),levlbtw,tab(22)=levlbtw
levlbtw=large(levlbtw)
ask=1,i=&600,u=&316,/8a=&22,/8b=&24:tab(26,10)=levbtw
if len$(levbtw)=11 : goto  &318
if len$(levbtw)=9 : goto  &321


if left(levbtw,1)="0" 
levbtw="000.000.000"
goto &324         
endif

if left(levbtw,1)="9" 
levbtw="999.999.999"
goto &324         
endif

&317
ask=1,i=&15,u=&15,/8a=&22,/8b=&24:tab(01,24),bell,paint(kh,ka),"Btw nummer niet in orde : ",paint(kt,0)," "=j
print=1:tab(01,24),atb(21)
goto &316
&318     ;btw nummer op 11 posities
testbtw=levbtw
tstbtw=testv1
gosub &319
if test=1 : goto  &317
tstbtw=testv2
gosub &319
if test=1 : goto  &317
tstbtw=testv3
gosub &319
if test=1 : goto  &317
goto &322               ;test btw
&319    ;routine testen zones
for i=1 to 3
if tstzon(i)<"0" : goto  &320
if tstzon(i)>"9" : goto  &320
next i
return
&320
test=1
return
&321    ;btw is negen lang
btw9=levbtw
testv1=btw13
testv2=btw23
testv3=btw33
testpu="."
testpv="."
levbtw=testbtw
goto &318
&322     ;test rekenen btw
btw13=testv1
btw23=testv2
btw33=testv3
zon1=btw9
zon4=conv(zon2)+conv(zon3)
zon5=mod(zon4,97)
if zon5<>0 : goto  &317
&323
levbtw=testbtw
&324
print=1:tab(22,10),levlbtw,levbtw,"."
&330
print=1:tab(01,24),atb(22)
ask=1,i=&600,u=&316:tab(72,10)=vd
&331
print=1:tab(01,24),atb(22)
print=1:tab(01,24),paint(kh,ka),"Leverancier goederen  Y-N ",paint(kt,0)
ask=1,i=&600,u=&330:tab(76,10)=levgoed
levgoed=large(levgoed)
if levgoed="Y" : goto  &334
if levgoed="N" : goto  &334
goto &331
&334
print=1:tab(01,24),atb(22)
print=1:tab(01,24),paint(kh,ka),"Voorlopige annulatie van deze leverancier  Y-N ",paint(kt,0)
ask=1,i=&600,u=&331:tab(78,10)=levniet
levniet=large(levniet)
if levniet="Y" : goto  &335
if levniet="N" : goto  &335
goto &334
&335
print=1:tab(01,24),atb(22)
ask=1,i=&600,u=&334,/8a=&22,/8b=&24:tab(22,11)=levtele
&336
ask=1,i=&600,u=&335:tab(22,12)=levfax
&337
ask=1,i=&600,u=&336:tab(46,11)=levklnum
levklnum=large(levklnum)
&338
ask=1,i=&600,u=&337:tab(72,11),abet,tab(72,11)=abet
abet=large(abet)
if abet="N" : goto  &340
if abet<>"Y" : goto  &338
&340
test=0
ask=1,i=&600,u=&338,/8a=&22,/8b=&24:tab(22,13)=levbank
if len$(levbank)=14 : goto  &344
if len$(levbank)=12 : goto  &350
if levbank<>"0" : goto  &342
testbnk="000-0000000-000"
goto &359                 ;afdruk btwnr
&342
ask=1,i=&15,u=&15,/8a=&22,/8b=&24:tab(01,24),bell,paint(kh,ka),"Banknummer niet in orde : ",paint(kt,0)," "=j
print=1:tab(01,24),atb(21)
goto &340
&344     ;bank op 14 posities
testbnk=levbank
tstbnk=testb1
aant=3
gosub &346
if test=1 : goto  &342
tstbnk=testb2
aant=7
gosub &346
if test=1 : goto  &342
tstbnk=testb3
aant=2
gosub &346
if test=1 : goto  &342
goto &352               ;test btw
&346    ;routine testen zones
for i=1 to aant
if tstbon(i)<"0" : goto  &347
if tstbon(i)>"9" : goto  &347
next i
return
&347
test=1
return
&350    ;btw is negen lang
bon9=levbank
testb1=bon13
testb2=bon23
testb3=bon33
testbu="-"
testbv="-"
levbank=testbnk
goto &344
&352     ;test rekenen btw
bon13=testb1
bon23=testb2
bon33=testb3
bon1=bon9
bon4=conv(bon2)-conv(bon3)
bon5=mod(bon4,97)
if bon5<>0 : goto  &342
&359
levbank=testbnk
print=1:tab(22,13),(u14),levbank
&360
print=1:tab(01,24),atb(21)
print=1:tab(01,24),paint(kh,ka),"N=opzoeken op naam van de rekening ",paint(kt,0)
ask=1,i=&600,u=&340,/80=&400,/8a=&362,/8b=&364,"n"=&400,"N"=&400:tab(22,14)=levvast
if levvast=" " : goto  &370
search=3,levvast:&361,e,rekrec
goto &366
&361
ask=1,i=&600,/8a=&362,/8b=&364:tab(01,24),bell,paint(kh,ka),"Rekening",ng,paint(kt,0),fvoor,voor,fvolg,volg=j
print=1:tab(01,24),atb(21)
goto &360
&362 
up=3:&363,e,rekdown
goto &366
&363
print=1:tab(01,24),atb(21)
ask=1,i=&600,u=&600,/8b=&364:tab(01,24),paint(kh,ka),berb,paint(kt,0),fvolg,volg=j
goto &360
&364
down=3:&365,e,rekdown
goto &366
&365
print=1:tab(01,24),atb(21)
ask=1,i=&600,u=&600,/8a=&362:tab(01,24),paint(kh,ka),bere,paint(kt,0),fvoor,voor=j
goto &360
&366
print=1:tab(30,14),paint(kh,ka),rekoms,paint(kt,0)
levvast=reknum
print=1:tab(22,14),reknum
&367
print=1:tab(01,24),atb(22)
print=1:tab(01,24),paint(kh,ka),"Percentage korting op aankoopfaktuur ",paint(kt,0),atb(21)
ask=1,i=&600,u=&360,/8a=&362,/8b=&364:tab(72,14),(-2.z)=levkort
&370
if pass=" " : goto  &600
print=1:tab(01,15),atb(22)
print=1:tab(01,15),"Jaaromzet",tab(20),": ",(-8.n2),levjomz
print=1:tab(01,16),"Vorig jaar",tab(20),": ",(-8.n2),levvj
print=1:tab(01,17),"Totaal Btw ",tab(20),": ",(-8.n2),levtbtw
print=1:tab(01,18),"Voorschotten",tab(20),": ",(-8.n2),levvoor
&372
ask=1,i=&600,u=&600:tab(22,15),(-7z.n2)=levjomz
&374
ask=1,i=&600,u=&372:tab(22,16),(-7z.n2)=levvj
&378
ask=1,i=&600,u=&374:tab(22,17),(-7z.n2)=levtbtw
&380
ask=1,i=&600,u=&378:tab(22,18),(-7z.n2)=levvoor
goto &600
&400
print=1:tab(01,23),atb(22)
print=1:tab(01,23),paint(kh,ka),"Opzoeken op naam van de algemene rekening ",paint(kt,0)
selzoek=" "
vindrek=" "
&405
ask=1,i=&500,u=&500:tab(01,24),"Geef trefwoord : "=selzoek
selzoek=large(selzoek)
if selzoek=" " : goto  &405
open=3
&410
down=3:&370,e,rekdown
rekoms=large(rekoms)
selindex=0
selindex=index(rekoms,selzoek)
if selindex=0 : goto  &410
print=1:tab(01,24),atb(21),tab(01,24),"Trefw. : ",selzoek," Rek. : ",reknum," ",rekoms
rekoms=" "
&415
j=" "
ask=1,i=&505,u=&505:tab(58,24),"Deze rekening Y-N : "=j
j=large(j)
if j="N" : goto  &410
if j<>"Y" : goto  &415
&430
vindrek=reknum
&500
levvast=vindrek
if levvast=" " : goto  &370
search=3,levvast:&361,e,rekrec
goto &366
&505
print=1:tab(01,23),atb(22)
print=1:tab(01,24),vindrek
goto &360
&600
j=" "
print=1:tab(01,24),atb(21)
ask=1,i=&15,u=&360,/80=&612,/8a=&362,/8b=&364:tab(01,24),paint(kh,ka),vali,paint(kt,0)," (A=annulatie) : "=j
j=large(j)
if j="Y" : goto  &605
if j="N" : goto  &15 
if j="A" : goto  &620
goto &600
&605
levkode2=levkode
insert=2,levkode:&606,e,levrec
goto &15 
&606
modif=2,levkode:&611,e,levrec
goto &15
&611
print=1:tab(01,24),"Fout modif leverancier : ",e," ",levkode
stop
&612
newkode=" "
print=1:tab(01,24),atb(21)
ask=1,i=&600,u=&600:tab(01,24),"Geef nieuwe leverancierskode : "=newkode
newkode=large(newkode)
levkode2=newkode
insert=2,newkode:&600,e,levrec
delete=2,levkode:&623,e
goto &15
&620
if levtebe<>0 : goto  &621
if levvoor<>0 : goto  &621
if levjomz<>0 : goto  &621
if levtbtw<>0 : goto  &621
goto &622
&621
ask=1,i=&15:tab(01,24),bell,paint(kh,ka),"Geen annulatie toegelaten : ",paint(kt,0),ret=j
goto &15
&622
delete=2,levkode:&623,e
goto &15
&623
if e=78 : goto  &15
print=1:tab(01,24),"Fout delete leverancier : ",e," ",levkode
stop

&903
vv="2"
goto &905
&904
vv="1"
&905
phil=0
i1=1
i2=1
totaal=0
totlev=0
l6=6
&906
print=1:tab(01,02),atb(22)
print=1:paint(kl,0),tab(20,02),ltb,gener(38,htb),rtb,tab(29),mtb,tab(40),mtb,tab(50),mtb
print=1:tab(20,04),lto,gener(38,hto),rto,tab(29),mto,tab(40),mto,tab(50),mto
print=1:tab(20,03),vtb,"        ",vtb,tab(40),vtb,"         ",vtb,tab(59),vte,paint(kt,0)
print=1:tab(22,03),paint(kh,ka),"Totaal",tab(42),"Leveran",paint(kt,0)
ask=1,i=&15,u=&15,/80=&903:tab(01,05),paint(kh,ka)," Overzicht van de leveranciers ",paint(kt,0)," Geef beginkode : ",levkode,tab(50)=levkode
levkode=large(levkode)
print=1:tab(01,05),atb(21)
print=1:tab(01,05),paint(kh,ka),tab(03),"Nr",tab(08),"Kode",tab(19),"Naam",tab(46),"Gemeente",tab(73),"Saldo",paint(kt,0)
search=2,levkode:&908,e,levrec
goto &910
&907
i1=-1 
i2=-1 
up=2:&933,e,levdown
goto &910
&908
if phil=1 : goto  &907
i1=1
i2=1
down=2:&933,e,levdown
&910
if vv="1" : goto  &912
if vv<>"2" : goto  &911
if levgoed<>"Y" : goto  &908
&911
print=1:tab(01,l6),paint(kn,ka),"  ",(n2),l6,(e)," ",paint(kt,ka2),"  ",levkode,"  ",paint(kt,ka3)," ",levnaam,"  ",paint(kt,ka4)," ",levgem," ",paint(kn,ka5),(-7.n2),levtebe-levvoor,paint(kt,0)
totaal=totaal+levtebe*conv(i1)
totlev=totlev+conv(i2)
goto &913
&912
if levvoor=0 : goto  &908
print=1:tab(01,l6),paint(kn,ka),"  ",(n2),l6,(e)," ",paint(kt,ka2),"  ",levkode,"  ",paint(kt,ka3)," ",levnaam,"  ",paint(kt,ka4)," ",levgem," ",paint(kn,ka5),(-7.n2),levvoor,paint(kt,0)
totaal=totaal+(levvoor*conv(i1))
totlev=totlev+conv(i2)
&913
tabel(l6)=levkode
print=1:tab(30,03),(-9),totaal,tab(52),(-5),totlev
l6=l6+1
if l6<22 : goto  &908
&914
o=0
ask=1,i=&10,u=&10,"t"=&950,"T"=&950:tab(01,24),paint(kh,ka),bla,paint(kt,0)," T=terug ",num,ret=o
if o<6 : goto  &915
if o>l6-1 : goto  &915
levkode=tabel(o)
search=2,levkode:&915,e,levrec
phil=1
goto &10
&915
for l6=6 to 24
tabel(l6)=" "
next l6
print=1:tab(01,06),atb(22)
l6=6
goto &908
&933
if e=74 : goto  &908
o=0
ask=1,i=&10,u=&10,"tT"=&950:tab(01,24),paint(kh,ka),bere,paint(kt,0)," T=terug ",ret=o
if o<6 : goto  &10
if o>l6-1 : goto  &10
levkode=tabel(o)
search=2,levkode:&10,e,levrec
phil=1
goto &10
&950
if phil=1 : goto  &951
phil=1
goto &952
&951
phil=0
&952
goto &915

&2000
print=1:tab(01,24),atb(21)
print=1:tab(01,24),paint(kh,ka),"Opzoeken van postnummer",paint(kt,0)
ask=1,i=&600,u=&305,/81=&2500:tab(22,09)=postnum
posttel=0
search=10,postkode:&2010,e,postrec
goto &2090
&2010
print=1:tab(01,24),atb(21)
ask=1,i=&310,u=&310,/8a=&2030,/8b=&2040:tab(01,24),paint(kh,ka),"Postnummer",ng,paint(kt,0),fvoor,voor,fvolg,volg=j
goto &310 
&2030
up=10:&2060,e,postdown
goto &2090
&2040
down=10:&2070,e,postdown
goto &2090
&2060
print=1:tab(01,24),atb(21)
ask=1,i=&310,u=&310,/80=&2500,/8b=&2040:tab(01,24),paint(kh,ka),berb,paint(kt,0),fvolg,volg=j
goto &310 
&2070
print=1:tab(01,24),atb(21)
ask=1,i=&310,u=&310,/80=&2500,/8a=&2030:tab(01,24),paint(kh,ka),bere,paint(kt,0),fvoor,voor=j
goto &310 
&2090
levgem=postnum+" "+postrec 
print=1:tab(01,24),atb(21)
ask=1,i=&310,u=&310,/8a=&2030,/8b=&2040:tab(01,24),paint(kh,ka),fvoor,paint(kt,0),voor,paint(kh,ka),fvolg,paint(kt,0),volg,esc,tab(22,09),levgem,tab(45,24)=j
goto &310 

&2500
print=1:tab(01,24),atb(21)
print=1:tab(01,24),paint(kh,ka),"Opzoeken van gemeente",paint(kt,0)
ask=1,i=&600,u=&305,/80=&2000:tab(22,09)=gem
gem=large(gem)
gemtel=0
search=11,gemkode:&2520,e,gemrec
goto &2590
&2520
print=1:tab(01,24),atb(21)
ask=1,i=&310,u=&310,/8a=&2530,/8b=&2540:tab(01,24),atb(21),tab(01,24),paint(kh,ka),"Gemeente",ng,paint(kt,0),fvoor,voor,fvolg,volg=j
goto &310 
&2530
up=11:&2560,e,gemdown
goto &2590
&2540
down=11:&2570,e,gemdown
goto &2590
&2560
print=1:tab(01,24),atb(21)
ask=1,i=&310,u=&310,/8b=&2540:tab(01,24),paint(kh,ka),berb,paint(kt,0),fvolg,volg=j
goto &310 
&2570
print=1:tab(01,24),atb(21)
ask=1,i=&310,u=&310,/8a=&2530:tab(01,24),paint(kh,ka),bere,paint(kt,0),fvoor,voor=j
goto &310 
&2590
levgem=gemrec+" "+gem
print=1:tab(01,24),atb(21)
ask=1,i=&310,u=&310,/8a=&2530,/8b=&2540:tab(01,24),paint(kh,ka),fvoor,paint(kt,0),voor,paint(kh,ka),fvolg,paint(kt,0),volg,esc,tab(22,09),levgem,tab(45,24)=j
goto &310 

&3000    ;routine openstaande fakturen
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  OPENSTAANDE FAKTUREN ",tab(70),ndat
print=1:paint(kl,0),tab(01,02),gener(79,hto),paint(kt,0)
&3001
print=1:tab(01,05),atb(22)
&3002
ask=1,i=&10,u=&10,/81=&4000,/8a=&3005,/8b=&3007:tab(01,05),"Geef leverancierskode",esc,levkode,tab(37)=levkode
if levkode=" " : goto  &3002
levkode=large(levkode)
search=2,levkode:&3003,e,levrec
goto &3020
&3003
ask=1,i=&3001,u=&3001,/8a=&3005,/8b=&3007:tab(01,24),paint(kh,ka),"Leverancier",ng,paint(kt,0),fvoor,voor,fvolg,volg=j
goto &3001
&3005
up=2:&3006,e,levdown
goto &3020
&3006
print=1:tab(01,24),atb(21)
ask=1,i=&3001,u=&3001,/8b=&3007:tab(01,24),paint(kh,ka),berb,paint(kt,0),fvolg,volg=j
goto &3001
&3007
down=2:&3008,e,levdown
goto &3020
&3008
if e=74 : goto  &3020
print=1:tab(01,24),atb(21)
ask=1,i=&3001,u=&3001,/8a=&3005,/8b=&3007:tab(01,24),paint(kh,ka),bere,paint(kt,0),fvoor,voor=j
goto &3001
&3020
l6=6
gosub &5000
gosub &5500    ;sublijn
for e=1 to 17
tabopf(e)=" "
next e
fakkllv="L"
fakname=levkode
fakfak=" "
totaal=0
search=4,fakkode:&3030,e,fakrec
&3030
down=4:&3035,e,fakdown
if fakname<>levkode : goto  &3035
print=1:tab(01,l6),paint(kn,ka)," ",(n2),l6-5,(e)," ",paint(kt,ka2)," ",fakdat,"  ",paint(kn,ka3),shr(faknum)," ",paint(kn,ka4)," ",fakverv," ",paint(kn,ka5),(-7.n2),faktebe,(e)," ",paint(kn,ka),(-7.n2),fakont,(e)," ",paint(kn,ka2),(-7.n2),faktebe-fakont,(e)," ",tab(66),paint(kt,ka3)," ",(u12),fakoms
totaal=totaal+faktebe-fakont
tabopf(l6-5)=fakkode
l6=l6+1
if l6>22 : goto  &3100  ;blad volzet
goto &3030
&3035
levtebe=totaal
modif=2,levkode:&3040,e,levrec
&3040
print=1:tab(01,23),atb(22)
print=1:tab(01,23),"Totaal te betalen : ",(-9.n2),levtebe
print=1:tab(45,23),"Voorschotten : ",(-9.n2),levvoor
print=1:tab(01,24),paint(kh,ka),"S a l d o         : ",paint(kt,0),(-9.n2),levtebe-levvoor
j=" " 
ask=1,i=&3000,u=&3000,/8a=&3005,/8b=&3007,/80=&4900,"bB"=&4900,"sS"=&3200:tab(34,24),fvoor,voor,fvolg,volg=j
goto &3000
&3100   
j=" " 
print=1:tab(01,24),atb(21)
ask=1,i=&3000,u=&3000,/8a=&3005,/8b=&3007,/80=&4900,"bB"=&4900,"sS"=&3200:tab(01,24),paint(kh,ka),bla,paint(kt,0),ret=j
&3105
for e=1 to 24
tabopf(e)=" "
next e
gosub &5000
gosub &5500
l6=6
goto &3030

&3200
dfile=14:&3205,e
&3205
cfile=14,d=80,lk=15
&3210
fakkllv="L"
fakname=levkode
fakfak=" "
search=4,fakkode:&3230,e,fakrec
&3230
down=4:&3235,e,fakdown
if fakname<>levkode : goto  &3235
fakfak=right(fakdat,2)+substr(fakdat,4,2)+left(fakdat,2)
insert=14,fakkode:&3231,e,fakrec
goto &3230
&3231
if e=81 : goto &3020
print=1:tab(01,24),"Fout insert fakkode : ",(-3),e
stop
&3235
fakkllv="L"
fakname=levkode
fakfak=" "
search=4,fakkode:&3236,e,fakrec
&3236
down=4:&3239,e,fakdown
if fakname<>levkode : goto  &3239
delete=4,fakkode:&3236,e
goto &3236
&3239
open=14:&3020,e
&3240
down=14:&3020,e,fakdown
print=1:tab(01,24),fakkllv," ",fakname," ",fakfak
insert=4,fakkode:&3240,e,fakrec
goto &3240

&4000    ;routine historiek
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  LEVERANCIERSFICHE - HISTORIEK ",tab(70),ndat
print=1:paint(kl,0),tab(01,02),gener(79,hto),paint(kt,0)
&4001
print=1:tab(01,05),atb(22)
&4002
ask=1,i=&10,u=&10,/82=&3000,/8a=&4005,/8b=&4007:tab(01,05),"Geef leverancierskode",esc,levkode,tab(37)=levkode
if levkode=" " : goto  &4002
levkode=large(levkode)
search=2,levkode:&4003,e,levrec
goto &4020
&4003
print=1:tab(01,24),atb(21)
ask=1,i=&4000,u=&4000,/8a=&4005,/8b=&4007:tab(01,24),paint(kh,ka),"Leverancier",ng,paint(kt,0),fvoor,voor,fvolg,volg=j
goto &4000
&4005
up=2:&4006,e,levdown
goto &4020
&4006
if e=74 : goto  &4005
ask=1,i=&4000,u=&4000,/8b=&4007:tab(01,24),paint(kh,ka),berb,paint(kt,0),fvolg,volg=j
goto &4000
&4007
down=2:&4008,e,levdown
goto &4020
&4008
if e=74 : goto  &4007
print=1:tab(01,24),atb(21)
ask=1,i=&4000,u=&4000,/8a=&4005:tab(01,24),paint(kh,ka),bere,paint(kt,0),fvoor,voor=j
goto &4000
&4020     
histdat=" "
gosub &5000
gosub &5600
loper="O"
ask=1,i=&4000,u=&4000,/8a=&4005,/8b=&4007:tab(01,24),"Geef loopsekwentie ",paint(kh,ka),"N",paint(kt,0),"=normaal  ",paint(kh,ka),"O",paint(kt,0),"=omgekeerd : ",loper," : "=loper
loper=large(loper)
if loper="N" : goto  &4022
if loper="O" : goto  &4021
goto &4020
&4021
histdat="ZZZZZZ"
&4022
for e=1 to 24
tabhis(e)=" "
next e
sall=0
l6=6
&4025
hisnaam=levkode
search=5,hiskode:&4030,e,kllvhis
&4030
for i=1 to 2
dr(i)=0
next i
opm=" "
if loper="O" : goto  &4035
down=5:&4300,e,hisdown
goto &4040
&4035
up=5:&4300,e,hisdown
&4040
if hisnaam<>levkode : goto  &4300
if hiskod1="A" : goto  &4070
if hiskod1="F" : goto  &4075
goto &4080
&4070
dr(1)=hisbed1
sall=sall+hisbed1
hisbed2=hisbtw
if hisbed2=0 : goto  &4090
opm="Btw"
goto &4090
&4075 
dr(2)=hisbed1
if hiskod2="+" : goto  &4076
sall=sall-hisbed1
goto &4077
&4076
sall=sall+hisbed1
&4077
opm=" "
rekkode=shl(large(hisbetw))
search=3,hisbetw:&4080,e,rekrec
opm=large(rekoms)
&4080
if hiskod2="T" : goto  &4081
if hiskod2="K" : goto  &4082
if hiskod2="I" : goto  &4083
if hiskod2="V" : goto  &4084
if hiskod2="X" : goto  &4085
if hiskod2="+" : goto  &4086
if hiskod2="-" : goto  &4087
if hiskod2=" " : goto  &4088
goto &4090
&4081
opm="Teveel"
goto &4090
&4082
opm="Korting"
sall=sall-hisbed2
goto &4090
&4083
opm="Intrest" 
goto &4090
&4084
opm="Koersv"
goto &4090
&4085
opm="Bet.verschil"
goto &4090
&4086 
opm="Terug"
goto &4090
&4087
opm="Voorschot"
goto &4090
&4088
&4090
print=1:tab(01,l6),paint(kn,ka)," ",(n2),l6-5,(e)," ",paint(kt,ka2)," ",hisdat," ",paint(kn,ka3),shr(hisfakt)," ",paint(kn,ka4),(-7.n2),dr(1),(e)," ",paint(kn,ka5),(-7.n2),dr(2)
print=1:(e),paint(kn,ka)," ",hisbetw," ",paint(kn,ka2),(-7.n2),hisbed2,(e)," ",paint(kt,ka3),left(opm,6)," ",paint(kn,ka4),(-7.n2),dr(1)-hisbed2,paint(kt,0)
print=1:tab(50,23),paint(kh,ka),"Saldo : ",paint(kt,0),(-8.n2),levtebe-levvoor,sall
tabhis(l6-5)=hiskode
l6=l6+1
if l6>22 : goto  &4200    
goto &4030
&4200
j=" "
print=1:tab(01,23),atb(22)
print=1:tab(50,23),paint(kh,ka),"Saldo : ",paint(kt,0),(-8.n2),levtebe-levvoor,sall
ask=1,i=&4000,u=&4000,/8a=&4005,/8b=&4007,/80=&4800,"bB"=&4800,"tT"=&4400:tab(01,24),paint(kh,ka),bla,paint(kt,0),ret,paint(kh,ka),"T",paint(kt,0),"=vorig blad : "=j
l6=6
gosub &5000
gosub &5600
for e=1 to 17
tabhis(e)=" "
next e
goto &4030
&4300
j=" "
print=1:tab(01,22),atb(22)
print=1:tab(50,23),paint(kh,ka),"Saldo : ",paint(kt,0),(-8.n2),levtebe-levvoor,sall
ask=1,i=&4000,u=&4000,/8a=&4005,/8b=&4007,/80=&4800,"bB"=&4800,"tT"=&4400:tab(01,24),paint(kh,ka),"Einde historiek : ",paint(kt,0),ret,paint(kh,ka),"T",paint(kt,0),"=vorig blad : "=j
goto &4000
&4400       ;routine einde blad en terug keren
if loper="N" : goto  &4410
loper="N"
goto &4420
&4410
loper="O"
&4420
print=1:tab(01,06),atb(22)
for e=1 to 17
tabhis(e)=" "
next e
l6=6
goto &4030

&4800
print=1:tab(01,23),atb(21)
print=1:tab(01,01),paint(kh,ka),space(79),tab(01)," MANIPULATIE VAN DE HISTORIEKEN",tab(70),ndat,tab(79)," ",paint(kt,0)
for e=1 to 17
if tabhis(e)=" " : goto  &4805
l6=e    
print=1:tab(02,e+5),paint(kh,ka),(--),e,paint(kt,0) 
next e
&4805
lijntel=0
print=1:tab(01,24),atb(21)
ask=1,i=&4000,u=&4000,/80=&4860:tab(01,24),"Geef lijnnummer te veranderen : "=lijntel
if lijntel<1 : goto  &4805
if lijntel>l6 : goto  &4805
hiskode=tabhis(lijntel)
&4806
search=5,hiskode:&4807,e,kllvhis
print=1:tab(01,06),atb(22)
goto &4809
&4807
print=1:tab(01,24),"Fout search hiskode : ",e," ",hiskode
stop
&4809
print=1:tab(01,06),"Datum faktuur",tab(20),": ",hisdat,"."
print=1:tab(01,07),"Kode F-L-A-V",tab(20),": ",hiskod1,"."
print=1:tab(01,08),"Bedrag 1     ",tab(20),": ",(-8.n2),hisbed1
print=1:tab(01,09),"Btw bedrag",tab(20),": ",(-8.n2),hisbtw
print=1:tab(01,10),"Kode T-I-K-V ",tab(20),": ",hiskod2,"."
print=1:tab(01,11),"Bedrag 2     ",tab(20),": ",(-8.n2),hisbed2
print=1:tab(01,12),"Kode histor.",tab(20),": ",hiskllv,"."
print=1:tab(01,13),"Factuurnummer",tab(20),": ",hisfakt,"."
print=1:tab(01,14),"Betaalwijze  ",tab(20),": ",hisbetw,"."
print=1:tab(01,15),"Omschrijving",tab(20),": ",hisoms,"."
print=1:paint(kl,0),tab(01,17),gener(79,hto),paint(kt,0)
goto &4812
&4810
print=1:tab(01,18),atb(22)
up=5:&4000,e,hisdown
if hisnaam<>levkode : goto  &4000
goto &4809
&4811
print=1:tab(01,18),atb(22)
down=5:&4000,e,hisdown
if hisnaam<>levkode : goto  &4000
goto &4809
&4812
delhis=hiskode
ask=1,i=&4834,u=&4834,/8a=&4810,/8b=&4811:tab(22,06)=hisdat
histdat=right(hisdat,2)+substr(hisdat,4,2)+left(hisdat,2)
&4814
ask=1,i=&4834,u=&4812:tab(22,07)=hiskod1
hiskod1=large(hiskod1)
&4816
ask=1,i=&4834,u=&4814:tab(22,08)=hisbed1
&4818
ask=1,i=&4834,u=&4816:tab(22,09)=hisbtw
&4820
ask=1,i=&4834,u=&4818:tab(22,10)=hiskod2
hiskod2=large(hiskod2)
&4822
ask=1,i=&4834,u=&4820:tab(22,11)=hisbed2
&4824
ask=1,i=&4834,u=&4822:tab(22,12)=hiskllv
hiskllv=large(hiskllv)
hisnaam=hiskllv
&4826
ask=1,i=&4834,u=&4824:tab(22,13)=hisfakt
hisfakt=shr(hisfakt)
&4828
ask=1,i=&4834,u=&4826:tab(22,14)=hisbetw
&4830
ask=1,i=&4834,u=&4828:tab(22,15)=hisoms
hisoms=large(hisoms)
&4834
j=" "
ask=1,i=&4000,u=&4830,/8a=&4810,/8b=&4811,/80=&4835:tab(01,19),vali," (A=annulatie) : "=j
j=large(j)
if j="O" : goto &4880
if j="A" : goto &4846
if j="S" : goto &4860
if j<>"Y" : goto &4811
delete=5,delhis:&4835,e
&4835
insert=5,hiskode:&4845,e,kllvhis
goto &4850
&4845
histel=histel+1
goto &4835
&4846
delete=5,delhis:&4847,e
&4847
print=1:tab(01,06),atb(22)
goto &4021
&4850
teller(08)=teller(08)+1       ;aanpassen historieken teller
par(3)=param3
goto &4000

&4860     ;sortering historiek op datum 
hiskode=levkode
search=5,hiskode:&4865,e,kllvhis
&4865
down=5:&4000,e,hisdown
if hisnaam<>levkode : goto  &4000
delete=5,hiskode:&4865,e
&4866
hisnaam=levkode
histdat=right(hisdat,2)+substr(hisdat,4,2)+left(hisdat,2)
histel=0
&4870
insert=5,hiskode:&4875,e,kllvhis 
goto &4865
&4875
histel=histel+1
goto &4870

&4880     ;openstaande facturen aanvullen vanuit historiek
ldgo.seg 1
goto &3000

&4900
print=1:tab(01,01),paint(kh,ka),space(79),tab(01)," MANIPULATIE VAN DE OPENSTAANDE FAKTUREN ",tab(70),ndat,tab(79)," ",paint(kt,0)
for e=1 to 17
if tabopf(e)=" " : goto  &4905
l6=e
print=1:tab(02,e+5),paint(kh,ka),(--),e,paint(kt,0)
next e
&4905
lijntel=0
print=1:tab(01,24),atb(21)
&4906
ask=1,i=&3000,u=&3000:tab(01,24),"Geef lijnnummer te veranderen : "=lijntel
if lijntel=0 : goto  &4906
fakkode=tabopf(lijntel)
search=4,fakkode:&4905,e,fakrec
print=1:tab(01,06),atb(22)
&4910
faknum=shr(faknum)
print=1:tab(01,06),"Datum faktuur",tab(20),": ",fakdat,".    ",faktest," ",fakteba
print=1:tab(01,07),"Vervaldatum  ",tab(20),": ",fakverv,"."
print=1:tab(01,08),"Leverancier  ",tab(20),": ",faknaam,"."
print=1:tab(01,09),"Omschrijving ",tab(20),": ",fakoms,"."
print=1:tab(01,10),"Factuurnummer",tab(20),": ",faknum,"."
print=1:tab(01,11),"Te betalen   ",tab(20),": ",(-8.n2),faktebe
print=1:tab(01,12),"Reeds betaald",tab(20),": ",(-8.n2),fakont
print=1:tab(20,13),"ÄÄÄÄÄÄÄÄÄÄÄÄ"
print=1:tab(01,14),"Saldo        ",tab(20),": ",(-8.n2),faktebe-fakont
print=1:paint(kl,0),tab(01,16),gener(79,hto),paint(kt,0)
&4912
ask=1,i=&3000,u=&3000,/8a=&4955,/8b=&4950:tab(22,06)=fakdat
&4914
ask=1,i=&4924,u=&4912:tab(22,07)=fakverv
&4915
ask=1,i=&4924,u=&4914:tab(22,08)=faknaam
faknaam=shl(large(faknaam))
&4916
ask=1,i=&4924,u=&4915:tab(22,09)=fakoms
fakoms=large(fakoms)
&4918
ask=1,i=&4924,u=&4916:tab(22,10)=faknum
faknum=shr(faknum)
&4920
ask=1,i=&4924,u=&4918:tab(22,11)=faktebe
&4922
ask=1,i=&4924,u=&4920:tab(22,12)=fakont
&4924
j=" "
print=1:tab(01,18),atb(21)
ask=1,i=&3000,u=&3000,/80=&4926:tab(01,18),vali," (A=annulatie) : "=j
j=large(j)
if j="A" : goto  &4925
if j<>"Y" : goto  &4950
modif=4,fakkode:&4950,e,fakrec
goto &4950
&4925
delete=4,fakkode:&4950,e
goto &4950
&4926
fakkllv="L"
fakname=faknaam
fakfak=shr(faknum)
insert=4,fakkode:&4927,e,fakrec
teller(05)=teller(05)+1
par(3)=param3
goto &4950
&4927
modif=4,fakkode:&4950,e,fakrec
&4950
down=4:&3000,e,fakdown
&4951
if fakname<>levkode : goto  &3000
goto &4910
&4955
up=4:&3000,e,fakdown
goto &4951

&5000
print=1:clear,paint(kl,0),ltb,gener(77,hto),rtb
print=1:tab(01,02),vte,tab(79),vte
print=1:tab(01,03),vtb,gener(77,hto),vte,paint(kt,0)
print=1:tab(03,02),paint(kh,ka),levnaam," ",levstraa," ",levgem,paint(kt,0)
return
&5500
print=1:paint(kl,0),tab(01,04),vtb,tab(79),vte
print=1:tab(01,05),lto,gener(77,hto),rto,paint(kt,0)
print=1:tab(06,04),paint(kh,ka),"Datum",tab(16),"Factuur",tab(24),"Vervald.",tab(34),"Totaal",tab(46),"Betaald",tab(57),"Saldo",tab(67),"Omschrijv.",paint(kt,0)
return
&5600
print=1:paint(kl,0),tab(01,04),vtb,tab(79),vte
print=1:tab(01,05),lto,gener(77,hto),rto,paint(kt,0)
print=1:tab(06,04),paint(kh,ka),"Datum",tab(16),"Factuur",tab(25),"Aankoop",tab(36),"Financ",tab(44),"Reken.",tab(53),"Bedrag",tab(62),"Opm",tab(72),"Netto",paint(kt,0)
return

&7000
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  BIJKOMEND SCHERM VOOR : ",levnaam
print=1:paint(kl,0),tab(01,02),ltb,gener(77,hto),rtb,tab(06),mtb
for tektel=1 to 20
print=1:tab(01,tektel+2),vte,tab(06),vte,tab(79),vte
next tektel
print=1:tab(01,23),lto,gener(77,hto),rto,tab(06),mto,paint(kt,0)
tektyp=levkode
&7001
for tektel=1 to 20
tekrec=" "
search=9,tekkode:&7002,e,tekrec
&7002
print=1:tab(02,tektel+2),(-3),tektel,(e),tab(08),(u70),tekrec
next tektel
&7100
tektel=1
&7101
if tektel<1 : goto  &10   
if tektel>20 : goto  &10   
tekrec=" "
search=9,tekkode:&7102,e,tekrec
&7102
ask=1,i=&10,u=&7106:tab(08,tektel+2)=tekrec
&7103
insert=9,tekkode:&7104,e,tekrec
goto &7105
&7104
modif=9,tekkode:&7105,e,tekrec
&7105
tektel=tektel+1
goto &7101
&7106
tektel=tektel-1
goto &7101

&8000   ;schermafdrukroutine
print=1:tab(01,05),atb(21),tab(01,05),"Leverancierskode : ",levkode
print=1:tab(01,07),"Naam       ",tab(20),": ",paint(kh,ka),left(levnaam,len$(levnaam)),paint(kt,0),".",atb(21)
print=1:tab(01,08),"Straat     ",tab(20),": ",levstraa,"."
print=1:tab(01,09),"Gemeente   ",tab(20),": ",levgem,".",tab(60),"Land",tab(70),": ",levland,"."
print=1:tab(01,10),"Btw nummer ",tab(20),": ",levlbtw,levbtw,"."
print=1:tab(60,10),"Vervaldag : ",tab(72),vd,tab(76),levgoed,tab(78),levniet
print=1:tab(01,11),"Telefoon   ",tab(20),": ",levtele,"."
print=1:tab(37,11),"Nr.lev :",tab(46),levklnum,".",tab(60),"Aut. bet. :",tab(72),abet,"."
print=1:tab(01,12),"Faxnummer  ",tab(20),": ",levfax,"."
print=1:tab(01,13),"Banknummer ",tab(20),": ",levbank,"."
print=1:tab(01,14),"Vast rekening ",tab(20),": ",levvast,".",tab(60),"% Korting :",tab(72),(-2.z),levkort,(e),"."
rekoms=" "
search=3,levvast:&8002,e,rekrec
goto &8003
&8002
rekoms="Rek niet gevonden"
&8003
print=1:tab(30,14),rekoms
print=1:paint(kl,0),tab(01,15),gener(79,hto),paint(kt,0)
print=1:tab(01,16),"Jaaromzet",tab(20),": ",(-8.n2),levjomz
print=1:tab(40,16),"Vorig jaar",tab(60),": ",(-8.n2),levvj
print=1:tab(01,17),"Btw",tab(20),": ",(-8.n2),levtbtw
print=1:tab(01,18),"Te betalen  ",tab(20),": ",(-8.n2),levtebe
print=1:tab(01,19),"Voorschotten",tab(20),": ",(-8.n2),levvoor
print=1:tab(01,20),paint(kh,ka),"Saldo",paint(kt,0),tab(20),": ",(-8.n2),levtebe-levvoor
print=1:paint(kl,0),tab(01,21),gener(79,hto),paint(kt,0)
print=1:tab(01,24),paint(kh,ka),"F6=bijkomend scherm voor deze leverancier ",paint(kt,0),atb(21)
return

eseg 0

segment 1
goto &130
&25
ret.seg
&130
fakkllv="L"
fakname=hisnaam 
fakfak=shr(hisfakt)
fakklv="L"
faknaam=levkode
fakdat=hisdat
fakverv=hisdat
faknum=hisfakt
fakoms=hisoms  
faktebe=hisbed1 
fakont=0
insert=4,fakkode:&134,e,fakrec
goto &140
&134
modif=4,fakkode:&135,e,fakrec
goto &140
&135
print=1:tab(01,24),"Fout insert fakkode : ",e," ",fakkode
stop
&140
teller(05)=teller(05)+1
levtebe=levtebe+faktebe
modif=2,levkode:&146,e,levrec
goto &150
&146    
print=1:tab(01,24),"Fout modif levkode : ",e," ",levkode
stop
&150    
par(3)=param3
par(4)=param4
goto &25
eseg 1

end