program "HISTORIEK REKENINGEN"

dcl totdag(12),koper%,groot,klein,tabgroot(20),gemid,gemidb0,gemido0
dcl tstbed,totdeb,totcred,saldo,soldo,saldod,saldoc,k#,bladvol#
dcl kode1$=14,selzoek$=10,vindrek$=6,selindex%,selkeuze%
dcl eindnr$=6,keuze#,beschr$=4,tabel$=14(25),drukdat$=8,druk$=1,srthm$=1
dcl ourec$=6,omsch$=10,hnm$=24,loop_$=1,tit$=40,reknum2$=6,kllvtst$=1,selma$=2
dcl oldmakod$=14,avftst$=1,selrek$=6,periode$=1

dcl surtdown$=32
field=m,surtdown
dcl surtkode$=31
field=m,surtkode
dcl surtkl$=1,surtnaam$=8,surtbed=8,surtkod9$=14
field=m

dcl sartdown$=97
field=m,sartdown
dcl sartkode$=16
field=m,sartkode
dcl brtrek$=6,brtbed$=8,brttel%,filler=1,brtrec$=80
field=m

dcl deeltot$=8
field=m,deeltot
dcl deelrec$=6,deeltel%
field=m

dcl subrek$=80
field=m,subrek
dcl subnum$=6,suboms$=24,filler=50
field=m

dcl tmadat=6     ;test madatum

#INCLUDE  "CRINCLU"
#INCLUDE  "CRINCLU2"

assign=45,"IM0",wr,ex,im

drukdat=ndat
srthm=conv(process)
assign=5,bestand(06),wr,si                        ;jaarhistoriek
assign=6,bestand(03),wr,si                        ;leveranciers
assign=7,bestand(04),wr,si                        ;klanten
assign=8,bestand(02),wr,si                        ;maandhistoriek
assign=9,bestand(01),wr,si                        ;rekeningen
assign=15,left(bestand(02),6)+"S"+srthm,wr,si     ;sort 
assign=16,left(bestand(02),6)+"N"+srthm,wr,si     ;sort op naam
open=6:&1,e
open=7:&1,e
open=9:&1,e
&10
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  HISTORIEK VAN DE REKENINGEN   ",tab(70),ndat
print=1:paint(kl,0),tab(01,02),gener(79,hto),paint(kt,0)
&11
print=1:tab(01,05),paint(kt,ka), " 1 --> Overzicht van een bepaalde rekening.",paint(kt,0)
print=1:tab(01,06),paint(kt,ka2)," 2 --> Afdruk historiek v/e bepaalde rekening.",paint(kt,0)
print=1:tab(01,07),paint(kt,ka3)," 3 --> Afdruk ingevoerde historiek.",paint(kt,0)
print=1:tab(01,08),paint(kt,ka5)," 4 --> Schrappen historiek v/e rekening.",paint(kt,0)
print=1:tab(01,09),paint(kt,ka), " 5 --> Overdracht historiek naar andere rekening.",paint(kt,0)
print=1:tab(01,10),paint(kt,ka2)," 6 --> Grafiek van een rekening.",paint(kt,0)
print=1:tab(01,11),paint(kt,ka3)," 7 --> Controle historiek t.o.v. balanstotalen.",paint(kt,0)
print=1:tab(01,12),paint(kt,ka5)," 8 --> Instellen afdrukdatum : ",drukdat,paint(kt,0)
print=1:tab(01,13),paint(kt,ka)," 9 --> Afpunten historiek v/e rekening op papier.",paint(kt,0)
print=1:tab(01,14),paint(kt,ka2),"10 --> Afpunten historiek v/e rekening op scherm.",paint(kt,0)
print=1:tab(01,15),paint(kt,ka3),"11 --> Opzoeken v/e bedrag in historiek.",paint(kt,0)
print=1:paint(kl,0),tab(01,17),gener(79,hto),paint(kt,0)
&15
selkeuze=0
ask=1,i=&1,u=&1:tab(01,19),"Maak uw keuze  1--11",esc,(nz)=selkeuze

if selkeuze=1 :  goto  &95
if selkeuze=2 
print=45:atb(70)
print=45:atb(6)
goto &95
endif
if selkeuze=3 
print=45:atb(70)
print=45:atb(6)
goto &25
endif
if selkeuze=4 :  goto  &95 
if selkeuze=5 :  goto  &95 
if selkeuze=6 :  goto  &95 
if selkeuze=7 :  goto  &600
if selkeuze=8 :  goto  &18
if selkeuze=9 
print=45:atb(70)
print=45:atb(6)
goto &17
endif
if selkeuze=10 : goto  &17
if selkeuze=11 : goto  &20
goto &15

&17
ldgo.seg 1
goto &10

&18
ask=1,i=&10,u=&10:tab(32,12)=drukdat
if len$(drukdat)<>8 : goto  &18
print=1:tab(32,12),drukdat
goto &15

&20
ldgo.seg 2
goto &10

&21
ldgo.seg 3
goto &95 

&25
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  AFDRUKKEN VAN DE HISTORIEK   ",tab(70),ndat
print=1:paint(kl,0),tab(01,02),gener(79,hto),paint(kt,0)
mareknr=" "
madatum=" "
matel=0
&26
inldat1=testd(1)
ask=1,i=&10,u=&10:tab(01,05),"Geef einddatum : ",tab(18),inldat1,tab(18)=inldat1
if len$(inldat1)<>6 : goto  &27
inldat1=left(inldat1,2)+"."+substr(inldat1,3,2)+"."+substr(inldat1,5,2)
&27
testd(1)=left(inldat1,len$(inldat1))+right(testd(1),8-len$(inldat1))
if substr(testd(1),3,1)<>"." : goto  &26
if substr(testd(1),6,1)<>"." : goto  &26
if len$(testd(1))<>8 : goto  &26
print=1:tab(18,05),testd(1)
drukdat=testd(1)
dat=testd(1) 
ldgo.seg 200
ttest1=test1
&30
ask=1,i=&10,u=&10:tab(01,07),"Geef start rekening nummer : ",(u6)=mareknr
&31
ask=1,i=&10,u=&30:tab(01,09),"Geef eind  rekening nummer : ",eindnr,tab(30),(u6)=eindnr
if (eindnr<mareknr) or (eindnr=" ") : goto  &31
gosub &50
print=45:tabv(01),naam,"  AFDRUK HISTORIEK ",tab(112),drukdat
print=45:tabv(01),gener(124,hto)
lijntel=2
matel=0
search=8,makod9:&35,e,mahisre
&35
down=8:&80,e,madown
if mareknr>eindnr : goto  &80
dat=madatum 
ldgo.seg 200
tmadat=test1
if tmadat>ttest1 : goto  &35
op &36,e
goto &39
&36
if e=83 : goto  &37
if e=115 : goto  &37
goto &39
&37
print=45:page
close=45
goto &10
&39
if ourec=mareknr : goto  &45
ourec=mareknr
if totdeb=0 : goto  &41
goto &42
&41
if totcred=0 : goto  &43
&42
print=45:tabv(01),tab(15),gener(24,hto)
print=45:tabv(01),tab(15),(-7.n2),totdeb,tab(27),totcred
lijntel=lijntel+2
&43
saldo=0
saldod=0
saldoc=0
totdeb=0
totcred=0
gosub &65
&45
reknum2=mareknr
gosub &1000
gosub &2000
goto &35

&50
j=" "
ask=1,i=&10,u=&10:tab(01,24),"O.K. om af te drukken  Y-N : "=j
j=large(j)
if j="N" : goto  &10 
if j="Y" : goto  &60 
goto &50 
&60
print=45:atb(70)
print=45:atb(6)
return

&65
search=9,ourec:&66,e,rekrec
goto &67
&66
print=45:tabv(01),"Rekening met nummer : ",ourec," werd niet gevonden : ",e
lijntel=lijntel+1
&67
if lijntel<printtel(07)-10 : goto  &69   
print=45:page
lijntel=0
&69
print=45:tabv(01),gener(124,hto)
print=45:tabv(01),"Rek : ",reknum,"  ",rekoms,"  Debet : ",(-9.n2),rekdeb(02),(e),"  Kredit : ",(-9.n2),rekcred(02),(e),"  -- Saldo : ",(-9.n2),rekdeb(02)-rekcred(02)
print=45:tabv(01),"Datum",tab(10),"Co.",tab(22),"Debet",tab(33),"Kredit",tab(41),"Soort",tab(47),"Type",tab(52),"Naam",tab(82),"Fact.nr-rek",tab(95),"Omschrijving"
print=45:tabv(01),gener(124,hto)
lijntel=lijntel+4
return

&70
print=1:tab(01,05),atb(22)
testd(1)=ndat
inldat1=testd(1)
ask=1,i=&75,u=&75:tab(01,05),"Geef begindatum : ",inldat1,tab(19)=inldat1 
if len$(inldat1)<>6 : goto  &71  
inldat1=left(inldat1,2)+"."+substr(inldat1,3,2)+"."+substr(inldat1,5,2)
&71  
testd(1)=left(inldat1,len$(inldat1))+right(testd(1),8-len$(inldat1))
if substr(testd(1),3,1)<>"." : goto  &70  
if substr(testd(1),6,1)<>"." : goto  &70   
if len$(testd(1))<>8 : goto  &70   
print=1:tab(19,05),testd(1)
dat=testd(1) 
ldgo.seg 200
ttest1=test1
&72  
inldat1=testd(1)
ask=1,i=&75,u=&70:tab(01,07),"Geef einddatum  : ",inldat1,tab(19)=inldat1 
if len$(inldat1)<>6 : goto  &73  
inldat1=left(inldat1,2)+"."+substr(inldat1,3,2)+"."+substr(inldat1,5,2)
&73  
testd(1)=left(inldat1,len$(inldat1))+right(testd(1),8-len$(inldat1))
if substr(testd(1),3,1)<>"." : goto  &72  
if substr(testd(1),6,1)<>"." : goto  &72   
if len$(testd(1))<>8 : goto  &72   
print=1:tab(19,07),testd(1)
dat=testd(1) 
ldgo.seg 200
ttest2=test1
periode="Y"
&75
goto &119

&80
if totdeb<>0 : goto  &85
if totcred<>0 : goto  &85
&81
print=45:page
close=45
goto &10
&85
print=45:tabv(01),tab(15),gener(24,hto)
print=45:tabv(01),tab(15),(-7.n2),totdeb,tab(27),totcred
lijntel=lijntel+2
goto &81

&90
ldgo.seg 4

&95
kllvtst=" "
if selkeuze=1 : goto  &96
if selkeuze=4 : goto  &97
if selkeuze=5 : goto  &98
if selkeuze=6 : goto  &99

print=1:clear,paint(kh,ka),naam,paint(kt,0),"  AFDRUKKEN HISTORIEK VAN EEN REKENING"
goto &100
&96
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  OVERZICHT HISTORIEK VAN EEN REKENING"
goto &100
&97 
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  SCHRAPPEN HISTORIEK VAN EEN REKENING"
goto &100
&98
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  OVERDRACHT HISTORIEK ANDERE REKENING"
goto &100
&99
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  GRAFIEK VAN EEN REKENING"

&100
print=1:paint(kl,0),tab(01,02),gener(79,hto),paint(kt,0)
ask=1,i=&10,u=&10,/80=&90,/8a=&105,/8b=&110,"nN"=&90:tab(01,04),"Geef rekeningnummer",esc,reknum,tab(35)=reknum 
if reknum=" " : goto  &100
search=9,reknum:&102,e,rekrec
goto &115
&102
ask=1,i=&10,/8a=&105,/8b=&110:tab(01,24),paint(kh,ka),"Rekening",ng,paint(kt,0),fvoor,voor,fvolg,volg=j
print=1:tab(01,24),atb(21)
goto &100
&105
up=9:&107,e,rekdown
if rekdeb(2)=0 : goto  &106
goto &115
&106
if rekcred(2)=0 : goto  &105
goto &115
&107
print=1:tab(01,24),atb(21)
ask=1,i=&10,u=&10,/8b=&110:tab(01,24),paint(kh,ka),berb,paint(kt,0),fvolg,volg=j
goto &95 
&110
down=9:&112,e,rekdown
if rekdeb(2)=0 : goto  &111
goto &115
&111
if rekdeb(2)=0 : goto  &110
goto &115
&112
print=1:tab(01,24),atb(21)
ask=1,i=&10,u=&10,/8a=&105:tab(01,24),paint(kh,ka),bere,paint(kt,0),fvoor,voor=j
goto &95 
&115
print=1:tab(01,03),atb(22)
print=1:tab(01,05),"Nummer : ",reknum
print=1:tab(01,07),"Naam   : ",paint(kh,ka),left(rekoms,len$(rekoms)),paint(kt,0),atb(21)
print=1:tab(01,09),"Klasse : ",rekklas
print=1:tab(01,11),"Totaal debet",tab(20),": ",(-9.n2),rekdeb(02)
print=1:tab(01,12),"Totaal kredit",tab(20),": ",(-9.n2),rekcred(02)
print=1:tab(20,13),gener(15,hto)
print=1:tab(01,14),"Saldo  ",tab(20),": ",(-9.nz),rekdeb(02)-rekcred(02)
print=1:paint(kl,0),tab(01,16),gener(79,hto),paint(kt,0)
goto &117
&116
bladvol=1    ;niet stoppen op vol scherm aan
&117
if phil=1 : goto  &118
j="Y"
ask=1,i=&10,u=&10,/80=&714,/81=&116,/8a=&105,/8b=&110:tab(01,18),"Deze rekening  Y-N : ",j,tab(22)=j
j=large(j)
if j="N" : goto  &95 
if j<>"Y" : goto  &117
&118
print=1:tab(01,20),atb(22)
selma="  "
reknum2=reknum
mareknr=reknum 
saldo=0
saldod=0
saldoc=0
totdeb=0
totcred=0
lijntel=0
periode=" "
ask=1,i=&10,u=&10,/8a=&105,/8b=&110,/80=&70:tab(01,20),"Geef maandkeuze : ",selma,tab(19),(nz)=selma
&119
phil=0
if selkeuze=1 : goto  &200
if selkeuze=4 : goto  &300
if selkeuze=5 : goto  &400
if selkeuze=6 : goto  &21
lijntel=0
gosub &69
mareknr=reknum
madat=" "
matel=0
search=8,makod9:&120,e,mahisre
&120
down=8:&140,e,madown
op &125,e
goto &130
&125
if e=83 : goto  &140
if e=115 : goto  &140
&130
if mareknr<>reknum : goto  &140
if selma="  " : goto  &131
if substr(madatum,4,2)<>selma : goto  &120
&131
if periode<>"Y" : goto &135
dat=madatum
ldgo.seg 200
ttest3=test1
if ttest3<ttest1 : goto &120
if ttest3>ttest2 : goto &120
&135
gosub &1000
gosub &2000
goto &120
&140
if totdeb<>0 : goto  &190
if totcred<>0 : goto  &190
&185
print=45:page
close=45
goto &10 
&190
print=45:tabv(01),tab(15),gener(24,hto)
print=45:tabv(01),tab(15),(-7.n2),totdeb,tab(27),totcred
lijntel=lijntel+2
goto &185

&195
print=1:tab(01,21),atb(22)
klkode=" "
ask=1,i=&95,u=&200:tab(01,21),"Geef klantenkode : "=klkode
klkode=large(klkode)
search=7,klkode:&195,e,klrec
kllvtst="K"
print=1:tab(01,21),atb(21)
print=1:tab(01,21),"Klant : ",klkode
goto &200
&196
print=1:tab(01,21),atb(22)
levkode=" "
ask=1,i=&95,u=&200:tab(01,21),"Geef leverancierskode : "=levkode
levkode=large(levkode)
search=6,levkode:&196,e,levrec
kllvtst="L"
print=1:tab(01,22),atb(21)
print=1:tab(01,22),"Lever : ",levkode
goto &200
&197
print=1:tab(01,22),atb(22)
avftst=" "
ask=1,i=&95,u=&118:tab(01,22),"1=Aankoop 2=Verkoop 3=Financ. 4=Opening : "=avftst
if avftst=" " : goto &200
if avftst="1" : goto &200
if avftst="2" : goto &200
if avftst="3" : goto &200
if avftst="4" : goto &200
goto &197
&198
print=1:tab(01,22),atb(22)
selrek=" "
ask=1,i=&95,u=&200:tab(01,22),"Geef rekeningnummer : "=selrek
if selrek=" " : goto &198
&200
for i1=1 to 24
tabel(i1)=" "
next i1
print=1:tab(01,20),atb(21)
print=1:tab(01,20),"Maand : ",selma
print=1:tab(01,22),atb(21)
print=1:tab(01,22),"A/V/F : ",avftst 
print=1:tab(01,23),atb(22)
print=1:tab(01,23),"F1=Hist. klant  F2=Hist. lever  F3=A/V/F. F4=Rekening"
loop_="O"
ask=1,i=&95,u=&95,/80=&195,/81=&196,/82=&197,/83=&198:tab(01,24),"Geef loopsekwentie ",paint(kh,ka),"N",paint(kt,0),"=normaal  ",paint(kh,ka),"O",paint(kt,0),"=omgekeerd : ",loop_," : "=loop_
loop_=large(loop_)
lijntel=4
print=1:clear,paint(kt,0),reknum,"  ",rekoms," Debet : ",(-8.n2),rekdeb(02),(e),"  Kredit : ",(-8.n2),rekcred(02)
print=1:tab(01,02),paint(kh,ka)," Datum       Debet    Kredit    Saldo  F/rek.  AVF K Omschrijving     ",paint(kt,0)
print=1:tab(69,03),(-9.n2),paint(kh,ka),rekdeb(02)-rekcred(02),paint(kt,0)
if loop_<>"O" : goto  &205
matel=32000
madat="999999"
goto &206
&205
madat=" "
matel=0
&206
search=8,makod9:&210,e,mahisre
&210
if loop_="O" : goto  &211
down=8:&230,e,madown
goto &212
&211
up=8:&230,e,madown
&212
if mareknr<>reknum : goto  &230
if selma="  " : goto  &213
if substr(madatum,4,2)<>selma : goto  &210
&213
if periode<>"Y" : goto &214
dat=madatum
ldgo.seg 200
ttest3=test1
if ttest3<ttest1 : goto &210
if ttest3>ttest2 : goto &210
&214
if avftst=" " : goto  &215
if makode=avftst : goto  &215
goto &210
&215
if selrek=" " : goto &216
if matgfak=selrek : goto &216
goto &210
&216
gosub &1000
if lijntel<23 : goto  &222
&217
if bladvol=1 : goto  &218
j=" "
ask=1,i=&95,u=&95,/80=&700,"bB"=&700,"sS"=&250,"tT"=&240,/8a=&105,/8b=&110:tab(01,24),paint(kh,ka),bla,paint(kt,0),ret=j
&218
for i1=1 to 24
tabel(i1)=" "
next i1
print=1:tab(01,04),atb(22)
lijntel=4
&222
if kllvtst<>"K" : goto  &223 
if maklv<>klkode : goto  &210 
goto &225
&223 
if kllvtst<>"L" : goto  &225 
if maklv<>levkode : goto  &210 
&225
if mabedrd=0 : goto  &226
goto &228
&226
if mabedrc=0 : goto  &227
goto &228
&227
;delete=8,makod9:&228,e
&228
on error goto &229,e
saldo=saldo+mabedrd-mabedrc
saldod=saldod+mabedrd
saldoc=saldoc+mabedrc
totdeb=totdeb+mabedrd
totcred=totcred+mabedrc
print=1:tab(01,lijntel),paint(kt,ka),madatum,paint(kn,ka2),(-7.n2),mabedrd,paint(kn,ka3),mabedrc,paint(kn,ka4),saldo,(e),"  ",paint(kt,ka5),matgfak," ",paint(kt,ka),(u3),beschr,(e),paint(kt,ka2)," ",makllev,paint(kt,ka3)," ",(u15),hnm,(e),paint(kt,ka4)," ",(u11),maomsch,paint(kt,0)
tabel(lijntel-3)=makod9
lijntel=lijntel+1
goto &210
&229
j=" "
ask=1,i=&210,u=&210:tab(01,24),"Fout in bestand  record schrappen  Y-N : "=j
j=large(j)
if j<>"Y" : goto  &210
delete=8,makod9:&210,e
goto &210
&230
bladvol=0
print=1:tab(01,lijntel+1),"Totaal  ",(-7.n2),totdeb,totcred
ask=1,i=&95,u=&95,/80=&700,"bB"=&700,"tT"=&240,"sS"=&250,/8a=&105,/8b=&110:tab(01,24),paint(kh,ka),"Einde historiek : ",paint(kt,0)," ",fvoor," ",fvolg,esc=j
goto &95 
&240
print=1:tab(01,24),atb(21)
if loop_="N" : goto  &245
loop_="N"
goto &246
&245
loop_="O"
goto &246
&246
for i1=1 to 24
tabel(i1)=" "
next i1
print=1:tab(01,04),atb(22)
lijntel=4
goto &210
&250
print=1:tab(01,24),atb(21)
for lijntel=1 to 20
if tabel(lijntel)=" " : goto  &251
print=1:tab(74,lijntel+3),paint(kh,ka),(---),lijntel,paint(kt,0)
next lijntel
&251
print=1:tab(01,24),atb(21)
&252
i1=0
ask=1,i=&217,u=&217:tab(01,24),"Geef lijnnummer te schrappen : "=i1
if i1<1 : goto  &252
if i1>23 : goto  &252
makod9=tabel(i1)
if makod9=" " : goto  &252
delete=8,makod9:&253,e
print=1:tab(01,i1+3),paint(kh,ka),space(79),paint(kt,0)
goto &251
&253
print=1:tab(70,24),e
goto &252

&300
passwoord=" "
print=1:tab(01,24),atb(21)
ask=1,i=&10,u=&95,/80=&302:tab(01,24),"Schrappen historiek voor deze rekening : ",paint(kt,0),"  Geef passwoord : "=passwoord
passwoord=large(passwoord)
if passwoord=pwtest : goto  &302
print=1:tab(01,24),atb(21)
ask=1,i=&95,u=&95:tab(01,24),bell,"Foutief passwoord "=j
goto &95 

&302
print=1:tab(01,24),atb(21)
madat=" "
matel=0
search=8,makod9:&320,e,mahisre
&320
down=8:&330,e,madown
if mareknr<>reknum : goto  &95 
print=1:tab(40,23),madatum," ",mareknr
delete=8,makod9:&321,e
goto &320
&321
print=1:tab(01,24),"Fout schrappen record historiek ",e," ",mareknr," ",matel
stop
&330
print=1:tab(01,24),atb(21)
ask=1,i=&95,u=&95,/8a=&105,/8b=&110:tab(01,24),paint(kh,ka),"Einde historiek : ",paint(kt,0),fvoor," ",fvolg,esc=j
goto &95 

&400
passwoord=" "
print=1:tab(01,24),atb(21)
ask=1,i=&95,u=&95,/80=&402:tab(01,24),"Overdracht historiek voor deze rekening : ",paint(kt,0),"  Geef passwoord : "=passwoord
passwoord=large(passwoord)
if passwoord=pwtest : goto  &402
print=1:tab(01,24),atb(21)
ask=1,i=&95,u=&95:tab(01,24),"Foutief passwoord "=j
goto &95 
&402
print=1:tab(01,24),atb(21)
deelrec=" "
ask=1,i=&95,u=&95:tab(01,24),"Geef nieuwe rekeningnummer : "=deelrec
deelrec=large(deelrec)
if deelrec=" " : goto  &402
&403
j=" "
print=1:tab(01,23),atb(21)
ask=1,i=&95,u=&402:tab(01,23),"O.K. voor uitvoering  Y-N : "=j
j=large(j)
if j="N" : goto  &95 
if j<>"Y" : goto  &403
&405
madat=" "
matel=0
search=8,makod9:&420,e,mahisre
&420
down=8:&430,e,madown
if mareknr<>reknum : goto  &95 
print=1:tab(60,23),madatum," ",mareknr
kode1=makod9
deeltel=matel
&421
insert=8,deeltot:&422,e,mahisre
goto &423
&422
deeltel=deeltel+1
goto &421
&423
delete=8,kode1:&424,e
goto &420
&424
print=1:tab(01,24),"Fout schrappen record historiek : ",e," ",mareknr," ",matel
stop
&430
print=1:tab(01,24),atb(21)
ask=1,i=&95,u=&95,/8a=&105,/8b=&110:tab(01,24),paint(kh,ka),"Einde overname historiek :",paint(kt,0)," ",fvoor," ",fvolg,esc=j

&600
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  TEST KONTROLE OP GELIJKHEID HISTORIEK EN BALANS"
print=1:paint(kl,0),tab(01,02),gener(79,hto),paint(kt,0)
print=1:tab(01,04)
lijntel=1
ourec=" "
open=8:&10,e
&625
down=8:&695,e,madown
op &626,e
goto &630
&626
if e=83 : goto  &10
if e=115 : goto  &10
&630
if ourec=mareknr : goto  &650
if ourec=" " : goto  &637
print=1:paint(kn,ka5),(-8.n2),saldo,paint(kt,0)
saldo=roun(saldo,2)
soldo=roun(soldo,2)
if saldo=soldo : goto  &637
print=1:tabv(01),bell,">",(-8.n2),abs(saldo-soldo)
lijntel=lijntel+1
ask=1:=j
&637
ourec=mareknr
saldo=0
soldo=0
saldod=0
saldoc=0
search=9,ourec:&640,e,rekrec
if rekhok<>"Y" : gosub  &698
goto &645
&640
if e=78 : goto  &641
print=1:tabv(02),"Fout zoeken rekening : ",e," ",mareknr
goto &645
&641
delete=8,makod9:&625,e
goto &625
&645
if lijntel<20 : goto  &646
ask=1:=j
print=1:tab(01,04),atb(22)
lijntel=1
&646
print=1:tabv(01),paint(kn,ka),reknum," ",paint(kt,ka2)," ",left(rekoms,20)," ",paint(kn,ka3),(-9.n2),rekdeb(2),paint(kn,ka4),rekcred(2),paint(kn,ka),rekdeb(2)-rekcred(2)
lijntel=lijntel+1
soldo=rekdeb(2)-rekcred(2)
&650
if madbcr=" " : gosub  &698
if madbcr="O" : gosub  &698
if madbcr="D" : goto  &653
mabedrd=0
goto &654
&653
mabedrc=0
&654
saldo=saldo+mabedrd-mabedrc
goto &625
&695
print=1:paint(kn,ka5),(-8.n2),soldo,paint(kt,0)
soldo=roun(soldo,2)
saldo=roun(saldo,2)
if soldo=saldo : goto  &696
print=1:tabv(01)," >> ",(-4.n6),abs(saldo-soldo)
&696
ask=1,i=&10,u=&10:=j
goto &10
&698
delete=8,makod9:&625,e
return

&700
print=1:tab(01,24),atb(21)
for lijntel=1 to 20
if tabel(lijntel)=" " : goto  &701
print=1:tab(74,lijntel+3),paint(kh,ka),(---),lijntel,paint(kt,0)
next lijntel
&701
print=1:tab(01,24),atb(21)
&702
i1=0
ask=1,i=&217,u=&217:tab(01,24),"Geef lijnnummer te manipuleren : "=i1
if i1<1 : goto  &702
if i1>23 : goto  &702
makod9=tabel(i1)
search=8,makod9:&705,e,mahisre
goto &715
&705
up=8:&706,e,madown
goto &715
&706
print=1:tab(01,24),atb(21)
ask=1,i=&10,u=&10,/8b=&710:tab(01,24),paint(kh,ka),berb,paint(kt,0),fvolg,volg=j
goto &701
&710
down=8:&711,e,madown
goto &715
&711
print=1:tab(01,24),atb(21)
ask=1,i=&10,u=&10,/8a=&705:tab(01,24),paint(kh,ka),bere,paint(kt,0),fvoor,voor=j
goto &701
&714
makod9=" "
matel=teller(01)
teller(01)=teller(01)+1
par(3)=param3
&715
oldmakod=makod9
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  MANIPULATIE VAN DE HISTORIEKEN "
print=1:paint(kl,0),tab(01,02),gener(79,hto),paint(kt,0)
print=1:tab(01,05),"Rekeningnummer",tab(20),": ",mareknr
print=1:tab(01,07),"Teller inschrijving",tab(20),": ",matel
print=1:tab(01,08),"Datum bewerking ",tab(20),": ",madatum
print=1:tab(01,09),"Code ",paint(kh,ka),"D",paint(kt,0),"ebet-",paint(kh,ka),"C",paint(kt,0),"redit",tab(20),": ",madbcr
print=1:tab(01,10),"Bedrag debet",tab(20),": ",(-9.n2),mabedrd
print=1:tab(01,11),"Bedrag kredit",tab(20),": ",(-9.n2),mabedrc
print=1:tab(01,12),"Type bewerking",tab(20),": ",makode
print=1:tab(50,11),paint(kh,ka),"1",paint(kt,0),"--> Aankoop "
print=1:tab(50,12),paint(kh,ka),"2",paint(kt,0),"--> Verkoop "
print=1:tab(50,13),paint(kh,ka),"3",paint(kt,0),"--> Financieel"
print=1:tab(50,14),paint(kh,ka),"4",paint(kt,0),"--> Opening "
print=1:tab(01,15),paint(kh,ka),"K",paint(kt,0),"lant ",paint(kh,ka),"L",paint(kt,0),"ever. ",paint(kh,ka),"A",paint(kt,0),"lgem.",tab(20),": ",makllev
print=1:tab(01,16),"Klant Lever Rekening",tab(22),": ",maklv
print=1:tab(01,17),"Factuur-rekening",tab(20),": ",matgfak
print=1:tab(01,18),"Omschrijving",tab(20),": ",maomsch
goto &720
&719
ask=1,i=&10,u=&10,/8a=&705,/8b=&710:tab(22,05)=mareknr
&720
ask=1,i=&10,u=&719,/8a=&705,/8b=&710:tab(22,07)=matel
&725
ask=1,i=&780,u=&720,/8a=&705,/8b=&710:tab(22,08)=madatum
madat=right(madatum,2)+substr(madatum,4,2)+left(madatum,2)
&730
ask=1,i=&780,u=&725,/8a=&705,/8b=&710:tab(22,09)=madbcr
madbcr=large(madbcr)
if madbcr="D" : goto  &735
if madbcr="C" : goto  &735
if madbcr="O" : goto  &735
goto &730
&735
ask=1,i=&780,u=&730,/8a=&705,/8b=&710:tab(22,10),(-8z.n2)=mabedrd
&738
ask=1,i=&780,u=&735,/8a=&705,/8b=&710:tab(22,11),(-8z.n2)=mabedrc
&740
ask=1,i=&780,u=&738,/8a=&705,/8b=&710:tab(22,12)=makode
if makode="1" : goto  &745
if makode="2" : goto  &745
if makode="3" : goto  &745
if makode="4" : goto  &745
goto &740
&745
ask=1,i=&780,u=&740,/8a=&705,/8b=&710:tab(22,15)=makllev
makllev=large(makllev)
if makllev="K" : goto  &750
if makllev="L" : goto  &750
if makllev="A" : goto  &750
goto &745
&750 
ask=1,i=&780,u=&745,/8a=&705,/8b=&710:tab(24,16)=maklv
maklv=large(maklv)
&755
ask=1,i=&780,u=&750,/8a=&705,/8b=&710:tab(22,17)=matgfak
&760
ask=1,i=&780,u=&755,/8a=&705,/8b=&710:tab(22,18)=maomsch
&780
j=" "
print=1:tab(01,22),paint(kh,ka),"F1=Bijvoegen in historiek ",paint(kt,0)
ask=1,i=&10,u=&760,/80=&790,/8a=&705,/8b=&710:tab(01,24),paint(kh,ka),vali,paint(kt,0)," (A=annulatie) : "=j
j=large(j)
if j="A" : goto  &795 
if j="Y" : goto  &785
if j="N" : goto  &715
goto &780
&785
delete=8,oldmakod:&790,e
&790
insert=8,makod9:&792,e,mahisre
goto &715
&792
matel=matel+1
goto &790
&795
delete=8,makod9:&715,e
goto &715

&1000
omsch=" "
hnm=" "
if rekhok="N" : goto  &1101 
if large(matgfak)="CENTRA" : goto  &1120
&1101
if makode<>"1" : goto  &1102
beschr="Aank"
goto &1105
&1102
if makode<>"2" : goto  &1103
beschr="Verk"
goto &1105
&1103
if makode<>"3" : goto  &1104
beschr="Fin."
goto &1105
&1104
if makode<>"4" : goto  &1105
beschr="Open"
&1105
if makllev="K" : goto  &1106
if makllev="L" : goto  &1108
if makllev="A" : goto  &1110
goto &1112
&1106
search=7,maklv:&1107,e,klrec
hnm=klnaam
goto &1112
&1107
hnm=maklv
goto &1112
&1108
search=6,maklv:&1107,e,levrec
hnm=levnaam
goto &1112
&1110
if makode<>"3" : goto  &1112
search=9,matgfak:&1111,e,rekrec
hnm=rekoms
goto &1112
&1111
hnm=matgfak
&1112
search=9,reknum2:&1113,e,rekrec
goto &1114
&1113
print=1:tab(01,24),"Fout search reknum : ",(-3),e,(e),reknum2
stop     
&1114
if rekhok="N" : goto  &1120
;if mareknr=vastrek(11) goto 1116  ;niet aftrekbare btw 
if madbcr="O" : goto  &1120
if madbcr="D" : goto  &1115
mabedrd=0
goto &1120
&1115
mabedrc=0
goto &1120
&1116
if makode<>"1" : goto  &1113
mabedrd=mabedrc
mabedrc=0
&1120
return 

&2000
if lijntel<printtel(07)-10 : goto  &2225
print=45:page
print=45:tabv(01),gener(124,hto)
print=45:tabv(01),"Rek : ",reknum,"  ",rekoms,"  Debet : ",(-9.n2),rekdeb(02),(e),"  Kredit : ",(-9.n2),rekcred(02),(e),"  -- Saldo : ",(-9.n2),rekdeb(02)-rekcred(02)
print=45:tabv(01),"Datum",tab(10),"Co.",tab(18),"Debet",tab(27),"Kredit",tab(35),"Soort",tab(45),"Type",tab(50),"Naam",tab(80),"Fact.nr-rek",tab(99),"Omschrijving"
print=45:tabv(01),gener(124,hto)
lijntel=4
&2225
saldo=saldo+mabedrd-mabedrc
print=1:tab(01,24),madatum," ",madbcr,(-7.n2),mabedrd,mabedrc,(e),makllev,matgfak,(-7.n2),saldo
print=45:tabv(01),madatum,tab(11),madbcr,tab(15),(-7.n2),mabedrd,tab(27),mabedrc,tab(39),(u8),omsch,tab(48),(u),makllev,tab(52),(u24),hnm,tab(82),(u6),matgfak,tab(92),(u15),maomsch,(-10.n2),saldo
lijntel=lijntel+1
totdeb=totdeb+mabedrd
totcred=totcred+mabedrc
return  

eseg 0

segment 1

goto &10 
&1
ret.seg
&5
ldgo.seg 4
&10
if selkeuze=9 : goto  &20
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  AFPUNTING REKENING OP SCHERM"
goto &30
&20
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  AFPUNTING REKENING OP PAPIER"
&30
print=1:paint(kl,0),tab(01,02),gener(79,hto),paint(kt,0)
&100
print=1:tab(01,04),atb(22)
ask=1,i=&1,u=&1,/8a=&105,/8b=&110,"nN"=&5:tab(01,04),"Geef rekeningnummer",esc,reknum,tab(35)=reknum
if reknum=" " : goto  &100
search=9,reknum:&102,e,rekrec
goto &115
&102
print=1:tab(01,24),atb(21)
ask=1,i=&10,/8a=&105,/8b=&110:tab(01,24),paint(kh,ka),"Rekening",ng,paint(kt,0),fvoor," ",fvolg=j
goto &10 
&105
up=9:&106,e,rekdown
goto &115
&106
print=1:tab(01,24),atb(21)
ask=1,i=&10,u=&10,/8b=&110:tab(01,24),paint(kh,ka),berb,paint(kt,0),fvolg,volg=j
goto &10 
&110
down=9:&111,e,rekdown
goto &115
&111
ask=1,i=&10,u=&10,/8a=&105:tab(01,24),paint(kh,ka),bere,paint(kt,0)," ",fvoor,voor=j
goto &10
&115
print=1:tab(01,03),atb(22)
print=1:tab(01,05),"Nummer : ",reknum
print=1:tab(01,07),"Naam   : ",paint(kh,ka),left(rekoms,len$(rekoms)),paint(kt,0)
print=1:tab(01,09),"Klasse : ",rekklas
print=1:tab(01,11),"Totaal debet",tab(20),": ",(-8z.n2),rekdeb(02)
print=1:tab(01,12),"Totaal kredit",tab(20),": ",(-8z.n2),rekcred(02)
print=1:tab(20,13),gener(15,hto)
print=1:tab(01,14),"Saldo  ",tab(20),": ",(-8z.n2),rekdeb(02)-rekcred(02)
print=1:paint(kl,0),tab(01,16),gener(79,hto),paint(kt,0)
&116
j=" "
ask=1,i=&10,u=&10,/8a=&105,/8b=&110:tab(01,18),"Deze rekening  Y-N : ",j,tab(22)=j
j=large(j)
if j="N" : goto  &10 
if j<>"Y" : goto  &116
&117
selma="  "
ask=1,i=&10,u=&116:tab(01,20),"Geef maandkeuze : ",(zz)=selma
if selma="  " : goto &118
if selma<"01" : goto &117
if selma>"12" : goto &117
&118
j=" "
ask=1,i=&10,u=&116:tab(01,22),"Sortering   N=naam  B=bedrag  S=naam+bedrag : "=j
j=large(j)
if j="B" : goto  &500
if j="N" : goto  &600
if j="S" : goto  &700
goto &118
&120
saldo=0
saldod=0
saldoc=0
totdeb=0
totcred=0
open=15:&10,e
if selkeuze=10 : goto  &220
print=45:tabv(01),gener(124,hto)
print=45:tabv(01),"Rek : ",reknum,"  ",rekoms,"  Debet : ",(-9.n2),rekdeb(02),(e),"  Kredit : ",(-9.n2),rekcred(02),(e),"  -- Saldo : ",(-9.n2),rekdeb(02)-rekcred(02)
print=45:tabv(01),"Datum",tab(10),"Co.",tab(18),"Debet",tab(27),"Kredit",tab(35),"Soort",tab(45),"Type",tab(50),"Naam",tab(80),"Fact.nr-rek",tab(99),"Omschrijving"
print=45:tabv(01),gener(124,hto)
lijntel=lijntel+4
&125
down=15:&150,e,sartdown
mahisre=brtrec
if selma="  " : goto  &126
if substr(madatum,4,2)<>selma : goto  &125
&126
gosub &1000
gosub &2000
goto &125
&130
open=16:&10,e
totdeb=0
totcred=0
if selkeuze=10 : goto  &230
print=45:tabv(01),gener(124,hto)
print=45:tabv(01),"Rek : ",reknum,"  ",rekoms,"  Debet : ",(-9.n2),rekdeb(02),(e),"  Kredit : ",(-9.n2),rekcred(02),(e),"  -- Saldo : ",(-9.n2),rekdeb(02)-rekcred(02)
print=45:tabv(01),"Datum",tab(10),"Co.",tab(18),"Debet",tab(27),"Kredit",tab(35),"Soort",tab(45),"Type",tab(50),"Naam",tab(80),"Fact.nr-rek",tab(99),"Omschrijving"
print=45:tabv(01),gener(124,hto)
lijntel=lijntel+4
&135
down=16:&150,e,surtdown
makod9=surtkod9
search=8,makod9:&135,e,mahisre
gosub &1000
gosub &2000
goto &135
&150
if totdeb<>0 : goto  &190
if totcred<>0 : goto  &190
&185
print=45:page
close=45
goto &10
&190
print=45:tabv(01),gener(80,hto)
print=45:tabv(01),"Debet  : ",tab(15),(-7.n2),totdeb
print=45:tabv(01),"Kredit : ",tab(15),(-7.n2),totcred,totdeb-totcred
lijntel=lijntel+3
goto &185

&220
print=1:clear,paint(kt,0),reknum,"  ",paint(kh,ka),rekoms,paint(kt,0),"  -- Saldo : ",(-9.n2),rekdeb(2)-rekcred(2)
print=1:tab(01,02),"Datum",tab(10),"Code",tab(18),"Bedrag"
print=1:paint(kl,0),tab(01,03),gener(80,hto),paint(kt,0)
lijntel=4
&225
down=15:&250,e,sartdown
mahisre=brtrec
if selma="  " : goto  &226
if substr(madatum,4,2)<>selma : goto  &225
&226
gosub &1000
gosub &3000
goto &225
&230
print=1:clear,paint(kt,0),reknum,"  ",paint(kh,ka),rekoms,paint(kt,0),"  -- Saldo : ",(-9.n2),rekdeb(2)-rekcred(2)
print=1:tab(01,02),"Datum",tab(10),"Code",tab(18),"Bedrag"
print=1:tab(30,02),"Debet  : ",(-7.n2),totdeb
print=1:tab(50,02),"Credit : ",(-7.n2),totcred,totdeb-totcred
print=1:paint(kl,0),tab(01,03),gener(80,hto),paint(kt,0)
lijntel=4
&240
down=16:&250,e,surtdown
makod9=surtkod9
search=8,makod9:mahisre
gosub &1000
gosub &3000
goto &240
&250
if totdeb<>0 : goto  &260
if totcred<>0 : goto  &260
goto &10 
&260
print=1:paint(kl,0),tabv(01),gener(80,hto),paint(kt,0)
ask=1,i=&10,u=&10:tab(01,24),paint(kh,ka),bere,paint(kt,0),ret,esc=j
goto &10 

&500
dfile=15:&510,e
&510
cfile=15,d=80,lk=16
&515
tel=0
mareknr=reknum
madat=" "
matel=0
search=8,makod9:&520,e,mahisre
&520
down=8:&120,e,madown
tel=tel+1
op &550,e
&530
if mareknr<>reknum : goto  &120
brtrek=mareknr
brttel=tel
if mabedrd=0 : goto  &535
brtbed=conv(abs(mabedrd))
goto &540
&535
brtbed=conv(abs(mabedrc))
&540
print=1:tab(55,07),mareknr," ",madatum," ",matel
insert=15,sartkode:&545,e,mahisre
goto &520
&545
print=1:tab(01,24),"Fout bijvoegen tijdens sorterening : ",e," ",sartkode
stop
&550
if e=83 : goto  &10 
if e=115 : goto  &10 
goto &530

&600
dfile=15:&610,e
&610
cfile=15,d=80,lk=16
&615
tel=0
mareknr=reknum
madat=" "
matel=0
search=8,makod9:&620,e,mahisre
&620
down=8:&120,e,madown
tel=tel+1
op &650,e
&630
if mareknr<>reknum : goto  &120
brtrek=mareknr
brtbed=shl(maklv)
brttel=tel
print=1:tab(40,07),mareknr," ",madatum," ",makllev," ",maklv," ",(-6),matel
insert=15,sartkode:&640,e,mahisre
goto &620
&640
print=1:tab(01,24),"Fout insert sartkode : ",(-3),e," ",(e),sartkode
stop
&650
if e=83 : goto  &10 
if e=115 : goto  &10 
goto &630

&700
dfile=16:&710,e
&710
cfile=16,k=31:&1,e
&715
tel=0
mareknr=reknum
madat=" "
matel=0
search=8,makod9:&720,e,mahisre
&720
down=8:&120,e,madown
if mareknr<>reknum : goto  &130
surtkl=makllev
surtnaam=maklv
surtkod9=makod9
mabedrd=mabedrd+mabedrc
surtbed=mabedrd
op &750,e
&730
insert=16,surtkode:&745,e
print=1:tab(40,07),mareknr," ",madatum," ",makllev," ",maklv," ",(-6),tel
tel=tel+1
goto &720
&745
print=1:tab(01,24),"Fout insert surtkode : ",(-3),e," ",(e),surtkode
stop
&750
if e=83 : goto  &10 
if e=115 : goto  &10 
goto &730

&1000
omsch=" "
hnm=" "
if rekhok="N" : goto  &1101 
if large(matgfak)="CENTRA" : goto  &1150
&1101
if makode<>"1" : goto  &1102
beschr="Aank"
goto &1105
&1102
if makode<>"2" : goto  &1103
beschr="Verk"
goto &1105
&1103
if makode<>"3" : goto  &1104
beschr="Fin."
goto &1105
&1104
if makode<>"4" : goto  &1105
beschr="Open"
&1105
if makllev="K" : goto  &1106
if makllev="L" : goto  &1108
if makllev="A" : goto  &1110
goto &1112
&1106
search=7,maklv:&1107,e,klrec
hnm=klnaam
goto &1112
&1107
hnm=maklv
goto &1112
&1108
search=6,maklv:&1107,e,levrec
hnm=levnaam
goto &1112
&1110
if makode<>"3" : goto  &1112
search=9,matgfak:&1111,e,rekrec
hnm=rekoms
goto &1112
&1111
hnm=matgfak
&1112
if rekhok="N" : goto  &1120
if mareknr=vastrek(11) : goto  &1116  ;niet aftrekbare btw 
&1113
if madbcr="O" : goto  &1120
if madbcr="D" : goto  &1115
mabedrd=0
goto &1120
&1115
mabedrc=0
goto &1120
&1116
if makode<>"1" : goto  &1113
mabedrd=mabedrc
mabedrc=0
&1120
return 
&1150
goto &1120

&2000
if lijntel+6<>printtel(07) : goto  &2225
print=45:page
print=45:tabv(01),gener(124,hto)
print=45:tabv(01),"Rek : ",reknum,"  ",rekoms,"  Debet : ",(-9.n2),rekdeb(02),(e),"  Kredit : ",(-9.n2),rekcred(02),(e),"  -- Saldo : ",(-9.n2),rekdeb(02)-rekcred(02)
print=45:tabv(01),"Datum",tab(10),"Co.",tab(18),"Debet",tab(27),"Kredit",tab(35),"Soort",tab(45),"Type",tab(50),"Naam",tab(80),"Fact.nr-rek",tab(99),"Omschrijving"
print=45:tabv(01),gener(124,hto)
lijntel=4
&2225
totdeb=totdeb+mabedrd
totcred=totcred+mabedrc
saldo=totdeb-totcred
print=45:tabv(01),madatum,tab(11),madbcr,tab(15),(-6.n2),mabedrd,tab(25),mabedrc,tab(35),(u9),omsch,tab(46),(u),makllev,tab(50),(u24),hnm,tab(80),(u6),matgfak,tab(90),(u15),maomsch,(-10.n2),saldo
lijntel=lijntel+1
return  

&3000
if lijntel<22  : goto  &3010
ask=1,i=&10,u=&10:tab(01,24),paint(kh,ka),bla,paint(kt,0),ret,esc=j
print=1:tab(01,04),atb(22)
lijntel=4
&3010
totdeb=totdeb+mabedrd
totcred=totcred+mabedrc
print=1:tab(01,lijntel),paint(kt,ka),madatum," ",paint(kt,ka2),madbcr,paint(kt,ka3),(-10.n2),mabedrd,paint(kt,ka4),mabedrc,(e),paint(kt,ka5)," ",makllev," ",paint(kt,ka)," ",left(hnm,16),paint(kt,ka2)," ",matgfak,paint(kt,ka3)," ",maomsch,paint(kt,0)
print=1:tab(39,02),(-7.n2),totdeb
print=1:tab(49,02),(-7.n2),totcred,totdeb-totcred
lijntel=lijntel+1
return 

eseg 1

segment 2

goto &30
&1
ret.seg
&30
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  OPZOEKEN IN HISTORIEK OP BEDRAG "
print=1:paint(kl,0),tab(01,02),gener(79,hto),paint(kt,0)
print=1:tab(01,03),paint(kh,ka),"Datum",tab(10),"Kl-Lv",tab(22),"Fact",tab(30),"Omschrijving",tab(46),"K",tab(53),"Debet",tab(64),"Kredit",tab(74),"Reknr",paint(kt,0)
print=1:paint(kl,0),tab(01,04),gener(79,hto),paint(kt,0)
print=1:tab(01,21),paint(kh,ka),"Opzoeken bepaald bedrag",paint(kt,0)
&31
totdeb=0
ask=1,i=&1,u=&1:tab(01,23),"Geef selektiebedrag : "=totdeb
if totdeb=0 : goto  &31
&32
mareknr=" "
ask=1,i=&1,u=&31:tab(01,24),"Geef start rekening nummer : "=mareknr
print=1:tab(01,20),atb(22)
lijntel=5
madat=" "
matel=0
search=8,makod9:&35,e,mahisre
&35
down=8:&80,e,madown
op &36,e
goto &39
&36
if e=83 : goto  &30
if e=115 : goto  &30
&39
if abs(mabedrd)=totdeb : goto  &40
if abs(mabedrc)=totdeb : goto  &40
print=1:tab(01,24),madatum," ",mareknr," ",matel
goto &35
&40
print=1:tab(01,lijntel),madatum,tab(10),makllev,"/",maklv,tab(22),matgfak,tab(30),maomsch,tab(46),madbcr,tab(49),(-9.n2),mabedrd,mabedrc,(e),tab(74),mareknr
reknum=mareknr
lijntel=lijntel+1
if lijntel<23 : goto  &35
&41
print=1:tab(01,24),atb(21)
ask=1,i=&1,u=&1:tab(01,24),paint(kh,ka),bla,paint(kt,0),ret,esc=j
print=1:tab(01,04),atb(22)
lijntel=5
goto &35
&80
print=1:tab(01,24),atb(21)
ask=1,i=&1,u=&1,/80=&100:tab(01,24),paint(kh,ka),bere,paint(kt,0),ret,esc=j
goto &1
&100
lijntel=0
mareknr=" "
madat=" "
matel=0
search=8,makod9:&135,e,mahisre
&135
down=8:&150,e,madown
if abs(mabedrd)=totdeb : goto  &140
if abs(mabedrc)=totdeb : goto  &140
goto &135
&140
print=45:tabv(01),madatum,tab(10),makllev,"/",maklv,tab(22),matgfak,tab(30),maomsch,tab(46),madbcr,tab(49),(-9.n2),mabedrd,mabedrc,(e),tab(74),mareknr
lijntel=lijntel+1
if lijntel<printtel(07) : goto  &135
print=45:page
lijntel=0
goto &135
&150
print=45:page
close=45 
goto &80

eseg 2

segment 3

goto &2
&1
ret.seg
&2
for e=1 to 12
totdag(e)=0
next e
print=1:clear,reknum,"  ",paint(kh,ka),rekoms,paint(kt,0)," Debet : ",(-8.n2),rekdeb(02),(e),"  Kredit : ",(-8.n2),rekcred(02)
print=1:tab(70,01),(-9.n2),paint(kh,ka),rekdeb(02)-rekcred(02),paint(kt,0)
print=1:paint(kl,0),tab(01,02),gener(79,hto),paint(kt,0)
print=1:tab(01,03),paint(kh,ka),"Inlezen historiek",paint(kt,0)
mareknr=reknum
madat=" "
matel=0
search=8,makod9:&5,e,mahisre
&5
down=8:&50,e,madown
op &40,e
if mareknr<>reknum : goto  &50
print=1:tab(19,03),madatum," ",matel
&10
koper=conv(substr(madatum,4,2))
if koper<1 : goto  &5
if koper>12 : goto  &5
if madbcr="D" : goto  &20
if madbcr="C" : goto  &30
goto &5
&20
totdag(koper)=totdag(koper)+mabedrd
goto &5
&30
totdag(koper)=totdag(koper)-mabedrc
goto &5
&40
if e=83 : goto  &1
if e=115 : goto  &1 
goto &10
&50
print=1:tab(01,03),space(40)
klein=totdag(12)
for i=1 to 12
if klein<totdag(i) : goto  &105
klein=totdag(i)
&105
next i
&110
groot=totdag(1)
for i=1 to 12
if groot>totdag(i) : goto  &120
groot=totdag(i)
&120
next i
gemid=(groot-klein)/18
if gemid=0 : goto  &1
&125
print=1:paint(kl,0),tab(01,22),gener(80,hto),paint(kt,0)
print=1:tab(12,23),paint(kh,ka),"JAN FEB MAA APR MEI JUN JUL AUG SEP OKT NOV DEC",paint(kt,0)
for i=1 to 19
tabgroot(i)=0
next i
tabgroot(1)=klein
tabgroot(19)=groot
&150
for i=2 to 18
tabgroot(i)=tabgroot(i-1)+gemid
next i
&160
lijntel=21
for e=2 to 19
if tabgroot(e)>0 : goto  &170
lijntel=lijntel-1
next e
&170
print=1:tab(01,lijntel),"       0 ",vtb," ",gener(68,hto)
tel=lijntel
&200
lijntel=21
for i=1 to 19
if lijntel=tel : goto  &205
print=1:tab(01,lijntel),(-8),tabgroot(i),(u)," ",vtb
&205
lijntel=lijntel-1
next i
for i=1 to 12
if totdag(i)=0 : goto  &250
lijntel=21
for e=1 to 19     
if totdag(i)<0 : goto  &210
if tabgroot(e)<0 : goto  &240
if totdag(i)+gemid<tabgroot(e) : goto  &240
goto &230
&210
if tabgroot(e)>0 : goto  &240
if tabgroot(e)<totdag(i)-gemid : goto  &240
&230
if lijntel=tel : goto  &240
print=1:tab(12+(i-1)*4,lijntel),paint(kgra,0),gener(3,chr$(219)),paint(kt,0)
&240
lijntel=lijntel-1
next e
&250
next i
&252
ask=1,i=&1,u=&1:tab(01,24),ret,esc=j
goto &1

eseg 3

segment 4

goto &400 
&1
phil=0
goto &10
&2
phil=1
&10
ret.seg
&300
if e=83 : goto  &400
if e=115 : goto  &400
goto &415
&400
print=1:tab(01,23),paint(kh,ka),"Opzoeken op naam van de algemene rekening ",paint(kt,0)
selzoek=" "
vindrek=" "
&405
print=1:tab(01,24),atb(21)
ask=1,i=&1,u=&1:tab(01,24),"Geef trefwoord : "=selzoek
selzoek=large(selzoek)
if selzoek=" " : goto  &405
selzoek=large(selzoek)
open=9:&1,e
&410
down=9:&405,e,rekdown
op &300,e
op &300,e
&415
rekoms=large(rekoms)
selindex=0
selindex=index(rekoms,selzoek)
if selindex=0 : goto  &410
print=1:tab(01,23),atb(22)
print=1:tab(01,23),"Trefw. : ",selzoek," Rek. : ",reknum," ",rekoms
&420
j="Y"
ask=1,i=&1,u=&410:tab(01,24),"Deze rekening  Y-N : ",j,tab(22)=j
j=large(j)
if j="Y" : goto  &425
goto &410
&425
vindrek=reknum
rekkode=vindrek
&435
search=9,rekkode:&436,e,rekrec
goto &2
&436
print=1:tab(01,24),"Fout search rekkode : ",e," ",rekkode
stop

eseg 4

segment 200

test1=conv(right(dat,2))
test1=test1+1900
if test1>1950 : goto  &10
test1=test1+100
&10
test1=test1*372
test2=conv(substr(dat,4,2))
test2=test2*31
test1=test1+test2
test2=conv(left(dat,2))
test1=test1+test2
ret.seg

eseg 200

end


surtbed