program "VERKOPEN"

dcl btwkeus#,retkode#,test#
dcl invul%(300)
dcl sleunum%,suptel%,selindex%,ee%,beg%,ende%,volgorde%,selma%,lees%,bl%
dcl antal=6(10),dr=6(2),druk=6(2)
dcl totklan=6,saldo=6,totaal2=6,vers=6,btwsoort=6,testbtw=6
dcl som=6,subtot1=6,subtot=6,totool=6,totbow=6,overz=6
dcl omzet=6,totaal=6,restant=6,totbtw=6,totmin=6,totberb=6
dcl totsbtw=6,berbtw=6,bedrag=6,vdat1=6,vdat2=6,vdat3=6,vdat4=6
dcl tabkod$=8(30),toetsen$=13(8),tabverk$=8(25),tabopf$=15(25),tabhis$=16(25)
dcl sleutl$=8(30),dat1$=8,dat2$=8,opm$=10,leessec$=1,pass$=1
dcl fakmnd$=2,fakdag$=2,fakjaar$=2,helpdat1$=8,helpdat2$=8
dcl boekdag$=8,valdag$=8,selzoek$=10,vindrek$=6,loop_$=1,selboek$=1

dcl delhis$=16
field=m,delhis
dcl delnaam$=8,deldat$=6,deltel%
field=m

dcl srtfdown$=26
field=m,srtfdown
dcl srtfkode$=25
field=m,srtfkode
dcl srtfsrt$=1,srtftype$=1,srtffak$=6,srtfrec$=15,srtfnul$=2,filler=1
field=m

dcl srtbdown$=26
field=m,srtbdown
dcl srtbkode$=25
field=m,srtbkode
dcl srtbsrt$=1,srtbtype$=1,srtbbed$=8,srtbrec$=15,filler=1
field=m

dcl omz$=6
field=m,omz
dcl omzkod$=1,filler=5
field=m

dcl dat3$=8
field=m,dat3
dcl ondat$=1(8)
field=m

#INCLUDE  "CRINCLU"
#INCLUDE  "CRINCLU2"

for i=1 to 8
toetsen(i)=" "
next i

assign=2,bestand(4),wr,si    ;klanten
assign=3,bestand(8),wr,si    ;verkoopdagboek
assign=4,bestand(2),wr,si    ;maandhistoriek
assign=5,bestand(1),wr,si    ;rekeningenbestand
assign=6,bestand(10),wr,si   ;openstaande faktuen
assign=7,bestand(11),wr,si   ;klantenhistoriek
assign=8,left(bestand(9),6)+"B",wr,si     ;bedragensort+fakturensort

open=2:&1,e
open=3:&1,e
open=4:&1,e
open=5:&1,e
open=6:&1,e
open=7:&1,e

&6
for i=1 to 8
if vastrek(i+27)=" " : goto  &9
search=5,vastrek(i+27):&7,e,rekrec
toetsen(i)=left(rekoms,13)
goto &8
&7
toetsen(i)="Niet gevonden"
&8
next i

&9
helpdat2=ndat
boekdag=ndat
valdag=ndat
vd=conv(teller(20))
if kodes(3)<>"Y" : goto  &10
gosub &800

&10
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  REGISTRATIE VERKOOPFAKTUREN  ",tab(70),ndat
print=1:paint(kl,0),tab(01,02),ltb,gener(77,hto),rtb
print=1:tab(01,03),vtb,tab(79),vte
print=1:tab(01,04),lto,gener(77,hto),rto,paint(kt,0)
print=1:paint(kh,ka),tab(03,03),"F1=Overz klanten  F2=Overz. dagboek  F3=Klanten  F4=Rekeningen",paint(kt,0)
goto &20

&11
assign=1,"CRBKLA"
chain=1
stop

&13
assign=1,"CRBREK"
chain=1
stop

&15
ldgo.seg 3
goto &10

&20
gosub &6000            ;init verkoopdagboek
gosub &6500            ;init faktuur
gosub &6600            ;init klantenhistoriek
gosub &6700            ;init rekeningenhistoriek
fakdat=boekdag
fakverv=valdag
phil=0
print=1:tab(01,05),atb(22)
print=1:tab(01,05),"Geef klantenkode",esc,klkode
print=1:tab(50,05),"Factuur : ",(-5),teller(14)
&24
ask=1,i=&1,u=&1,/8a=&33,/8b=&35,/80=&9000,/81=&9200,/82=&11,/83=&13,/85=&15:tab(32,05)=klkode
klkode=large(klkode)
if klkode=" " : goto  &24
search=2,klkode:&25,e,klrec
goto &40
&25
ask=1,i=&20,u=&20,/8a=&33,/8b=&35:tab(01,24),paint(kh,ka),"Klant",ng,paint(kt,0),fvoor,voor,fvolg,volg=j
goto &20
&33
up=2:&34,e,kldown
goto &40
&34
print=1:tab(01,24),atb(21)
ask=1,i=&20,u=&20,/8a=&33,/8b=&35:tab(01,24),paint(kh,ka),berb,paint(kt,0),fvolg,volg=j
goto &10
&35
down=2:&37,e,kldown
goto &40
&37
print=1:tab(01,24),atb(21)
ask=1,i=&20,u=&20,/8a=&33:tab(01,24),paint(kh,ka),bere,paint(kt,0),fvoor,voor=j
goto &10
&40
print=1:tab(01,05),atb(22)
print=1:tab(01,05),"Klantenkode : ",klkode
print=1:tab(50,06),"Btwnummer : ",kllbtw,klbtwnr
print=1:tab(01,07),"Naam klant : ",paint(kh,ka),left(klnaam,len$(klnaam)),paint(kt,0),tab(50),"Jaaromzet : ",(-7.n2),kljomz
print=1:tab(01,08),"Adres      : ",klstra,tab(50),"Tegoeden  : ",(-7.n2),kltego
print=1:tab(01,09),"Gemeente   : ",klgem,tab(50), "Voorschot : ",(-7.n2),klover
print=1:paint(kl,0),tab(01,11),gener(79,hto),paint(kt,0)
klland=large(klland)
if klland<>"X" : goto  &41
print=1:tab(01,24),bell,paint(kt,ka),"Opgelet boekingen op deze klant zijn niet toegelaten",paint(kt,0)
ask=1:=j
&41
verkfok="999999"
search=3,verkkey:&42,e,verkrec
&42
up=3:&43,e,verkdown
goto &44
&43
verkfok="0     "
&44
teller(02)=conv(verkfok)+1
teller(14)=teller(02)
par(3)=param3

gosub &6000            ;init verkoopdagboek

print=1:tab(50,05),"Factuur : ",(-5),teller(14)
print=1:tab(01,12),"Factuurnummer",tab(20),": ",(-6),teller(14)
print=1:tab(01,13),"Omschrijving",tab(20),": ",fakoms,"."
print=1:tab(01,14),"Factuurdatum",tab(20),": ",fakdat,"."
print=1:tab(01,15),"Vervaldatum",tab(20),": ",fakverv,"."
if kodes(05)<>"Y" : goto  &46
print=1:tab(01,16),"Dagboeknummer",tab(20),": "
&46
print=1:tab(01,18),"Totaal fakt.",tab(20),": "
&50
phil=1
print=1:tab(01,22),paint(kh,ka),"F2=historiek",paint(kt,0),"  ",paint(kh,ka),"F3=openstaande fakturen deze klant",paint(kt,0)
ask=1,i=&20,u=&20,/8a=&33,/8b=&35,/81=&4000,/82=&3000:tab(22,12),(-6)=teller(14)
overz=conv(teller(14))
faknum=strn(overz)
faknum=shr(faknum)
&52
ask=1,i=&20,u=&50,/81=&4020,/82=&3020,/8a=&33,/8b=&35:tab(22,13)=fakoms
&53
print=1:tab(01,22),atb(22)
fakoms=large(fakoms)
print=1:tab(40,13),fakoms
inldat1=fakdat
retkode=1
ask=1,i=&20,u=&52,/8a=&33,/8b=&35:tab(22,14)=inldat1
if len$(inldat1)<>6 : goto  &54
inldat1=left(inldat1,2)+"."+substr(inldat1,3,2)+"."+substr(inldat1,5,2)
&54
fakdat=left(inldat1,len$(inldat1))+right(fakdat,8-len$(inldat1))
if substr(fakdat,3,1)<>"." : goto  &58
if substr(fakdat,6,1)<>"." : goto  &58
dat3=fakdat
&55
if ondat(1)<"0" : goto  &58
if ondat(1)>"3" : goto  &58
if ondat(2)<"0" : goto  &58
if ondat(2)>"9" : goto  &58
if ondat(4)<"0" : goto  &58
if ondat(4)>"1" : goto  &58
if ondat(5)<"0" : goto  &58
if ondat(5)>"9" : goto  &58
if ondat(7)<"0" : goto  &58
if ondat(7)>"9" : goto  &58
if ondat(8)<"0" : goto  &58
if ondat(8)>"9" : goto  &58
if retkode=1 : goto  &57
if retkode=2 : goto  &66
goto &53
&56
ask=1,i=&20,u=&53:bell,tab(01,24),"Datum niet korrekt : ",paint(kt,0)," DD.MM.JJ : "=j
print=1:tab(01,24),atb(21)
if retkode=1 : goto  &53
&57
retkode=2
print=1:tab(22,14),fakdat
fakdag=left(fakdat,2)
fakmnd=substr(fakdat,4,2)
fakjaar=substr(fakdat,7,2)
vdat1=conv(fakdag)
vdat3=conv(fakmnd)
vdat4=conv(fakjaar)
vdat2=conv(vd)
vdat1=vdat1+vdat2
fakdag=conv(vdat1)
if vdat1>30 : gosub  &60
if vdat1>30 : gosub  &60
if vdat1>30 : gosub  &60
if vdat1>30 : gosub  &60
if vdat1>30 : gosub  &60
if vdat1>30 : gosub  &60
fakverv=fakdag+"."+fakmnd+"."+fakjaar
inldat2=fakverv
&58
ask=1,i=&20,u=&53,/8a=&33,/8b=&35:tab(22,15),inldat2,tab(22)=inldat2
if len$(inldat2)<>6 : goto  &59
inldat2=left(inldat2,2)+"."+substr(inldat2,3,2)+"."+substr(inldat2,5,2)
&59
fakverv=left(inldat2,len$(inldat2))+right(fakverv,8-len$(inldat2))
dat3=fakverv
print=1:tab(22,15),fakverv
goto &55
&60
vdat3=vdat3+1
if vdat3>12 : gosub  &61
vdat1=vdat1-30
fakmnd=conv(vdat3)
fakdag=conv(vdat1)
fakverv=fakdag+"."+fakmnd+"."+right(fakdat,2)
return
&61
vdat3=1
vdat4=conv(fakjaar)
vdat4=vdat4+1
if vdat4<>100 : goto  &62
vdat4=vdat4-100
&62
fakjaar=conv(vdat4)
return
&66
if kodes(05)<>"Y" : goto  &67
ask=1,i=&20,u=&58,/8a=&33,/8b=&35:tab(22,16)=verkboek
verkboek=large(verkboek)
&67
print=1:tab(01,20),atb(22)
ask=1,i=&20,u=&58,/80=&68,/8a=&33,/8b=&35:tab(22,18)=faktebe
if faktebe=0 : goto  &67
&68
if faktebe>0 : goto  &70
ask=1,i=&20,u=&67,/8a=&33,/8b=&35:tab(01,20),"Bedrag negatief : ",paint(kh,ka),"F",paint(kt,0),"=factuur  ",paint(kh,ka),"K",paint(kt,0),"=credietnota : "=aankcnf
verkcnf=large(aankcnf)
if verkcnf="F" : goto  &70
if verkcnf="K" : goto  &70
goto &68
&70
j=" "
print=1:tab(01,24),paint(kh,ka),"F1=Fichen + Openstaande fakturen.",paint(kt,0)
ask=1,i=&20,u=&67,/80=&75,/8a=&33,/8b=&35:tab(01,23),vali=j
j=large(j)
if j="N" : goto  &20
if j<>"Y" : goto  &70
goto &80

&75
ldgo.seg 4
goto &10

&80
subtot=0
print=1:clear
klland=large(klland)
if klland="B" : goto  &82
if klland=" " : goto  &82
print=1:bell,tab(01,23),paint(kh,ka),"Klant onderworpen aan export ",paint(kt,0)
&82
print=1:tab(01,01),paint(kh,ka),naam,paint(kt,0),"  Klant : ",klnaam,tab(60),ltb,gener(18,hto),rtb
print=1:tab(01,02),gener(59,hto),mtr,tab(79),vte
print=1:tab(62,02),"Bedr :",tab(69),(-7.n2),faktebe
print=1:tab(60,03),vte,tab(62),"Rest : ",tab(79),vte
print=1:tab(01,03),"Factuurnummer : ",faknum
print=1:tab(60,04),lto,gener(18,hto),rto
totaal=0
restant=0
totbtw=0
totmin=0
totberb=0
i2=1       ;teller btw invul verkoop
i3=1       ;teller tegenboekingen invullen
totsbtw=0
restant=faktebe
for i=1 to 10
antal(i)=0
verkteg(i)=" "
verktbe(i)=0             ;tegenboekingsbedragen
next i
gosub &7000
for i=1 to 5
verkkod(i)=" "           ;kode btw
verkbed(i)=0             ;basis btw
next i
&85
i1=7
btwkeus=0
print=1:tab(01,05),paint(kn,ka2),"BTW : "
for i=1 to 5
if verkod(i)=0 : goto  &90   ;einde btws
print=1:tab(i1,5),(-),verkod(i),(u),"=",(-z.n),verper(i),(e),"%"
i1=i1+9
next i
&90
print=1:tab(i1,05),"6=mede  7=uitv  9=stop :",paint(kt,0)
print=1:tab(01,24),atb(21)
ask=1,i=&10,u=&10:tab(76,5),(-)=btwkeus
if btwkeus=0 : goto  &90
for i=1 to 5
if verkkod(i)<>conv(btwkeus) : goto  &91
ask=1,i=&90,u=&90:tab(01,24),paint(kh,ka),"Reeds ingevuld op deze btw kode ",paint(kt,0)," "=j
goto &90
&91
next i
if btwkeus=6 : goto  &98   ;mede
if btwkeus=7 : goto  &99   ;uitv
if btwkeus=9 : goto  &102
for i=1 to 5
i4=i
if verkod(i)=btwkeus : goto  &93
next i
ask=1,i=&90,u=&90:tab(01,24),paint(kh,ka),"Deze btw-keuze bestaat niet : ",paint(kt,0)," "=j
goto &90
&93
verkkod(i2)=conv(btwkeus)
print=1:tab(01,06),atb(21)
ask=1,u=&90,i=&80:tab(01,06),"Geef basis bedrag : "=verkbed(i2)
if verkbed(i2)=0 : goto  &93
berbtw=verkbed(i2)*conv(verper(i4))/100
&96
berbtw=roun(berbtw,2)
print=1:tab(01,07),"Berekende btw op deze basis : ",(-7.n2),berbtw
totbtw=totbtw+berbtw
print=1:tab(01,08),"Totale btw op deze faktuur  : ",(-7.n2),totbtw
print=1:tab(01,05),atb(21)
restant=faktebe-totbtw
gosub &7000    ;affichering saldo
restant=faktebe
i2=i2+1
if i2>5 : goto  &97
goto &85
&97
ask=1,i=&80,u=&80:tab(01,24),paint(kh,ka),"Maximaal 5 btw keuzes : ",paint(kt,0)=j
goto &80
&98    ;opvragen gegevens medekontraktant
print=1:tab(01,06),atb(21)
verkkod(i2)=conv(btwkeus)
ask=1,i=&80,u=&90:tab(01,06),"Keuze ",paint(kh,ka),"medekontraktant",paint(kt,0)," geef bedrag : "=verkbed(i2)
if verkbed(i2)=0 : goto  &98
berbtw=0
goto &96
&99    ;opvragen gegevens uitvoer
print=1:tab(01,06),atb(21)
verkkod(i2)=conv(btwkeus)
ask=1,i=&80,u=&90:tab(01,06),"Keuze ",paint(kh,ka),"Uitvoer",paint(kt,0)," geef bedrag : "=verkbed(i2)
if verkbed(i2)=0 : goto  &99
berbtw=0
goto &96
&102
restant=restant-totbtw
if restant<>0 : goto  &103
print=1:tab(01,23),atb(21)
ask=1,i=&120,u=&120:bell,tab(01,23),paint(kh,ka),"Alles is btw ",paint(kt,0)," "=j
goto &120
&103
gosub &7000    ;afdrukken restant bedrag
i3=1          ;loper tegenboekingen
i4=10         ;loper lijn op het scherm
i2=1
print=1:tab(01,21),atb(22)
print=1:tab(60,23),"N = sel naam "
for i5=1 to 3
if vastrek(i5+27)=" " : goto  &105
print=1:tab(i2,20),paint(kh,ka),"F",(-),I5,paint(kt,0),(u1),"=",(u6),vastrek(i5+27),(u),"=",(u13),toetsen(i5)
i2=i2+19
next i5
i2=1
for i5=4 to 6
if vastrek(i5+27)=" " : goto  &105
print=1:tab(i2,21),paint(kh,ka),"F",(-),i5,paint(kt,0),(u1),"=",(u6),vastrek(i5+27),(u),"=",(u13),toetsen(i5)
i2=i2+19
next i5
&105
print=1:tab(01,22),paint(kh,ka),"F1=Overname saldo bij rekeningnummer    ",paint(kt,0)
print=1:tab(01,23),paint(kh,ka),"B",paint(kt,0),"=veranderen btwbedrag                  ",paint(kt,0)
ask=1,i=&10,u=&80,/80=&400,/81=&401,/82=&402,/83=&403,/84=&404,/85=&405,/86=&406,/87=&407,/8a=&107,/8b=&109,"B"=&300,"b"=&300,"n"=&450,"N"=&450,"V"=&400,"v"=&400:tab(01,i4),"Reknr : "=rekkode
if rekkode=" " : goto  &105
search=5,rekkode:&106,e,rekrec
goto &111
&106
print=1:tab(01,24),atb(21)
ask=1,i=&105,u=&105,/8a=&107,/8b=&109:tab(01,24),paint(kh,ka),"Rekening",ng,paint(kt,0),fvoor,voor,fvolg,volg=j
print=1:tab(01,24),atb(21)
goto &105
&107  
up=5:&108,e,rekdown
goto &111
&108
print=1:tab(01,24),atb(21)
ask=1,i=&105,u=&105,/8b=&109:tab(01,24),paint(kh,ka),berb,paint(kt,0),fvolg,volg=j
goto &105
&109   
down=5:&110,e,rekdown
goto &111
&110
print=1:tab(01,24),atb(21)
ask=1,i=&105,u=&105,/8a=&107:tab(01,24),paint(kh,ka),bere,paint(kt,0),fvoor,voor=j
goto &105
&111
print=1:tab(01,24),atb(21)
print=1:tab(09,i4),rekkode,tab(18),rekoms
&112
bedrag=0
ask=1,i=&80,u=&105,/80=&114,/8a=&107,/8b=&109:tab(44,i4),"Bedrag : ",(-6z.n2)=bedrag
print=1:tab(01,23),atb(22)
if bedrag=0 : goto  &112
if kodes(3)<>"Y" : goto  &113
if rekbtw<>"A" : goto  &113
print=1:bell,tab(01,24),bell,"Dit is een aantallen rekening "
print=1:tab(01,24),atb(21)
ask=1,i=&112,u=&112:tab(60,i4),": ",(-5z.n2)=antal(i3)
&113
restant=restant-bedrag
gosub &7000
verkteg(i3)=rekkode
verktbe(i3)=bedrag
print=1:tab(53,i4),(-7.n2),bedrag
i3=i3+1
i4=i4+1
if restant=0 : goto  &115
if i3<=10 : goto  &105
ask=1,i=&80,u=&80:tab(01,24),paint(kh,ka),"Meer dan 10 rekeningen zijn niet toegelaten : ",paint(kt,0)," "=j
goto &80
&114
bedrag=restant
goto &113
&115 
gosub &7000
subtot=0
for e=1 to 5
subtot=subtot+verkbed(e)
next e
subtot=subtot
subtot1=0
for e=1 to 10
subtot1=subtot1+verktbe(e)
next e
if subtot=subtot1 : goto  &120
print=1:tab(60,23),atb(21)
print=1:tab(60,23),"Saldo : ",(-7.n2),subtot-subtot1
ask=1,i=&80,u=&80,/80=&120:bell,tab(01,24),paint(kh,ka),"Bedrag btw uitsplitsingen niet gelijk aan goederen ",paint(kt,0)," "=j
goto &80 
&120
j=" "
print=1:tab(01,22),atb(22)
ask=1,i=&80,u=&80:tab(01,23),vali=j
j=large(j)
if j="N" : goto  &10
if j<>"Y" : goto  &120

&125
hisnaam=klkode
histdat=right(fakdat,2)+substr(fakdat,4,2)+left(fakdat,2)
histel=0
hisdat=fakdat                 ;invullen klantenhistoriek gegevens
hisoms=fakoms
hiskod1="V"                   ;kode verkoop
hiskod2=" "                   ;kode 2 geen intrest , korting e.d.
hisbed1=faktebe               ;totaal te betalen
hiskllv=klkode                ;klantenkode
hisbed2=0                     ;geen tweede kode ingevuld dus geen tweede bedrag
hisfakt=shr(faknum)           ;invullen faktuurnummer
hisbetw=" "
hisbtw=totbtw                 ;totaal bedrag btw
&128
insert=7,hiskode:&130,e,kllvhis
goto &131
&130
histel=histel+1
teller(07)=teller(07)+1       ;aanpassen historieken teller
goto &128
&131
teller(07)=teller(07)+1       ;aanpassen historieken teller
fakkllv="K"
fakname=klkode
fakfak=shr(faknum)
fakklv="K"                    ;kodering klant
faknaam=klkode                ;kode klant
fakont=0                      ;reeds ontvangen bedragen
insert=6,fakkode:&133,e,fakrec
goto &135
&133
modif=6,fakkode:&134,e,fakrec
goto &135
&134
print=1:tab(01,24),"Fout modif fakkode : ",e," ",fakkode
stop

&135
srtfsrt="F"
srtbsrt="B"
srtftype=fakklv
srtbtype=fakklv
srtffak=shr(faknum)
srtfrec=fakkode
srtfnul=" "
srtbrec=fakkode
som=faktebe-fakont
som=roun(som,2)
srtbbed=conv(som)
insert=8,srtbkode:&136,e
insert=8,srtfkode:&136,e
&136
teller(05)=teller(05)+1
omzet=0
for i4=1 to 10
omz=verkteg(i4)
if omzkod<>"7" : goto  &137
omzet=omzet+verktbe(i4)
&137
next i4         ;verrekenen totale omzet : exclusief btw en verpakkingen

kljomz=kljomz+omzet           ;verhogen jaaromzet
kltego=kltego+faktebe         ;verhogen te ontvangen van deze klant
if verkcnf="K" : goto  &140       ;kredietnota
kltbtw=kltbtw+totbtw
goto &145
&140
klcred=klcred+totbtw
&145
modif=2,klkode:&146,e,klrec
goto &150
&146
print=1:tab(01,24),"Fout modif klkode : ",e,klkode
stop

&150
verkfok=conv(teller(14))
verktel=0
verkdat=fakdat
verkkla=klkode
verkfak=faknum
verkoms=fakoms
verkbtw=totbtw
verkdeb=faktebe
insert=3,verkkey:&155,e,verkrec
goto &160
&155
teller(14)=teller(14)+1
verkfok=conv(teller(14))
overz=conv(teller(14))
faknum=shr(strn(overz))
goto &150
&160
teller(14)=teller(14)+1       ;aanpassen fakturen inschrijvings teller
teller(02)=teller(14)
rekkode=vastrek(01)
search=5,rekkode:&161,e,rekrec
goto &162
&161
print=1:tab(01,24),"Fout search rekkode : ",e," ",rekkode
stop
&162
if verkcnf="K" : goto  &164
rekdeb(1)=rekdeb(1)+faktebe
rekdeb(2)=rekdeb(2)+faktebe
madbcr="D"
mabedrd=faktebe
goto &170
&164
rekcred(1)=rekcred(1)+abs(faktebe)
rekcred(2)=rekcred(2)+abs(faktebe)
madbcr="C"
mabedrc=abs(faktebe)
&170
modif=5,rekkode:&171,e,rekrec
goto &172
&171
print=1:tab(01,24),"Fout modif rekkode : ",e," ",rekkode
stop
&172
madatum=verkdat
madat=right(madatum,2)+substr(madatum,4,2)+left(madatum,2)
makode="2"     ;kode verkoop
makllev="K"    ;kode klant
maklv=klkode   ;sleutel klant
matgfak=shr(faknum)  ;faktuurnummer
maomsch=fakoms ;omschrijving faktuur
mareknr=rekkode ;klaarzetten voor insert te doen
gosub &500

&175
if verkcnf="K" : goto  &185
rekkode=vastrek(03)
search=5,rekkode:&415,e,rekrec
rekcred(1)=rekcred(1)+totbtw
rekcred(2)=rekcred(2)+totbtw
madbcr="C"
mabedrc=totbtw
modif=5,rekkode:&415,e,rekrec
gosub &500
goto &190

&185
rekkode=vastrek(05)
search=5,rekkode:&415,e,rekrec
rekdeb(1)=rekdeb(1)+abs(totbtw)
rekdeb(2)=rekdeb(2)+abs(totbtw)
madbcr="D"
mabedrd=abs(totbtw)
modif=5,rekkode:&415,e,rekrec
gosub &500
goto &190

&190
for i2=1 to 10
if verkteg(i2)=" " : goto  &200
rekkode=verkteg(i2)
search=5,rekkode:&191,e,rekrec
gosub &850
goto &192
&191
print=1:tab(01,24),"Fout search rekkode : ",e," ",rekkode
stop
&192
if verktbe(i2)<0 : goto  &194
rekcred(1)=rekcred(1)+verktbe(i2)
rekcred(2)=rekcred(2)+verktbe(i2)
madbcr="C"
mabedrc=verktbe(i2)
goto &198
&194
rekdeb(01)=rekdeb(01)+abs(verktbe(i2))
rekdeb(02)=rekdeb(02)+abs(verktbe(i2))
madbcr="D"
mabedrd=abs(verktbe(i2))
&198
modif=5,rekkode:&191,e,rekrec
gosub &500
next i2

&200
par(3)=param3
par(4)=param4
goto &10

&300
if i3<>1 : goto  &105
print=1:tab(01,24),atb(21)
print=1:tab(01,24),"Opgave van btw bedrag : "
&305
ask=1,i=&105,u=&105:tab(25,24),(-4z.n2),totbtw,tab(25)=totbtw
if totbtw=0 : goto  &305
restant=faktebe-totbtw
gosub &7000
goto &105

&400
rekkode=vastrek(28)
goto &410
&401
rekkode=vastrek(29)
goto &410
&402
rekkode=vastrek(30)
goto &410
&403
rekkode=vastrek(31)
goto &410
&404
rekkode=vastrek(32)
goto &410
&405
rekkode=vastrek(33)
goto &410
&406
rekkode=vastrek(34)
goto &410
&407
rekkode=vastrek(35)
goto &410
&410
search=5,rekkode:&106,e,rekrec
goto &111
&415
print=1:tab(01,24),"Fout search rekkode : ",e," ",vastrek(04)
stop

&450
print=1:tab(01,23),atb(22)
print=1:tab(01,23),paint(kh,ka),"Opzoeken op naam van de algemene rekening  ",paint(kt,0)
selzoek=" "
vindrek=" "
&455
print=1:tab(01,24),atb(21)
ask=1,i=&480,u=&480:tab(01,24),"Geef trefwoord : "=selzoek
selzoek=large(selzoek)
if selzoek=" " : goto  &455
selzoek=large(selzoek)
open=5
&460
down=5:&480,e,rekdown
rekoms=large(rekoms)
selindex=0
selindex=index(rekoms,selzoek)
if selindex=0 : goto  &460
print=1:tab(01,24),atb(21)
print=1:tab(01,24),"Trefw. : ",selzoek," Rek. : ",rekkode," ",rekoms
&465
j=" "
ask=1,i=&480,u=&480:tab(60,24),"Deze rek. Y-N : "=j
j=large(j)
if j="N" : goto  &460
if j<>"Y" : goto  &465
&470
vindrek=rekkode
rekkode=vindrek
goto &485
&480
print=1:tab(01,23),atb(22)
goto &106
&485
search=5,rekkode:&106,e,rekrec
goto &111

&500    ;wegschrijven historiek
rekhok=large(rekhok)
if rekhok="N" : goto  &510
mareknr=rekkode
&501
matel=teller(01)
makode2=makod9
insert=4,makod9:&503,e,mahisre
goto &505
&503
teller(01)=teller(01)+1
goto &501
&505
teller(01)=teller(01)+1
&510
madbcr=" "
mabedrd=0
mabedrc=0    ;credit bedrag op nul
return

&800
assign=14,left(bestand(01),6)+"A",wr,si
open=14:&801,e
goto &802
&801
cfile=14,d=50,lk=6
&802
return

&850
if kodes(3)<>"Y" : goto  &860
if rekbtw<>"A" : goto  &860
search=14,rekkode:&851,e,rekarec
goto &853
&851
for e=1 to 3
rekaan1(e)=0
rekaan2(e)=0
next e
insert=14,rekkode:&852,e,rekarec
goto &853
&852
print=1:tab(01,24),"Fout insert rekkode : ",e," ",rekkode
stop
&853
rekaan1(1)=rekaan1(1)+antal(i2)
rekaan1(2)=rekaan1(2)+antal(i2)
modif=14,rekkode:&854,e,rekarec
goto &860
&854
print=1:tab(01,24),"Fout modif rekkode : ",e," ",rekkode
stop
&860
return

&3000  
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  OPENSTAANDE FAKTUREN  ",tab(70),ndat
print=1:paint(kl,0),tab(01,02),gener(79,hto),paint(kt,0)
&3001
print=1:tab(01,05),atb(22)
&3002
ask=1,i=&10,u=&10,/81=&4000,/8a=&3005,/8b=&3007:tab(01,05),"Geef klantenkode",esc,klkode,tab(32)=klkode
if klkode=" " : goto  &3002
klkode=large(klkode)
search=2,klkode:&3003,e,klrec
goto &3020
&3003
print=1:tab(01,24),atb(21)
ask=1,i=&3001,u=&3001,/8a=&3005,/8b=&3007:tab(01,24),paint(kh,ka),"Klant",ng,paint(kt,0),fvoor,voor,fvolg,volg=j
goto &3001
&3005
up=2:&3006,e,kldown
goto &3020
&3006
print=1:tab(01,24),atb(21)
ask=1,i=&3000,u=&3000,/8b=&3007:tab(01,24),paint(kh,ka),berb,paint(kt,0),fvolg,volg=j
goto &3000
&3007
down=2:&3008,e,kldown
goto &3020
&3008
print=1:tab(01,24),atb(21)
ask=1,i=&3000,u=&3000,/8a=&3005:tab(01,24),paint(kh,ka),bere,paint(kt,0),fvoor,voor=j
goto &3000
&3020
l6=6
gosub &5000
gosub &5500    ;sublijn
for e=1 to 17
tabopf(e)=" "
next e
fakkllv="K"
fakname=klkode
fakfak=" "
totaal=0
search=6,fakkode:&3030,e,fakrec
&3030
down=6:&3035,e,fakdown
if fakname<>klkode : goto  &3035
print=1:tab(01,l6),paint(kn,ka)," ",(n2),l6-5,(e)," ",paint(kt,ka2)," ",fakdat,"  ",paint(kn,ka3),shr(faknum),"   ",paint(kn,ka4)," ",fakverv,"   ",paint(kn,ka5),(-5.n2),faktebe,(e)," ",paint(kn,ka),(-5.n2),fakont,(e),"   ",paint(kn,ka2),(-5.n2),faktebe-fakont,(e),"   ",tab(64),paint(kt,ka3)," ",(u13),fakoms
totaal=totaal+faktebe-fakont
tabopf(l6-5)=fakkode
l6=l6+1
if l6>22 : goto  &3100  ;blad volzet
goto &3030
&3035
kltego=totaal
modif=2,klkode:&3040,e,klrec
&3040
print=1:tab(01,23),atb(22)
print=1:tab(01,23),"Totaal te betalen : ",(-7.n2),kltego
print=1:tab(46,23),"Voorschotten : ",(-7.n2),klover
print=1:tab(01,24),paint(kh,ka),"S a l d o         : ",paint(kt,0),(-7.n2),kltego-klover
j=" " 
ask=1,i=&3000,u=&3000,/80=&4900,/8a=&3005,/8b=&3007,"bB"=&4900:tab(32,24),fvoor,voor,fvolg,volg=j
goto &3000
&3100   
j=" " 
print=1:tab(01,24),atb(21)
ask=1,i=&3000,u=&3000,/80=&4900,/8a=&3005,/8b=&3007,"bB"=&4900:tab(01,24),paint(kh,ka),bla,paint(kt,0),ret=j
&3105
for e=1 to 24
tabopf(e)=" "
next e
gosub &5000
gosub &5500
l6=6
goto &3030

&4000    ;routine historiek
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  KLANTENFICHE - HISTORIEK ",tab(70),ndat
print=1:paint(kl,0),tab(01,02),gener(79,hto),paint(kt,0)
&4001
print=1:tab(01,05),atb(22)
&4002
ask=1,i=&10,u=&10,/82=&3000,/8a=&4005,/8b=&4007:tab(01,05),"Geef klantenkode",esc,klkode,tab(32)=klkode
if klkode=" " : goto  &4002
klkode=large(klkode)
search=2,klkode:&4003,e,klrec
goto &4020
&4003
print=1:tab(01,24),atb(21)
ask=1,i=&4001,u=&4001,/8a=&4005,/8b=&4007:tab(01,24),paint(kh,ka),"Klant",ng,paint(kt,0),fvoor,voor,fvolg,volg=j
goto &4001
&4005
up=2:&4006,e,kldown
goto &4020
&4006
print=1:tab(01,24),atb(21)
ask=1,i=&4001,u=&4001,/8b=&4007:tab(01,24),paint(kh,ka),berb,paint(kt,0),fvolg,volg=j
goto &4001
&4007
down=2:&4008,e,kldown
goto &4020
&4008
print=1:tab(01,24),atb(21)
ask=1,i=&4001,u=&4001,/8a=&4005:tab(01,24),paint(kh,ka),bere,paint(kt,0),fvoor,voor=j
goto &4000
&4020     
histdat=" "
gosub &5000
gosub &5600
loop_="O"
ask=1,i=&4000,u=&4000,/8a=&4005,/8b=&4007:tab(01,24),"Geef loopsekwentie ",paint(kh,ka),"N",paint(kt,0),"=normaal  ",paint(kh,ka),"O",paint(kt,0),"=omgekeerd : ",loop_," : "=loop_
loop_=large(loop_)
if loop_="N" : goto  &4022
if loop_="O" : goto  &4021
goto &4020
&4021
histdat="ZZZZZZ"
&4022
for e=1 to 24
tabhis(e)=" "
next e
l6=6
&4025
hisnaam=klkode
search=7,hiskode:&4030,e,kllvhis
&4030
for i=1 to 2
dr(i)=0
next i
opm=" "
if loop_="O" : goto  &4035
down=7:&4300,e,hisdown
goto &4040
&4035
up=7:&4300,e,hisdown
&4040
if hisnaam<>klkode : goto  &4300
if hiskod1="V" : goto  &4070
if hiskod1="L" : goto  &4070
if hiskod1="F" : goto  &4073
goto &4079
&4070
dr(1)=hisbed1
opm="Btw"
hisbed2=hisbtw
if hisbtw<>0 : goto  &4079
opm=" "
goto &4079
&4073
dr(2)=hisbed1
&4079
if hiskod2=" " : goto  &4090
if hiskod2="T" : goto  &4081
if hiskod2="K" : goto  &4082
if hiskod2="I" : goto  &4083
if hiskod2="V" : goto  &4084
if hiskod2="X" : goto  &4085
goto &4090
&4081
opm="Teveel    "
goto &4090
&4082
opm="Korting   "
goto &4090
&4083
opm="Intrest   " 
goto &4090
&4084
opm="Voorschot "
goto &4090
&4085
opm="Bet.verschil"
&4090
print=1:tab(01,l6),paint(kn,ka)," ",(n2),l6-5,(e)," ",paint(kt,ka2)," ",hisdat,"   ",paint(kn,ka3),shr(hisfakt),"   ",paint(kn,ka4),(-5.n2),dr(1),(e),"   ",paint(kn,ka5),(-5.n2),dr(2)
print=1:(e),"   ",paint(kn,ka)," ",hisbetw,"  ",paint(kn,ka2),(-5.n2),hisbed2,(e),"   ",paint(kt,ka3),hiskod2,"   ",paint(kn,ka4),(-5.n2),dr(1)-hisbed2,(e),"   ",paint(kt,0)
tabhis(l6-5)=hiskode
l6=l6+1
if l6>22 : goto  &4200    
goto &4030
&4200
j=" " 
print=1:tab(01,23),atb(22)
print=1:tab(60,23),paint(kh,ka),"Saldo : ",paint(kt,0),(-6.n2),kltego
ask=1,i=&4000,u=&4000,/80=&4800,/8a=&4005,/8b=&4007,"tT"=&4400,"bB"=&4800:tab(01,24),paint(kh,ka),bla,paint(kt,0),ret,paint(kh,ka),"T",paint(kt,0),"=vorig blad : "=j
l6=6
gosub &5000
gosub &5600
for e=1 to 17
tabhis(e)=" "
next e
goto &4030
&4300
j=" " 
print=1:tab(01,22),atb(22)
print=1:tab(60,23),paint(kh,ka),"Saldo : ",paint(kt,0),(-6.n2),kltego
ask=1,i=&4000,u=&4000,/80=&4800,/8a=&4005,/8b=&4007,"tT"=&4400,"bB"=&4800:tab(01,24),paint(kh,ka),"Einde historiek : ",paint(kt,0),ret,paint(kh,ka),"T",paint(kt,0),"=vorig blad : "=j
goto &4000
&4400       ;routine einde blad en terug keren
if loop_="N" : goto  &4410
loop_="N"
goto &4420
&4410
loop_="O"
&4420
print=1:tab(01,06),atb(22)
for e=1 to 17
tabhis(e)=" " 
next e
l6=6
goto &4030

&4800
print=1:tab(01,23),atb(21)
print=1:tab(01,01),paint(kh,ka),space(79),tab(01)," MANIPULATIE VAN DE HISTORIEKEN",tab(70),ndat,tab(79)," ",paint(kt,0)
for e=1 to 17
if tabhis(e)=" " : goto  &4805
l6=e    
print=1:tab(02,e+5),paint(kh,ka),(--),e,paint(kt,0) 
next e
&4805
lijntel=0
print=1:tab(01,24),atb(21)
ask=1,i=&4000,u=&4000,/80=&4860:tab(01,24),"Geef lijnnummer te veranderen : "=lijntel
if lijntel<1 : goto  &4805
if lijntel>l6 : goto  &4805
hiskode=tabhis(lijntel)
&4806
search=7,hiskode:&4807,e,kllvhis
print=1:tab(01,06),atb(22)
goto &4809
&4807
print=1:tab(01,24),"Fout search hiskode : ",e," ",hiskode
stop
&4809
print=1:tab(01,06),"Datum faktuur",tab(20),": ",hisdat,"."
print=1:tab(01,07),"Kode F-L-A-V",tab(20),": ",hiskod1,"."
print=1:tab(01,08),"Bedrag 1     ",tab(20),": ",(-6.n2),hisbed1
print=1:tab(01,09),"Btw bedrag",tab(20),": ",(-6.n2),hisbtw
print=1:tab(01,10),"Kode T-I-K-V ",tab(20),": ",hiskod2,"."
print=1:tab(01,11),"Bedrag 2     ",tab(20),": ",(-6.n2),hisbed2
print=1:tab(01,12),"Kode histor.",tab(20),": ",hiskllv,"."
print=1:tab(01,13),"Factuurnummer",tab(20),": ",hisfakt,"."
print=1:tab(01,14),"Betaalwijze  ",tab(20),": ",hisbetw,"."
print=1:tab(01,15),"Omschrijving",tab(20),": ",hisoms,"."
print=1:paint(kl,0),tab(01,17),gener(79,hto),paint(kt,0)
goto &4812
&4810
print=1:tab(01,18),atb(22)
up=7:&4002,e,hisdown
if hisnaam<>klkode : goto  &4002
goto &4809
&4811
print=1:tab(01,18),atb(22)
down=7:&4002,e,hisdown
if hisnaam<>klkode : goto  &4002
goto &4809
&4812
delhis=hiskode
ask=1,i=&4834,u=&4834,/8a=&4810,/8b=&4811:tab(22,06)=hisdat
histdat=right(hisdat,2)+substr(hisdat,4,2)+left(hisdat,2)
&4814
ask=1,i=&4834,u=&4812:tab(22,07)=hiskod1
hiskod1=large(hiskod1)
&4816
ask=1,i=&4834,u=&4814:tab(22,08)=hisbed1
&4818
ask=1,i=&4834,u=&4816:tab(22,09)=hisbtw
&4820
ask=1,i=&4834,u=&4818:tab(22,10)=hiskod2
hiskod2=large(hiskod2)
&4822
ask=1,i=&4834,u=&4820:tab(22,11)=hisbed2
&4824
ask=1,i=&4834,u=&4822:tab(22,12)=hiskllv
hiskllv=large(hiskllv)
hisnaam=hiskllv
&4826
ask=1,i=&4834,u=&4824:tab(22,13)=hisfakt
hisfakt=shr(hisfakt)
&4828
ask=1,i=&4834,u=&4826:tab(22,14)=hisbetw
&4830
ask=1,i=&4834,u=&4828:tab(22,15)=hisoms
hisoms=large(hisoms)
&4834
j=" "
ask=1,i=&4000,u=&4830,/8a=&4810,/8b=&4811,/80=&4835:tab(01,19),vali," (A=annulatie) : "=j
j=large(j)
if j="A" : goto  &4846
if j<>"Y" : goto  &4811
delete=7,delhis:&4835,e
&4835
insert=7,hiskode:&4845,e,kllvhis
goto &4850
&4845
histel=histel+1
goto &4835
&4846
delete=7,hiskode:&4847,e
&4847
print=1:tab(01,06),atb(22)
goto &4021
&4850
teller(07)=teller(07)+1       ;aanpassen historieken teller
par(3)=param3
goto &4000
&4860
hiskode=klkode 
search=7,hiskode:&4865,e,kllvhis
&4865
down=7:&4000,e,hisdown
if hisnaam<>klkode : goto  &4000
delete=7,hiskode:&4865,e
&4866
hisnaam=klkode
histdat=right(hisdat,2)+substr(hisdat,4,2)+left(hisdat,2)
histel=0
&4870
insert=7,hiskode:&4875,e,kllvhis 
goto &4865
&4875
histel=histel+1
goto &4870

&4900
print=1:tab(01,01),paint(kh,ka),space(79),tab(01)," MANIPULATIE VAN DE OPENSTAANDE FAKTUREN ",tab(70),ndat,tab(79)," ",paint(kt,0)
for e=1 to 17
if tabopf(e)=" " : goto  &4905
l6=e
print=1:tab(02,e+5),paint(kh,ka),(--),e,paint(kt,0)
next e
&4905
lijntel=0
print=1:tab(01,24),atb(21)
&4906
ask=1,i=&3000,u=&3000:tab(01,24),"Geef lijnnummer te veranderen : "=lijntel
if lijntel=0 : goto  &4906
fakkode=tabopf(lijntel)
search=6,fakkode:&4905,e,fakrec
print=1:tab(01,06),atb(22)
&4910
faknum=shr(faknum)
print=1:tab(01,06),"Datum faktuur",tab(20),": ",fakdat,"."
print=1:tab(01,07),"Vervaldatum  ",tab(20),": ",fakverv,"."
print=1:tab(01,08),"Klantenkode  ",tab(20),": ",faknaam,"."
print=1:tab(01,09),"Omschrijving ",tab(20),": ",fakoms,"."
print=1:tab(01,10),"Factuurnummer",tab(20),": ",faknum,"."
print=1:tab(01,11),"Te betalen   ",tab(20),": ",(-6.n2),faktebe
print=1:tab(01,12),"Reeds betaald",tab(20),": ",(-6.n2),fakont
print=1:tab(20,13),"============"
print=1:tab(01,14),"Saldo        ",tab(20),": ",(-6.n2),faktebe-fakont
print=1:paint(kl,0),tab(01,16),gener(79,hto),paint(kt,0)
&4912
ask=1,i=&3000,u=&3000,/8a=&4955,/8b=&4950:tab(22,06)=fakdat
&4914
ask=1,i=&4924,u=&4912:tab(22,07)=fakverv
&4915
ask=1,i=&4924,u=&4914:tab(22,08)=faknaam
faknaam=large(faknaam)
&4916
ask=1,i=&4924,u=&4915:tab(22,09)=fakoms
fakoms=large(fakoms)
&4918
ask=1,i=&4924,u=&4916:tab(22,10)=faknum
faknum=shr(faknum)
&4920
ask=1,i=&4924,u=&4918:tab(22,11)=faktebe
&4922
ask=1,i=&4924,u=&4920:tab(22,12)=fakont
&4924
j=" "
print=1:tab(01,18),atb(21)
ask=1,i=&3000,u=&3000,/80=&4926:tab(01,18),vali," (A=annulatie) : "=j
j=large(j)
if j="A" : goto  &4925
if j<>"Y" : goto  &4950
modif=6,fakkode:&4950,e,fakrec
goto &4950
&4925
delete=6,fakkode:&4950,e
goto &4950
&4926
fakkllv="K"
fakname=faknaam 
fakfak=shr(faknum)
insert=6,fakkode:&4927,e,fakrec
teller(05)=teller(05)+1
par(3)=param3
goto &4950
&4927
modif=6,fakkode:&4950,e,fakrec
&4950
down=6:&3000,e,fakdown
&4951
if fakname<>klkode : goto  &3000
goto &4910
&4955
up=6:&3000,e,fakdown
goto &4951

&5000
print=1:clear,paint(kl,0),ltb,gener(77,hto),rtb
print=1:tab(01,02),vte,tab(79),vte
print=1:tab(01,03),vtb,gener(77,hto),vte,paint(kt,0)
print=1:tab(03,02),paint(kh,ka),klnaam," ",klstra," ",klgem,paint(kt,0)
return
&5500
print=1:paint(kl,0),tab(01,04),vtb,tab(79),vte
print=1:tab(01,05),lto,gener(77,hto),rto,paint(kt,0)
print=1:tab(06,04),paint(kh,ka),"Datum",tab(16),"Factuur",tab(26),"Vervald.",tab(38),"Totaal",tab(45),"Betaald",tab(57),"Saldo",tab(65),"Omschrijving",paint(kt,0)
return
&5600
print=1:paint(kl,0),tab(01,04),vtb,tab(79),vte
print=1:tab(01,05),lto,gener(77,hto),rto,paint(kt,0)
print=1:tab(06,04),paint(kh,ka),"Datum",tab(16),"Factuur",tab(26),"Verkoop",tab(37),"Financ",tab(45),"Rekening",tab(56),"Bedrag",tab(65),"Opm",tab(71),"Netto",paint(kt,0)
return

&6000
verkrec=" "
for i=1 to 5
verkbed(i)=0
next i
verkdeb=0
verkbtw=0
for i=1 to 10
verktbe(i)=0
next i
return

&6500
fakrec=" "
fakklv="K"
faktebe=0
fakont=0
return

&6600
hiskllv=" "
hisbed1=0
hisbed2=0
hisbtw=0
return

&6700
mahisre=" "
mabedrd=0
mabedrc=0
return

&7000
print=1:tab(68,03),(-8.n2),restant
return

&9000
for lijntel=5 to 23
sleutl(lijntel)=" "
next lijntel
print=1:tab(01,05),atb(22)
lijntel=5
ask=1,i=&10,u=&10:tab(01,05),"Geef beginkode overzicht klanten : "=klkode
klkode=large(klkode)
search=2,klkode:&9002,e,klrec
&9002
down=2:&9010,e,kldown
sleutl(lijntel)=klkode
print=1:tab(01,lijntel),paint(kn,ka),(n2),lijntel,(e)," ",paint(kt,ka2)," ",klnaam,paint(kt,ka3)," ",klstra,paint(kt,ka4)," ",klgem,paint(kt,0)
lijntel=lijntel+1
if lijntel<23 : goto  &9002
&9003
sleunum=0
print=1:tab(01,24),atb(21)
ask=1,i=&10,u=&10:tab(01,24),paint(kh,ka),bla,paint(kt,0),num,ret,esc,(n2)=sleunum
if sleunum=0 : goto  &9020
if sleunum<5 : goto  &9003
if sleunum>22 : goto  &9003
&9004
klkode=sleutl(sleunum)
search=2,klkode:&9005,e,klrec
print=1:tab(01,06),atb(22)
goto &40
&9005
print=1:tab(01,24),"Fout search klkode : ",e," ",klkode
stop
&9010
sleunum=0
print=1:tab(01,24),atb(21)
ask=1,i=&10,u=&10:tab(01,24),paint(kh,ka),bere,paint(kt,0),num,ret,esc,(n2)=sleunum
if sleunum=0 : goto  &10
if sleunum<5 : goto  &9010
if sleunum>lijntel-1 : goto  &9010
goto &9004
&9020
for e=1 to 22
sleutl(e)=" "
next e
lijntel=5
print=1:tab(01,05),atb(22)
goto &9002
&9200
ldgo.seg 1
goto &10
&9300
eseg 0

segment 1
selma=0   
klkode=" "
&1
leessec="O"
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  OVERZICHT DAGBOEK OP HET SCHERM "
print=1:paint(kl,0),tab(01,02),ltb,gener(77,hto),rtb
if selma<>0 : goto &2
print=1:tab(60,01),"Alle maanden"
goto &3
&2
print=1:tab(60,01),"Maand : ",(n2),selma
&3
print=1:tab(01,03),vtb,tab(79),vte
print=1:tab(01,04),lto,gener(77,hto),rto,paint(kt,0)
print=1:tab(02,03),paint(kh,ka),"Ln  Dat",tab(14),"Klant       ",tab(26),"Fact",tab(32),"Bedrag",tab(42),"Omschrijving",tab(61),"Totaal  -   Btw",paint(kt,0)
&10
totbow=0
totool=0
lijntel=5
phil=0
ask=1,i=&200,u=&200,"I"=&300,"i"=&300,/80=&310,/81=&900,/82=&1000:tab(01,24),"Uw keuze overzicht ",paint(kh,ka),"I",paint(kt,0),"=instellen maand ",paint(kh,ka),"N",paint(kt,0),"=normaal ",paint(kh,ka),"O",paint(kt,0),"=omgekeerd : ",leessec," "=leessec
leessec=large(leessec)
phil=0
if kodes(05)<>"Y" : goto  &15
selboek=" "
print=1:tab(01,24),atb(21)
ask=1,i=&10,u=&10:tab(01,24),"Geef dagboeknummer : "=selboek
selboek=large(selboek)
&15
if leessec="N" : goto  &30
if leessec="O" : goto  &20 
goto &10
&20
verkkey="99999999"
phil=1
goto &40
&30
verkkey=" "
phil=0
&40
search=3,verkkey:&50,e,verkrec
goto &70
&50
op &400,e
if phil=1 : goto  &60
down=3:&130,e,verkdown
goto &70
&60
up=3:&130,e,verkdown
&70
if selboek=" " : goto  &75
if verkboek<>selboek : goto  &50
&75
if selma=0 : goto  &80
if selma<>conv(substr(verkdat,4,2)) : goto  &50
&80
if klkode=" " : goto  &85
if verkkla<>klkode : goto  &50
&85
totool=totool+verkdeb
totbow=totbow+verkbtw
print=1:tab(01,lijntel),paint(kn,ka),(n3),lijntel,(e)," ",paint(kt,ka2)," ",(u5),verkdat,(e),"  ",paint(kt,ka3)," ",verkkla," ",paint(kn,ka4),(u6),shr(verkfak)," ",tab(30),paint(kn,ka5),(-6.n2),verkdeb
print=1:(e),"   ",tab(41),paint(kt,ka)," ",(u19),verkoms,tab(58),paint(kn,ka2),(-7.n2),totool,paint(kn,ka3),totbow,(e),"   ",paint(kt,0)
tabverk(lijntel)=verkkey
lijntel=lijntel+1
if lijntel<23 : goto  &50
&90
zoek=0
print=1:tab(01,24),atb(21)
ask=1,i=&1,u=&1,"T"=&110,"t"=&110:tab(01,24),paint(kh,ka),bla,paint(kt,0),num,paint(kh,ka),"T",paint(kt,0),"=terug",ret=zoek
if zoek=0 : goto  &100
if zoek<1 : goto  &90
if zoek>lijntel-1 : goto  &90
goto &500
&100
print=1:tab(01,05),atb(22)
lijntel=5
goto &50
&110
if phil=0 : goto  &120
phil=0
goto &100
&120
phil=1
goto &100
&130
zoek=0
print=1:tab(01,24),atb(21)
ask=1,i=&200,u=&200,"T"=&110,"t"=&110:tab(01,24),paint(kh,ka),bere,paint(kt,0),num,paint(kh,ka),"T",paint(kt,0),"=terug",ret=zoek
if zoek=0 : goto  &200
if zoek<1 : goto  &130
if zoek>lijntel-1 : goto  &130
goto &500
&200
ret.seg
&300
print=1:tab(01,24),atb(21)
ask=1,i=&1,u=&1,/80=&310:tab(01,24),"Geef maandkeuze beginselektie : "=selma
if selma<1 : goto  &300
if selma>12 : goto  &300
goto &1
&310
print=1:tab(01,24),atb(21)
ask=1,i=&320,u=&300:tab(01,24),"Geef beginfaktuur voor overzicht : "=zoek
verkfok=conv(zoek)
verktel=0
&320  
phil=0
print=1:tab(01,24),atb(21)
goto &40
&400
if e=83 : goto  &200
if e=115 : goto  &200
goto &40  
&500
verkkey=tabverk(zoek)
search=3,verkkey:&510,e,verkrec
goto &520
&510
down=3:&640,e,verkdown
&520
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  DETAIL VAN EEN VERKOOPFAKTUUR ",tab(70),ndat
print=1:paint(kl,0),tab(01,02),gener(79,hto),paint(kt,0)
&525
print=1:tab(01,03),atb(22)
print=1:tab(01,03),"Factuurkode",tab(40),": ",verkfok,(n2),verktel
klkode=verkkla
search=2,klkode:&530,e,klrec
print=1:tab(01,04),"Klant      ",tab(40),": ",paint(kh,ka),left(klnaam,len$(klnaam)),paint(kt,0)
goto &540
&530
print=1:tab(01,04),bell,"Klant niet gevonden : ",e," ",klkode
stop
&540
print=1:tab(01,05),"Factuurnumer",tab(40),": ",verkfak
print=1:tab(01,06),"Omschrijving",tab(40),": ",verkoms
print=1:tab(01,07),"Datum faktuur",tab(40),": ",verkdat
print=1:tab(01,08),"Type dokument",tab(40),": ",verkcnf
print=1:tab(01,09),"Totaal bedrag",tab(40),": ",(-6.n2),verkdeb
print=1:paint(kl,0),tab(01,10),gener(79,hto),paint(kt,0)
for i=1 to 5
if verkbed(i)=0 : goto  &580
if conv(verkkod(i))=8 : goto  &580
if conv(verkkod(i))=7 : goto  &560
if conv(verkkod(i))=6 : goto  &570
print=1:tabv(01),"Btw groep ",verkkod(i)," ",vertek(conv(verkkod(i))),tab(40),": ",(-6.n2),verkbed(i)
goto &580
&560
print=1:tabv(01),"Bedrag uitvoer btw keuze 7",tab(40),": ",(-6.n2),verkbed(i)
goto &580
&570
print=1:tabv(01),"Bedrag btw medekontraktant",tab(40),": ",(-6.n2),verkbed(i)
&580
next i
&590
print=1:paint(kl,0),tabv(01),gener(79,hto),paint(kt,0)
print=1:tabv(01),"Totaal btw ",tab(40),": ",(-6.n2),verkbtw
print=1:paint(kl,0),tabv(01),gener(79,hto),paint(kt,0)
print=1:tabv(01),paint(kh,ka),"Tegenboekingsrekeningen",atb(0)
print=1:tabv(01)
for i=1 to 10
if verktbe(i)=0 : goto  &591
rekkode=verkteg(i)
if rekkode=" " : goto  &595
search=5,rekkode:&593,e,rekrec
print=1:tabv(01),rekkode," " ,paint(kh,ka),left(rekoms,len$(rekoms)),paint(kt,0),tab(40),": ",(-6.n2),verktbe(i)
&591
next i
goto &595
&593
print=1:tab(01,24),"Fout search rekkode : ",e," ",rekkode
stop
&595
print=1:paint(kl,0),tabv(01),gener(79,hto),paint(kt,0)
&600
ask=1,i=&700,u=&700,/80=&800,/8a=&610,/8b=&620:tab(01,24),fvoor,voor,fvolg,volg=j
goto &700
&610
up=3:&630,e,verkdown
goto &525
&620
down=3:&640,e,verkdown
goto &525
&630
print=1:tab(01,24),atb(21)
ask=1,i=&700,u=&700,/8b=&620:tab(01,24),paint(kh,ka),berb,paint(kt,0),fvolg,volg,esc=j
goto &525
&640
print=1:tab(01,24),atb(21)
ask=1,i=&700,u=&700,/8a=&610:tab(01,24),paint(kh,ka),bere,paint(kt,0),fvoor,voor,esc=j
goto &700
&700
ret.seg
&800
ask=1,i=&525,u=&525:tab(42,04)=verkkla
verkkla=large(verkkla)
search=2,verkkla:&800,e,klrec
&810
ask=1,i=&850,u=&800:tab(42,05)=verkfak
&820
ask=1,i=&850,u=&810:tab(42,06)=verkoms
verkoms=large(verkoms)
&830
ask=1,i=&850,u=&820:tab(42,07)=verkdat
if len$(verkdat)<>8 : goto  &830
&840
ask=1,i=&850,u=&830:tab(42,08)=verkcnf
if verkcnf=" " : goto  &850
if verkcnf="F" : goto  &850
if verkcnf="K" : goto  &850
goto &840
&850
j=" " 
ask=1,i=&525,u=&840:tab(01,24),paint(kh,ka),vali,paint(kt,0)," (A=annulatie) : "=j
j=large(j)
if j="A" : goto  &860
if j<>"Y" : goto  &525
modif=3,verkkey:&525,e,verkrec
goto &525
&860
delete=3,verkkey:&525,e
goto &525

&900
ldgo.seg 5
goto &1

&1000
print=1:tab(01,06),atb(22)
ask=1,i=&1660,u=&1660,/8a=&1622,/8b=&1624:tab(01,06),"Geef klantenkode",esc,klkode,tab(32)=klkode
klkode=large(klkode)
search=2,klkode:&1620,e,klrec
goto &1640
&1620
print=1:tab(01,24),atb(21)
ask=1,i=&1000,u=&1000,/8a=&1622,/8b=&1624:tab(01,24),paint(kh,ka),"Klant",ng,paint(kt,0),fvoor,voor,fvolg,volg=j
goto &1000
&1622
up=2:&1623,e,kldown
goto &1640
&1623
print=1:tab(01,24),atb(21)
ask=1,i=&1000,u=&1000,/8b=&1624:tab(01,24),paint(kh,ka),berb,paint(kt,0),fvolg,volg=j
goto &1000
&1624
down=2:&1625,e,kldown
goto &1640
&1625
print=1:tab(01,24),atb(21)
ask=1,i=&1000,u=&1000,/8a=&1622:tab(01,24),paint(kh,ka),bere,paint(kt,0),fvoor,voor=j
goto &1000
&1640
print=1:tab(01,06),atb(22)
print=1:tab(01,06),"Klantkode",tab(20),": ",klkode
print=1:tab(01,08),"Naam",tab(20),": ",paint(kh,ka),left(klnaam,len$(klnaam)),paint(kt,0)
print=1:tab(01,09),"Straat",tab(20),": ",klstra
print=1:tab(01,10),"Gemeente",tab(20),": ",klgem
print=1:paint(kl,0),tab(01,02),gener(79,hto),paint(kt,0)
&1650
j=" "
ask=1,i=&1000,u=&1000,/8a=&1622,/8b=&1624:tab(01,14),"Deze klant  Y-N : "=j
j=large(j)
if j=" " : goto  &1650
if j<>"Y" : goto  &1000
goto &1
&1660
klkode=" " 
&1670
goto &1 
eseg 1

segment 3
goto &10 
&1
ret.seg
&10
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  KONTROLE VERKOOPDAGBOEK ",tab(70),ndat
print=1:paint(kl,0),tab(01,02),gener(79,hto),paint(kt,0)
&30 
overz=0
ask=1,i=&1,u=&1:tab(01,05),"Geef de maandkeuze 1--12",esc=overz
if overz=0 : goto  &100
if overz<1 : goto  &30
if overz>12 : goto  &30
&100
open=3:&1,e
verkfok="999999"
verktel=32000
search=3,verkkey:&105,e,verkrec
&105
totaal=0
totaal2=0
testbtw=0
up=3:&1,e,verkdown 
op &220,e
if overz=0 : goto  &106
vers=conv(substr(verkdat,4,2))
if vers<>overz : goto  &105
&106
print=1:tab(01,07),"Kode klant : ",verkkla
print=1:tab(01,08),"Factuurnr  : ",verkfak
print=1:tab(01,09),"Fact. dat. : ",verkdat
for tel=1 to 5  
totaal=totaal+verkbed(tel)
next tel
goto &120
&110
return
&120
print=1:tab(01,10),"Goederen   : ",(-7.n2),totaal
totaal=totaal+verkbtw
print=1:tab(01,11),"Btw        : ",(-7.n2),verkbtw 
print=1:tab(01,12),gener(13,hto) 
print=1:tab(01,12),"Totaal     : ",(-7.n2),verkdeb
for a=1 to 10
totaal2=totaal2+verktbe(a)
next a
for tel=1 to 5  
z=conv(verkkod(tel))
if z<1 : goto  &121
if z>5 : goto  &121
btwsoort=conv(conv(verper(z)))
testbtw=testbtw+verkbed(tel)*btwsoort/100 
testbtw=roun(testbtw,2)
&121
next tel
vers=totaal2+verkbtw-verkdeb
print=1:tab(01,15),"Totaal 2   : ",(-7.n2),vers
if totaal2+verkbtw<>verkdeb : goto  &200
if testbtw<>verkbtw : goto  &210
goto &105
&200
verkdeb=verkdeb+vers
print=1:tab(01,20),"Tot. factuur : ",(-7.n2),verkdeb
ask=1,i=&1,u=&105:tab(01,24)=j
print=1:tab(01,20),atb(22)
goto &105 
&210 
print=1:tab(01,20),"Test op btw   : ",(-7.n2),testbtw
ask=1,i=&1,u=&105:tab(01,24)=j
print=1:tab(01,20),atb(22)
goto &105 
&220
j=" "
ask=1,i=&1,u=&225:tab(01,24),"U heeft de kontrole onderbroken - verdergaan  Y-N : "=j
j=large(j)
if j=" " : goto  &220
if j="N" : goto  &1
&225
print=1:tab(01,24),atb(21)
goto &105
eseg 3

segment 4
&10
goto &125
&25
ret.seg
&125
hisnaam=klkode
histdat=right(fakdat,2)+substr(fakdat,4,2)+left(fakdat,2)
histel=0
hisdat=fakdat                 ;invullen klantenhistoriek gegevens
hisoms=fakoms
hiskod1="V"                   ;kode verkoop
hiskod2=" "                   ;kode 2 geen intrest , korting e.d.
hisbed1=faktebe               ;totaal te betalen
hiskllv=klkode                ;klantenkode
hisbed2=0                     ;geen tweede kode ingevuld dus geen tweede bedrag
hisfakt=faknum                ;invullen faktuurnummer
hisbetw=" "
hisbtw=totbtw                 ;totaal bedrag btw
&128
insert=7,hiskode:&130,e,kllvhis
goto &132
&130
histel=histel+1
goto &128
&132
teller(07)=teller(07)+1       ;aanpassen historieken teller
teller(14)=teller(14)+1       ;aanpassen fakturen inschrijvings teller
&133
omzet=0
fakkllv="K"
fakname=klkode
faknaam=klkode                ;kode klant
fakfak=shr(faknum)
fakont=0                      ;reeds ontvangen bedragen
teller(05)=teller(05)+1
insert=6,fakkode:&134,e,fakrec
goto &140
&134
modif=6,fakkode:&135,e,fakrec
goto &140
&135
print=1:tab(01,24),"Fout insert faktuurrecord : ",e," ",fakkode
stop
&140
teller(05)=teller(05)+1
kltego=kltego+faktebe
modif=2,klkode:&146,e,klrec
goto &200
&146    
print=1:tab(01,24),"Fout modif klantenkode : ",e," ",klkode
stop
&200    
par(3)=param3
par(4)=param4
goto &25
eseg 4

segment 5
goto &30
&1
ret.seg
&30
totaal=0
lijntel=5
print=1:clear,paint(kh,ka),naam,paint(kt,0),"  OPZOEKEN IN HISTORIEK OP BEDRAG "
print=1:paint(kl,0),tab(01,02),ltb,gener(77,hto),rtb
print=1:tab(01,03),vtb,tab(79),vte
print=1:tab(01,04),lto,gener(77,hto),rto,paint(kt,0)
print=1:tab(03,03),paint(kh,ka),"Datum",tab(10),"Lever",tab(22),"Factuur",tab(30),"Omschrijv.",tab(46),"Bedrag",paint(kt,0)
print=1:tab(01,21),paint(kh,ka),"Opzoeken bepaald bedrag"
print=1:tab(01,22),"=======================",paint(kt,0)
&31
ask=1,i=&1,u=&1:tab(01,23),"Geef selektiebedrag : "=totaal
if totaal=0 : goto  &31
&32
ask=1,i=&1,u=&31:tab(01,24),"Geef beginfaktuur : "=verkfok 
print=1:tab(01,20),atb(22)
verktel=0
search=3,verkfok:&35,e,verkrec
&35
down=3:&80,e,verkdown
op &36,e
goto &39
&36
if e=83 : goto  &30
if e=115 : goto  &30
&37
j=" "
print=1:tab(01,24),atb(21)
ask=1,i=&39,u=&39:tab(01,24),bell,"U heeft deze routine onderbroken - verdergaan Y-N : "=j
j=large(j)
if j="N" : goto  &1
if j<>"Y" : goto  &37
print=1:tab(01,24),atb(21)
&39
if verkdeb=totaal : goto  &40
if verkbtw=totaal : goto  &40
for e=1 to 5
if verkbed(e)=totaal : goto  &40
next e
for e=1 to 10
if verktbe(e)=totaal : goto  &40
next e
print=1:tab(01,24),verkdat," ",verkfak," ",verkkla
goto &35
&40
print=1:tab(01,lijntel),verkdat,tab(10),verkkla,tab(22),verkfak,tab(30),verkoms,tab(46),totaal
lijntel=lijntel+1
if lijntel<23 : goto  &35
&41
print=1:tab(01,24),atb(21)
ask=1,i=&1,u=&1:tab(01,24),paint(kh,ka),bla,paint(kt,0),ret,esc=j
print=1:tab(01,04),atb(22)
lijntel=5
goto &35
&80
print=1:tab(01,24),atb(21)
ask=1,i=&1,u=&1:tab(01,24),paint(kh,ka),bere,paint(kt,0),ret,esc=j
goto &1
eseg 5
end