program "REKENINGEN"

dcl selindex%,selma%,bepklas%
dcl sommen=6(20),totdebm=6(9),totcredm=6(9),totdebj=6(9),totcredj=6(9)
dcl tdebm=6,tdebj=6,tcredm=6,tcredj=6,sal1=6,sal2=6,saldo=6,totdeb=6,totcred=6
dcl totaal=6 
dcl tabel$=14(25),omsch$=10,hnm$=24,selzoek$=10,vindrek$=6,eindrek$=6
dcl reknum2$=8,beschr$=4,doorl$=1,pass$=4,poss$=1,loop_$=1,m$=2

#INCLUDE  "CRINCLU"
#INCLUDE  "CRINCLU2"

assign=02,bestand(01),c,wr,si                      ;rekeningenbestand
assign=03,bestand(02),c,wr,si                      ;maandhistoriekbestand
assign=04,left(bestand(01),3)+"CEN",wr,si    ;rekeningencentralisatie
assign=06,bestand(03),c,wr,si                     ;leveranciers
assign=07,bestand(04),c,wr,si                     ;klanten
assign=14,left(bestand(01),6)+"A",wr,si

open=2:&1,e
open=3:&10,e
open=6:&10,e
open=7:&10,e
goto &10
&7
poss="Y"
goto &11

&8
ldgo.seg 5
goto &11

&9
print=1:tab(01,23),atb(22)
ldgo.seg 6
goto &40

&10
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  BEHANDELING REKENINGEN ",tab(70),ndat
print=1:paint(kl,0),tab(01,02),ltb,gener(77,hto),rtb
print=1:tab(01,03),vtb,tab(79),vte
print=1:tab(01,04),lto,gener(77,hto),rto,paint(kt,0)
print=1:tab(03,03),paint(kh,ka),"F1=Overzicht  F2=Overz klas  F3=Salderen  F4=Historiek  F5=Centralisatie",paint(kt,0)
&11
print=1:tab(01,05),atb(22)
if phil=1 : goto  &15
&12
ask=1,i=&1,u=&1,/80=&1000,/81=&1050,/82=&1100,/83=&1150,/84=&950,/85=&8,/8a=&22,/8b=&24,"nN"=&9:tab(01,05),"Geef rekeningnummer",esc,rekkode,tab(35)=rekkode
rekkode=large(rekkode)
if rekkode=" " : goto  &12
if rekkode=pwtest : goto  &7
&15
search=2,rekkode:&20,e,rekrec
goto &40
&20
ask=1,i=&11,u=&11,/8a=&22,/8b=&24,"nN"=&29:tab(01,24),paint(kh,ka),"Rekening",ng,paint(kt,0)," ",paint(kh,ka),"N",paint(kt,0),"=nieuwe  ",fvoor,voor,fvolg,volg=j
phil=0
goto &11
&22
up=2:&23,e,rekdown
goto &40
&23
print=1:tab(01,24),atb(21)
ask=1,i=&11,u=&11,/8b=&24:tab(01,24),paint(kh,ka),berb,paint(kt,0)," ",fvolg,volg=j
goto &11
&24
down=2:&25,e,rekdown
goto &40
&25
print=1:tab(01,24),atb(21)
ask=1,i=&11,u=&11,/8a=&22:tab(01,24),paint(kh,ka),bere,paint(kt,0)," ",fvoor,voor=j
goto &11
&29
rekrec=" "
rekmeca=0
for i=1 to 3
rekdeb(i)=0
rekcred(i)=0
next i
rekhok="Y"
rekbtw="N"
rekdiver="N"
&40
phil=0
print=1:tab(01,24),atb(21)
gosub &2000
&45
rekklas=left(rekkode,3)
ask=1,i=&11,u=&11,/80=&940,/8a=&22,/8b=&24,"nN"=&9:tab(23,08),left(rekkode,3),".",tab(23,08)=rekklas
&47
ask=1,i=&100,u=&45,/80=&940,/8a=&22,/8b=&24:tab(23,10)=rekoms
if rekoms=" " : goto  &47
&49
ask=1,i=&100,u=&47,/80=&940,/8a=&22,/8b=&24:tab(23,12)=rekmeko
rekmeko=large(rekmeko)
&51
ask=1,i=&100,u=&49,/80=&940,/8a=&22,/8b=&24:tab(23,14)=rekhok
rekhok=large(rekhok)
if rekhok="Y" : goto  &53
if rekhok<>"N" : goto  &51
&53
ask=1,i=&100,u=&51,/80=&940,/8a=&22,/8b=&24:tab(23,16)=rekbtw
rekbtw=large(rekbtw)
if rekbtw="A" : goto  &55
if rekbtw="Y" : goto  &55
if rekbtw<>"N" : goto  &53  
&55
print=1:tab(01,24),atb(22)
ask=1,i=&100,u=&53,/80=&940,/8a=&22,/8b=&24:tab(62,16)=rekdiver
rekdiver=large(rekdiver)
if rekdiver="Y" : goto  &57
if rekdiver<>"N" : goto  &55
&57
if poss=" " : goto  &100
&59
ask=1,i=&100,u=&55:tab(24,18),(-8.n2)=rekdeb(1)
&61
rekdeb(2)=rekdeb(1)
ask=1,i=&100,u=&59:tab(46,18),(-8.n2)=rekdeb(2)
&63
ask=1,i=&100,u=&61:tab(68,18),(-8.n2)=rekdeb(3)
&65
ask=1,i=&100,u=&63:tab(24,19),(-8.n2)=rekcred(1)
&67
rekcred(2)=rekcred(1)
ask=1,i=&100,u=&65:tab(46,19),(-8.n2)=rekcred(2)
&69
ask=1,i=&100,u=&67:tab(68,19),(-8.n2)=rekcred(3)
gosub &2000
&100
j=" "
print=1:tab(01,24),atb(21)
ask=1,i=&10,u=&55,/80=&940,/8a=&22,/8b=&24:tab(01,24),paint(kh,ka),vali,paint(kt,0)," (A=annulatie) : "=j
j=large(j)
if j="Y" : goto  &105
if j="N" : goto  &11
if j="A" : goto  &110
goto &100
&105
reknum=rekkode
insert=2,rekkode:&106,e,rekrec
goto &10
&106
modif=2,rekkode:&107,e,rekrec
goto &10
&107
print=1:tab(01,24),"Fout modif rekening : ",e," ",rekkode
stop
&110
if rekdeb(2)<>0 : goto  &115
if rekcred(2)<>0 : goto  &115
for e=1 to 38
if rekkode=vastrek(e) : goto  &115
next e
&111
j=" "
print=1:tab(01,24),atb(21)
ask=1,i=&100,u=&100:tab(01,24),"Annulatie van deze rekening  Y-N : "=j
j=large(j)
if j="N" : goto  &11
if j="Y" : goto  &120
goto &111
&115
print=1:tab(01,24),atb(21)
j=" "
ask=1,i=&100,u=&100:bell,tab(01,24),"Saldo NIET gelijk aan 0  of vaste rekening (A=annulatie) : "=j
j=large(j)
if j<>"A" : goto  &100
&120
delete=2,rekkode:&125,e
delete=14,rekkode:&11,e
goto &10
&125
if e=78 : goto  &11
print=1:tab(01,24),"Fout deleting rekening : ",e," ",rekkode
stop

&940
ldgo.seg 8
goto &10

&950
ldgo.seg 1
goto &10

&1000
ldgo.seg 2
goto &10

&1050
ldgo.seg 4
goto &10

&1100
ldgo.seg 3
goto &10

&1150
assign=1,"CRLIHM"
chain=1:&1,e
stop

&2000
print=1:paint(kt,0)
print=1:tab(01,05),atb(21),tab(01,05),"Rekeningnummer : ",rekkode
print=1:tab(01,08),"Klasse rekening ",tab(21),": ",left(rekkode,3),"."
print=1:tab(01,10),"Omschrijving",tab(21),": ",paint(kh,ka),rekoms,paint(kt,0),"."
print=1:tab(01,12),"Balansnummer ",tab(21),": ",(e),rekmeko,(u),"."
print=1:tab(01,14),"Hist. detail Y-N",tab(21),": ",rekhok,"."
print=1:tab(01,16),"Btw rekening Y-N",tab(21),": ",rekbtw,"."
print=1:tab(40,16),"Collectief Y-N",tab(60),": ",rekdiver,"."
print=1:paint(kl,0),tab(01,17),gener(79,hto),paint(kt,0)
print=1:tab(01,18),"Cumul debet (maand) : ",tab(40),"Jaar ",tab(60),"Vorig"
print=1:tab(01,19),"Cumul kredit(maand) : ",tab(40),"Jaar ",tab(60),"Vorig"
print=1:paint(kl,0),tab(01,20),gener(79,hto),paint(kt,0)
print=1:tab(01,21),"Saldo       (maand) : ",tab(40),"Jaar ",tab(60),"Vorig"
print=1:paint(kl,0),tab(01,22),gener(79,hto),paint(kt,0)
print=1:tab(01,23),atb(21)
for i=1 to 3
sommen(i)=rekdeb(i)-rekcred(i)
next i
print=1:paint(kn,0),tab(24,18),(-9.n2),rekdeb(1),tab(46),rekdeb(2),tab(68),rekdeb(3)
print=1:tab(24,19),(-9.n2),rekcred(1),tab(46),rekcred(2),tab(68),rekcred(3)
print=1:tab(24,21),(-9.n2),sommen(1),tab(46),sommen(2),tab(68),sommen(3)
print=1:paint(kt,0)

if kodes(3)="Y"
if rekbtw="A" 
search=14,rekkode:&2100,e,rekarec
print=1:tab(01,23),"Aantallen",tab(25),(-9.n2),rekaan1(1),tab(49),rekaan1(2),tab(71),rekaan1(3)
endif
endif

&2100
return

eseg 0

segment 1

goto &10
&1
ret.seg
&10
lijntel=6
open=4:&1,e
&20 
for i=1 to 2 
sommen(i)=0
next i
&60
print=1:tab(01,05),atb(22)
print=1:tab(01,05),paint(kh,ka),"F1=Overz centralisatie  (S)chrappen.",paint(kt,0)
ask=1,i=&1,u=&1,/80=&400,/81=&300,"sS"=&200:tab(01,06),"Geef maand op  1--12 : ",(n2),selma,tab(24)=selma
if selma<1 : goto  &60
if selma>12 : goto  &60
&70
print=1:tab(01,05),atb(22)
print=1:tab(03,05),paint(kh,ka),"Reknr",tab(11),"Omschrijving",tab(41),"Debet",tab(52),"Kredit",tab(67),"Saldo",paint(kt,0)
&100
down=4:&150,e,centdown
if centdeb(selma)=0 : goto  &101
goto &105
&101
if centcred(selma)=0 : goto  &100
&105
sommen(1)=sommen(1)+centdeb(selma)
sommen(2)=sommen(2)+centcred(selma)
&110
print=1:tab(01,lijntel),paint(kn,ka),"  ",centkode," ",paint(kt,ka2)," ",centoms," ",paint(kn,ka3),"  ",(-8.n2),centdeb(selma),(e)," ",paint(kn,ka4),"  ",(-6.n2),centcred(selma),(e)," ",paint(kn,ka5),"  ",(n8.n2),centdeb(selma)-centcred(selma),paint(kt,0)
lijntel=lijntel+1
if lijntel<19 : goto  &100
&120
print=1:tab(01,24),atb(21)
ask=1,i=&1,u=&1:tab(01,24),paint(kh,ka),bla,paint(kt,0),num,ret=j
&130
lijntel=6
print=1:tab(01,06),atb(22)
goto &100
&150
print=1:tab(01,20),atb(22)
print=1:paint(kl,0),tab(01,20),gener(79,hto),paint(kt,0)
print=1:tab(01,21),"Totaal debet  = ",(-8.n2),sommen(1)
print=1:tab(01,22),"Totaal kredit = ",(-8.n2),sommen(2)
print=1:tab(01,23),"Saldo         = ",(-8.n2),sommen(1)-sommen(2)
ask=1,i=&1,u=&1:tab(01,24),paint(kh,ka),bere,paint(kt,0),ret=j
goto &1
&200 
print=1:tab(01,24),paint(kh,ka),"O.K. om centralisatiebestand te schrappen  Y-N : ",paint(kt,0)," "
ask=1,i=&10,u=&10:=j
j=large(j)
if j="N" : goto  &10
if j<>"Y" : goto  &200
dfile=4:&210,e
print=1:bell
&210
cfile=4,d=216,lk=6
goto &1

&300
assign=1,"CRCENT"
chain=1:&1,e
stop

&400 
print=1:tab(01,05),atb(22)
&401
ask=1,i=&10,u=&10,/8a=&422,/8b=&424:tab(01,05),"Geef rekeningnummer",esc,rekkode,tab(35)=rekkode
if rekkode=" " : goto  &401
rekkode=large(rekkode)
search=2,rekkode:&420,e,rekrec
goto &440
&420
ask=1,i=&400,u=&400,/8a=&422,/8b=&424:tab(01,24),paint(kh,ka),"Rekenining niet gevonden : ",paint(kt,0)," ",fvoor,voor,fvolg,volg=j
goto &400
&422
up=2:&423,e,rekdown
goto &440
&423
print=1:tab(01,24),atb(21)
ask=1,i=&400,u=&400,/8b=&424:tab(01,24),paint(kh,ka),berb,paint(kt,0)," ",fvolg,volg=j
goto &400
&424
down=2:&425,e,rekdown
goto &440
&425
print=1:tab(01,24),atb(21)
ask=1,i=&400,u=&400,/8a=&422:tab(01,24),paint(kh,ka),bere,paint(kt,0)," ",fvoor,voor=j
goto &400
&440
print=1:tab(60,05),(-13.n2),rekdeb(1)-rekcred(1)
centkode=rekkode
search=4,centkode:&400,e,centrec
print=1:tab(35,05),rekkode
sommen(1)=0
sommen(2)=0
for tel=1 to 12
sommen(3)=0
for a=1 to tel 
sommen(3)=sommen(3)+centdeb(a)-centcred(a)
next a 
print=1:tab(01,tel+6),(--),tel,(e)," ",vte,(-13.n2),centdeb(tel),centcred(tel),centdeb(tel)-centcred(tel),sommen(3)
sommen(1)=sommen(1)+centdeb(tel)
sommen(2)=sommen(2)+centcred(tel)
next tel
print=1:tab(05,22),(-13.n2),paint(kh,ka),sommen(1),sommen(2),sommen(1)-sommen(2),paint(kt,0)," "
ask=1,i=&400,u=&400,/8a=&422,/8b=&424:=j
goto &400

eseg 1

segment 2

goto &20 

&1
ret.seg

&10
ldgo.seg 7

&20 
lijntel=6
a=0
phil=0
print=1:tab(01,03),atb(22)
print=1:tab(01,03),paint(kl,0),vtb,tab(79),vte
print=1:tab(01,04),lto,gener(77,hto),rto,paint(kt,0)
print=1:tab(03,03),paint(kh,ka),"Overzicht rekeningen  F1--F2 ",paint(kt,0)
&40
ask=1,i=&1,u=&1,/80=&45,/81=&10:tab(01,06),"Geef beginrekening",esc,rekkode,tab(34)=rekkode
goto &50
&45
a=1
goto &40
&50
print=1:tab(01,05),atb(22)
print=1:tab(01,05),paint(kh,ka),"Nr",tab(06),"Reknr",tab(15),"Omschrijving",tab(39),"Debet",tab(49),"Kredit",tab(61),"Debet",tab(71),"Kredit",paint(kt,0)
&60
search=2,rekkode:&110,e,rekrec
goto &120
&105
up=2:&300,e,rekdown
goto &120
&110
if phil=1 : goto  &105
down=2:&300,e,rekdown
&120
if a=1 : goto  &150
if rekdeb(1)=0 : goto  &125
goto &150
&125
if rekdeb(2)=0 : goto  &130
goto &150
&130
if rekcred(1)=0 : goto  &135
goto &150
&135
if rekcred(2)=0 : goto  &110
&150
print=1:tab(01,lijntel),paint(kn,ka),(n2),lijntel,(e),paint(kn,ka2)," ",rekkode," ",paint(kt2,ka3)," ",rekoms,paint(kn,ka4),(-8.n2),rekdeb(1),paint(kn,ka5),rekcred(1),paint(kn,ka),rekdeb(2),paint(kn,ka2),rekcred(2)
tabel(lijntel)=rekkode
lijntel=lijntel+1
if lijntel<22 : goto  &110
&200
zoek=0
ask=1,i=&1,u=&1,"tT"=&350:tab(01,24),paint(kh,ka),bla,paint(kt,0)," T=terug ",num,ret=zoek
print=1:tab(01,24),atb(21)
if zoek=0 : goto  &210
if zoek<6 : goto  &200
if zoek>22 : goto  &200
rekkode=tabel(zoek)
search=2,rekkode:&210,e,rekdown
phil=1
goto &1
&210
print=1:tab(01,06),atb(22)
for tel=6 to 22
tabel(tel)=" "
next tel
lijntel=6
print=1:tab(01,06),atb(22)
goto &110
&300
zoek=0
ask=1,i=&1,u=&1,"tT"=&350:tab(01,24),paint(kh,ka),bere,paint(kt,0)," T=terug ",num,ret=zoek
if zoek=0 : goto  &1
if zoek<6 : goto  &300
if zoek>lijntel-1 : goto  &300
rekkode=tabel(zoek)
search=2,rekkode:&1,e,rekdown
for tel=6 to 22
tabel(tel)=" "
next tel
phil=1
goto &1
&350
if phil=1 : goto  &351
phil=1
goto &352
&351
phil=0
&352
goto &210

eseg 2

segment 3

goto &2

&1
ret.seg

&2
open=2:&1,e
&2000
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  Salderen algemene rekeningen : Jaar - Maand "
print=1:paint(kl,0),tab(01,02),gener(79,hto),paint(kt,0)
&2010
print=1:tab(01,05),paint(kt,ka), "1 --> Maandsaldering.",paint(kt,0)
print=1:tab(01,06),paint(kt,ka2),"2 --> Jaarsaldering.",paint(kt,0)
print=1:tab(01,07),paint(kt,ka3),"3 --> Maand en jaar op nul zetten.",paint(kt,0)
print=1:paint(kl,0),tab(01,09),gener(79,hto),paint(kt,0)
&2020
j=" " 
ask=1,i=&1,u=&1:tab(01,11),"Maak uw keuze  1--3",esc=j
if j="1" : goto  &2030
if j="2" : goto  &2300
if j="3" : goto  &2400
goto &2020
&2030
print=1:tab(01,18),atb(22)
print=1:tab(01,18),"Maandsaldering."
pass=" "
&2035
ask=1,i=&1,/80=&2036:tab(01,20),"Geef salderings passwoord : "=pass
pass=large(pass)
if pass=pwtest : goto  &2036
goto &1    
&2036
j=" "
ask=1,i=&1,u=&2035:tab(01,24),"Maandgetallen op nul zetten  Y-N  : "=j
j=large(j)
if j="Y" : goto  &2040
if j=" " : goto  &2036
&2040
print=1:tab(01,24),atb(21)
&2050
down=2:&2250,e,rekdown
if j="Y" : goto  &2070
if rekdeb(1)>rekcred(1) : goto  &2060
rekcred(1)=rekcred(1)-rekdeb(1)
rekdeb(1)=0
goto &2080
&2060
rekdeb(1)=rekdeb(1)-rekcred(1)
rekcred(1)=0
goto &2080
&2070
rekdeb(1)=0
rekcred(1)=0
rekdeb(2)=0
rekcred(2)=0
&2080
print=1:tab(01,22),"Bezig met rekening : ",rekkode
modif=2,rekkode:&2090,e,rekrec
goto &2050
&2090
print=1:tab(01,24),atb(21)
print=1:tab(01,24),"Fout modif rekkode : ",e," ",rekkode
stop
&2250
print=1:tab(01,24),atb(21)
ask=1,i=&1,u=&1:tab(01,24),paint(kh,ka),"Einde saldering : ",paint(kt,0),ret=j
goto &1

&2300
print=1:tab(01,18),atb(22)
print=1:tab(01,18),"Jaarsaldering."
&2310
j=" "
ask=1,i=&1,u=&2000:tab(01,20),"Overzetten naar vorig boekjaar  Y-N  : "=j
j=large(j)
if j="Y" : goto  &2320
if j<>"N" : goto  &2310
&2320
pass=" "
ask=1,i=&1,/80=&2340:tab(01,24),"Geef salderings passwoord : "=pass
pass=large(pass)
if pass=pwtest : goto  &2340
goto &2320
&2340
print=1:tab(01,24),atb(21)
open=2:&1,e
&2350
down=2:&2390,e,rekdown
if rekdeb(2)>rekcred(2) : goto  &2360
rekcred(2)=rekcred(2)-rekdeb(2)
rekdeb(2)=0
goto &2370
&2360
rekdeb(2)=rekdeb(2)-rekcred(2)
rekcred(2)=0
&2370
if j<>"Y" : goto  &2375
rekdeb(3)=rekdeb(2)
rekcred(3)=rekcred(2)
&2375
print=1:tab(01,22),"Bezig met rekening : ",rekkode
modif=2,rekkode:&2380,e,rekrec
goto &2350
&2380
print=1:tab(01,24),atb(21)
print=1:tab(01,24),"Fout modif rekkode : ",e," ",rekkode
stop
&2390
print=1:tab(01,24),atb(21)
ask=1,i=&1,u=&1:tab(01,24),paint(kh,ka),"Einde saldering : ",paint(kt,0),ret=j
goto &1

&2400
print=1:tab(01,18),atb(21)
print=1:tab(01,18),"Maand en jaar op nul zetten"
pass=" "
ask=1,/80=&2410:tab(01,24),"Geef salderingspasswoord : "=pass
pass=large(pass)
if pass=pwtest : goto  &2410
goto &1
&2410
print=1:tab(01,24),atb(21)
&2420
down=2:&2470,e,rekdown
&2430
for tel=1 to 2
rekdeb(tel)=0
rekcred(tel)=0
next tel
&2450
print=1:tab(01,20),"Bezig met rekening : ",rekkode
modif=2,rekkode:&2460,e,rekrec
goto &2420
&2460
print=1:tab(01,24),atb(21)
print=1:tab(01,24),"Fout modif rekkode : ",e," ",rekkode
stop
&2470
print=1:tab(01,24),atb(21)
ask=1,i=&2480,u=&2480:tab(01,24),paint(kh,ka),"Einde saldering : ",paint(kt,0),ret=j
&2480
dfile=14:&2490,e
&2490
goto &1

eseg 3

segment 4

goto &10

&1
ret.seg

&10
for e=1 to 9
totdebm(e)=0
totdebj(e)=0
totcredm(e)=0
totcredj(e)=0
next e
tdebm=0
tdebj=0
tcredm=0
tcredj=0
open=2
print=1:clear,paint(kl,0),ltb,gener(77,hto),rtb,paint(kt,0)
print=1:tab(20,01),paint(kh,ka),"Overzicht van de totalen per klasse",paint(kt,0)
print=1:paint(kl,0),tab(01,03),gener(79,hto)
print=1:tab(01,19),gener(79,hto)
print=1:tab(01,21),lto,gener(77,hto),rto
for e=3 to 17 step 2
print=1:tab(02,e),gener(77,hto)
next e
for e=2 to 20
print=1:tab(01,e),vtb,tab(07),vtb,tab(19),vtb,tab(31),vtb,tab(43),vtb,tab(55),vtb,tab(67),vtb,tab(79),vtb
next e
print=1:tab(02,02),paint(kh,ka),"Klas",tab(12),"Debet M",tab(23),"Kredit M",tab(36),"Saldo M",tab(48),"Debet J",tab(59),"Kredit J",tab(72),"Saldo J",paint(kt,0)
for e=1 to 7
print=1:tab(04,(e-1)*2+4),(-),e
next e
print=1:tab(02,18),"And."
print=1:tab(02,20),"Tot"
print=1:tab(02,22),"Bruto winst (klasse 6 - klasse 7 ) : "
&20
down=2:&140,e,rekdown
print=1:tab(01,24),rekkode," ",rekoms
bepklas=1
if left(reknum,1)="1" : goto  &25
bepklas=2
if left(reknum,1)="2" : goto  &25
bepklas=3
if left(reknum,1)="3" : goto  &25
bepklas=4
if left(reknum,1)="4" : goto  &25
bepklas=5
if left(reknum,1)="5" : goto  &25
bepklas=6
if left(reknum,1)="6" : goto  &25
bepklas=7
if left(reknum,1)="7" : goto  &25
bepklas=8
&25
totdebm(bepklas)=totdebm(bepklas)+rekdeb(01)
totdebj(bepklas)=totdebj(bepklas)+rekdeb(02)
totcredm(bepklas)=totcredm(bepklas)+rekcred(01)
totcredj(bepklas)=totcredj(bepklas)+rekcred(02)
sal1=totdebm(bepklas)-totcredm(bepklas)
sal2=totdebj(bepklas)-totcredj(bepklas)
print=1:paint(kn,0),tab(03,(bepklas-1)*2+4),tab(09),(-7.n2),totdebm(bepklas),tab(21),totcredm(bepklas),tab(33),sal1,tab(45),totdebj(bepklas),tab(57),totcredj(bepklas),tab(69),sal2,paint(kt,0)
goto &20
&140
for e=1 to 8
tdebm=tdebm+totdebm(e)
tdebj=tdebj+totdebj(e)
tcredm=tcredm+totcredm(e)
tcredj=tcredj+totcredj(e)
next e
sal1=tdebm-tcredm
sal2=tdebj-tcredj
print=1:tab(08,20),(-8.n2),tdebm,tab(20),tcredm,tab(32),sal1,tab(44),tdebj,tab(56),tcredj,tab(68),sal2
sal1=totdebj(6)-totcredj(6)
sal2=totdebj(7)-totcredj(7)
sal2=sal2*-1
sal1=sal2-sal1
&150
ask=1,i=&1,u=&1,/80=&160:tab(01,24),paint(kh,ka),"F1-toets=winst",paint(kt,0),esc=j
goto &1
&160
print=1:tab(40,22),paint(kn,0),(-10.n2),sal1,paint(kt,0)
ask=1,i=&1,u=&1:tab(55,22)=j
goto &1

eseg 4

segment 5
 
&5
print=1:tab(01,24),atb(21)
print=1:tab(01,20),paint(kt,ka2),"Historiek van alle rekeningen",paint(kt,0)
ask=1,i=&50,u=&50,/80=&6:tab(01,24),"Geef passwoord : "=pass
if pass=" " : goto  &5
pass=large(pass)
if pass<>pwtest : goto  &50
&6
print=1:tab(01,24),atb(21)
open=2:&50,e
&10
down=2:&50,e,rekdown
rekklas=left(rekkode,3)
rekhok="Y"
print=1:tab(01,24),rekkode," ",rekhok
modif=2,rekkode:&20,e,rekrec
goto &10
&20
print=1:tab(01,24),"Fout modif rekkode : ",e," ",rekkode
stop
&50
print=1:tab(01,24),atb(21)
ret.seg

eseg 5

segment 6

goto &400

&1
ret.seg

&400
print=1:tab(01,23),paint(kh,ka),"Opzoeken op naam van de algemene rekening ",paint(kt,0)
&405
vindrek=" "
print=1:tab(01,24),atb(21)
ask=1,i=&1,u=&1:tab(01,24),"Geef trefwoord : ",selzoek,tab(18)=selzoek
selzoek=large(selzoek)
if selzoek=" " : goto  &405
selzoek=large(selzoek)
open=2:&1,e
&410
down=2:&405,e,rekdown
rekoms=large(rekoms)
selindex=0
selindex=index(rekoms,selzoek)
if selindex=0 : goto  &410
print=1:tab(01,23),atb(22)
print=1:tab(01,23),"Trefw. : ",selzoek," Rek. : ",reknum," ",paint(kt,ka),rekoms,atb(0)
&415
j=" "
ask=1,i=&1,u=&410:tab(01,24),"Deze rekening  Y-N : "=j
j=large(j)
if j="Y" : goto  &420
if j="N" : goto  &410
goto &415
&420
vindrek=reknum
rekkode=vindrek
&435
search=2,rekkode:&436,e,rekrec
goto &1
&436
print=1:tab(01,24),"Fout search rekkode : ",e," ",rekkode
stop

eseg 6

segment 7

goto &20 

&1
ret.seg

&20 
print=1:tab(01,03),atb(22)
print=1:paint(kl,0),tab(01,03),vtb,tab(79),vte
print=1:tab(01,04),lto,gener(77,hto),rto
print=1:paint(kh,ka),tab(03,03),"Overzicht rekeningen ",paint(kt,0)
&40
print=1:tab(01,05),atb(22)
lijntel=6
for tel=1 to 3
sommen(tel)=0
next tel
ask=1,i=&1,u=&1:tab(01,06),"Geef beginrekening",esc,rekkode,tab(34)=rekkode
if rekkode=" " : goto  &40
&45
ask=1,i=&1,u=&40:tab(01,08),"Geef eindrekening ",esc,eindrek,tab(34)=eindrek
if eindrek<rekkode : goto  &40
print=1:tab(40,03),rekkode," ",eindrek
&50
print=1:tab(01,05),atb(22)
print=1:tab(01,05),"Nr",tab(06),"Reknr",tab(15),"Omschrijving",tab(39),"Debet",tab(49),"Kredit",tab(61),"Debet",tab(71),"Kredit"
&60
search=2,rekkode:&100,e,rekrec
goto &110
&100
down=2:&300,e,rekdown
&110
if rekkode>eindrek : goto  &300
&120
if rekdeb(1)<>0 
goto &150
endif

if rekdeb(2)<>0 
goto &150
endif

if rekcred(1)<>0 
goto &150
endif

if rekcred(2)=0 
goto  &100
endif 

&150
print=1:tab(01,lijntel),paint(kn,ka2),(n2),lijntel,(e)," ",paint(kt,ka3)," ",rekkode,paint(kt,ka4)," ",rekoms,(e),paint(kn,ka5),(-8.n2),rekdeb(1),paint(kn,ka2),rekcred(1),paint(kn,ka3),rekdeb(2),paint(kn,ka4),rekcred(2),paint(kt,0)
sommen(1)=sommen(1)+rekdeb(2)
sommen(2)=sommen(2)+rekcred(2)
tabel(lijntel)=rekkode
lijntel=lijntel+1
if lijntel<23 : goto  &100
&200
zoek=0
ask=1,i=&40,u=&40:tab(01,24),paint(kh,ka),bla,paint(kt,0),num,ret=zoek
print=1:tab(01,24),atb(21)
if zoek=0 : goto  &210
if zoek<6 : goto  &200
if zoek>22 : goto  &200
rekkode=tabel(zoek)
search=2,rekkode:&210,e,rekdown
phil=1
goto &1
&210
print=1:tab(01,06),atb(22)
for tel=6 to 22
tabel(tel)=" "
next tel
lijntel=6
print=1:tab(01,06),atb(22)
goto &100
&300
print=1:tab(01,20),atb(22)
print=1:paint(kl,0),tab(01,20),gener(79,hto),paint(kt,0)
print=1:tab(01,21),"Totaal Debet  = ",(-9.n2),sommen(1)
print=1:tab(01,22),"Totaal Kredit = ",(-9.n2),sommen(2)
print=1:tab(01,23),"Debet-Kredit  = ",(-9.n2),sommen(1)-sommen(2)
zoek=0
ask=1,i=&40,u=&40:tab(01,24),paint(kh,ka),bere,paint(kt,0),num,ret=zoek
if zoek=0 : goto  &40
if zoek<6 : goto  &300
if zoek>22 : goto  &300
rekkode=tabel(zoek)
search=2,rekkode:&1,e,rekrec
for tel=6 to 22
tabel(tel)=" "
next tel
phil=1
goto &1

eseg 7

segment 8

goto &200

&10
ret.seg

&200
reknum2=reknum
mareknr=reknum 
saldo=0
totdeb=0
totcred=0
lijntel=0
for i1=1 to 24
tabel(i1)=" "
next i1
loop_="O"
&201
print=1:tab(01,24),atb(21)
ask=1,i=&10,u=&10:tab(01,24),"Geef loopsekwentie ",paint(kh,ka),"N",paint(kt,0),"=normaal  ",paint(kh,ka),"O",paint(kt,0),"=omgekeerd : ",loop_," : "=loop_
loop_=large(loop_)
&202
print=1:tab(01,24),atb(21)
selma=0
ask=1,i=&10,u=&201:tab(01,24),"Geef maand 1--12 : "=selma
if selma=0 : goto  &203
if selma<1 : goto  &202
if selma>12 : goto  &202
&203
lijntel=4
print=1:clear,paint(kt,0),reknum,"  ",rekoms," Debet : ",(-8.n2),rekdeb(02),(e),"  Kredit : ",(-8.n2),rekcred(02)
print=1:tab(01,02),paint(kh,ka)," Datum     Debet     Kredit     Saldo  F/rek.   AVF K Omschrijving     ",paint(kt,0)
print=1:tab(70,03),(-8.n2),paint(kh,ka),rekdeb(02)-rekcred(02),paint(kt,0)
if loop_<>"O" : goto  &205
madat="999999"
matel=32000
goto &206
&205
madat=" "
matel=0
&206
search=3,makod9:&210,e,mahisre
&210
if loop_="O" : goto  &215
down=3:&230,e,madown
goto &216
&215
up=3:&230,e,madown
&216
if mareknr<>reknum : goto  &230
if selma=0 : goto  &217
m=substr(madatum,4,2)
tel=conv(m)
if tel<>selma : goto  &210
&217
gosub &1000
if lijntel<23 : goto  &222
&218
j=" "
ask=1,i=&10,u=&10,"bB"=&700,"sS"=&250,"tT"=&240:tab(01,24),paint(kh,ka),bla,paint(kt,0),ret=j
for i1=1 to 24
tabel(i1)=" "
next i1
print=1:tab(01,04),atb(22)
lijntel=4
&222
saldo=saldo+mabedrd-mabedrc
totdeb=totdeb+mabedrd
totcred=totcred+mabedrc
print=1:tab(01,lijntel),paint(kt,ka),madatum,paint(kn,ka2),(-8.n2),mabedrd,paint(kn,ka3),mabedrc,paint(kn,ka4),saldo,(e),"  ",paint(kt,ka5),matgfak," ",paint(kt,ka),(u),beschr,(e),paint(kt,ka2)," ",makllev,paint(kt,ka3)," ",(u15),hnm,(e),paint(kt,ka4)," ",(u10),maomsch,paint(kt,0)
tabel(lijntel-3)=makod9
lijntel=lijntel+1
goto &210
&230
print=1:tab(01,lijntel+1),"Totaal  ",(-8.n2),totdeb,totcred
ask=1,i=&10,u=&10,"b"=&700,"B"=&700,"t"=&240,"T"=&240,"s"=&250,"S"=&250:tab(01,24),paint(kh,ka),"Einde historiek : ",paint(kt,0)," ",fvoor," ",fvolg,esc=j
goto &10 
&240
print=1:tab(01,24),atb(21)
if loop_="N" : goto  &245
loop_="N"
goto &246
&245
loop_="O"
goto &246
&246
for i1=1 to 24
tabel(i1)=" "
next i1
print=1:tab(01,04),atb(22)
lijntel=4
goto &210
&250
print=1:tab(01,24),atb(21)
for lijntel=1 to 20
if tabel(lijntel)=" " : goto  &251
print=1:tab(74,lijntel+3),paint(kh,ka),(n3),lijntel,paint(kt,0)
next lijntel
&251
print=1:tab(01,24),atb(21)
&252
i1=0
ask=1,i=&217,u=&217:tab(01,24),"Geef lijnnummer te schrappen : "=i1
if i1<1 : goto  &252
if i1>23 : goto  &252
makod9=tabel(i1)
if makod9=" " : goto  &252
delete=3,makod9:&253,e
print=1:tab(01,i1+3),paint(kh,ka),space(79),paint(kt,0)
goto &251
&253
print=1:tab(70,24),e
goto &252
&700
print=1:tab(01,24),atb(21)
for lijntel=1 to 20
if tabel(lijntel)=" " : goto  &701
print=1:tab(74,lijntel+3),paint(kh,ka),(n3),lijntel,paint(kt,0)
next lijntel
&701
print=1:tab(01,24),atb(21)
&702
i1=0
ask=1,i=&217,u=&217:tab(01,24),"Geef lijnnummer te manipuleren : "=i1
if i1<1 : goto  &702
if i1>23 : goto  &702
makod9=tabel(i1)
search=3,makod9:&705,e,mahisre
goto &715
&705
up=3:&706,e,madown
goto &715
&706
print=1:tab(01,24),atb(21)
ask=1,i=&10,u=&10,/8b=&710:tab(01,24),paint(kh,ka),berb,paint(kt,0),fvolg,volg=j
goto &701
&710
down=3:&711,e,madown
goto &715
&711
print=1:tab(01,24),atb(21)
ask=1,i=&10,u=&10,/8a=&705:tab(01,24),paint(kh,ka),bere,paint(kt,0),fvoor,voor=j
goto &701
&714
makod9=" "
matel=teller(01)
teller(01)=teller(01)+1
par(3)=param3
&715
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  MANIPULATIE VAN DE HISTORIEKEN "
print=1:paint(kl,0),tab(01,02),gener(79,hto),paint(kt,0)
print=1:tab(01,05),"Rekeningnummer",tab(20),": ",mareknr
print=1:tab(01,07),"Teller inschrijving",tab(20),": ",matel
print=1:tab(01,08),"Datum bewerking ",tab(20),": ",madatum
print=1:tab(01,09),"Kode ",paint(kh,ka),"D",paint(kt,0),"ebet-",paint(kh,ka),"C",paint(kt,0),"redit",tab(20),": ",madbcr
print=1:tab(01,10),"Bedrag debet",tab(20),": ",(-9.n2),mabedrd
print=1:tab(01,11),"Bedrag kredit",tab(20),": ",(-9.n2),mabedrc
print=1:tab(01,12),"Type bewerking",tab(20),": ",makode
print=1:tab(50,11),paint(kh,ka),"1",paint(kt,0),"--> Aankoop "
print=1:tab(50,12),paint(kh,ka),"2",paint(kt,0),"--> Verkoop "
print=1:tab(50,13),paint(kh,ka),"3",paint(kt,0),"--> Financieel"
print=1:tab(50,14),paint(kh,ka),"4",paint(kt,0),"--> Opening "
print=1:tab(01,15),paint(kh,ka),"K",paint(kt,0),"lant ",paint(kh,ka),"L",paint(kt,0),"ever. ",paint(kh,ka),"A",paint(kt,0),"lgem.",tab(20),": ",makllev
print=1:tab(01,16),"Kode klant-lever-rek",tab(20),": ",maklv
print=1:tab(01,17),"Faktuur-rekening",tab(20),": ",matgfak
print=1:tab(01,18),"Omschrijving",tab(20),": ",maomsch
goto &720
&719
ask=1,i=&725,u=&780,/8a=&705,/8b=&710:tab(22,05)=mareknr
&720
ask=1,i=&725,u=&719,/8a=&705,/8b=&710:tab(22,07)=matel
&725
ask=1,i=&780,u=&720,/8a=&705,/8b=&710:tab(22,08)=madatum
madat=right(madatum,2)+substr(madatum,4,2)+left(madatum,2)
&730
ask=1,i=&780,u=&725,/8a=&705,/8b=&710:tab(22,09)=madbcr
madbcr=large(madbcr)
if madbcr="D" : goto  &735
if madbcr="C" : goto  &735
if madbcr="O" : goto  &735
goto &730
&735
ask=1,i=&780,u=&730,/8a=&705,/8b=&710:tab(22,10),(-6z.n2)=mabedrd
&738
ask=1,i=&780,u=&735,/8a=&705,/8b=&710:tab(22,11),(-6z.n2)=mabedrc
&740
ask=1,i=&780,u=&738,/8a=&705,/8b=&710:tab(22,12)=makode
if makode="1" : goto  &745
if makode="2" : goto  &745
if makode="3" : goto  &745
if makode="4" : goto  &745
goto &740
&745
ask=1,i=&780,u=&740,/8a=&705,/8b=&710:tab(22,15)=makllev
makllev=large(makllev)
if makllev="K" : goto  &750
if makllev="L" : goto  &750
if makllev="A" : goto  &750
goto &745
&750 
ask=1,i=&780,u=&745,/8a=&705,/8b=&710:tab(22,16)=maklv
maklv=large(maklv)
&755
ask=1,i=&780,u=&750,/8a=&705,/8b=&710:tab(22,17)=matgfak
matgfak=shr(matgfak)
&760
ask=1,i=&780,u=&755,/8a=&705,/8b=&710:tab(22,18)=maomsch
&780
j=" "
print=1:tab(01,22),paint(kh,ka),"F1=Bijvoegen in historiek ",paint(kt,0)
ask=1,i=&10,u=&760,/80=&790,/8a=&705,/8b=&710:tab(01,24),paint(kh,ka),vali,paint(kt,0)," (A=annulatie) : "=j
j=large(j)
if j="A" : goto  &795 
if j="Y" : goto  &785
if j="N" : goto  &715
goto &780
&785
modif=3,makod9:&790,e,mahisre
goto &715
&790
insert=3,makod9:&792,e,mahisre
goto &715
&792
matel=matel+1
goto &790
&795
delete=3,makod9:&715,e
goto &715
&1000
omsch=" "
hnm=" "
if rekhok="N" : goto  &1101 
if matgfak="Centra" : goto  &1120
&1101
if makode<>"1" : goto  &1102
beschr="Aank"
goto &1105
&1102
if makode<>"2" : goto  &1103
beschr="Verk"
goto &1105
&1103
if makode<>"3" : goto  &1104
beschr="Fin."
goto &1105
&1104
if makode<>"4" : goto  &1105
beschr="Open"
&1105
if makllev="K" : goto  &1106
if makllev="L" : goto  &1108
if makllev="A" : goto  &1110
goto &1112
&1106
search=7,maklv:&1107,e,klrec
hnm=klnaam
goto &1112
&1107
hnm=maklv
goto &1112
&1108
search=6,maklv:&1107,e,levrec
hnm=levnaam
goto &1112
&1110
if makode<>"3" : goto  &1112
search=2,matgfak:&1111,e,rekrec
hnm=rekoms
goto &1112
&1111
hnm=matgfak
&1112
search=2,reknum2:&1113,e,rekrec
goto &1114
&1113
print=1:tab(01,24),"Fout search reknum : ",(n3),e
stop
&1114
if rekhok="N" : goto  &1120
if mareknr=vastrek(11) : goto  &1116  ;niet aftrekbare btw 
if madbcr="O" : goto  &1120
if madbcr="D" : goto  &1115
mabedrd=0
goto &1120
&1115
mabedrc=0
goto &1120
&1116
if makode<>"1" : goto  &1113
mabedrd=mabedrc
mabedrc=0
&1120
return 

eseg 8

end